COMPCTE 
COMMON
          CTEXT  COMPCTE - CREATE MANAGED TABLE ENTRY.
 CTE      SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCTE
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CTE      SPACE  4,10 
***       CTE - CREATE MANAGED TABLE ENTRY. 
*         P. D. HAAS.        81/03/10.
 CTE      SPACE  4,20 
***              *CTE* CREATES AN ENTRY IN A SPECIFIED MANAGED
*         TABLE, AS DEFINED IN *COMSCPS* UNDER THE *MTRM* MONITOR 
*         FUNCTION.  IF THE SPECIFIED TABLE IS THE QFT, A JOB 
*         SEQUENCE NUMBER IS APPENDED TO THE ENTRY.  AN OVERRIDE
*         OF THE LATTER IS AVAILABLE BY SETTING THE UPPER 6 BITS
*         OF THE *A* REGISTER NON-ZERO ON ENTRY.
* 
*         ENTRY  (A) = 6/ J,1/ F,11/ TABLE IDENTIFIER 
*                      J .NE. 0 IF NO JSN TO BE REQUESTED.
*                      F .NE. 0 IF SYSTEM JOB CALL (RESERVED ENTRY WILL 
*                        BE ASSIGNED IF TABLE FULL).
*                (CM+3 - CM+7) = VALUE FOR FIRST WORD OF ENTRY. 
* 
*         EXIT   (A) = (CM+3 - CM+4) = ABSOLUTE ADDRESS OF ENTRY. 
*                    = 0 IF TABLE FULL. 
*                (CM+1) = ORDINAL OF TABLE ENTRY. 
* 
*         USES   T2, CM - CM+4. 
* 
*         MACROS MONITOR. 
* 
*         XREF   COMSCPS. 
  
  
 CTE2     STD    CM+1        SELECT CREATION MODE 
          LDD    MA          STORE VALUE FOR TABLE ENTRY
          CWD    CM+3 
          MONITOR  RJSM      REQUEST JOB SEQUENCE NUMBER/QFT ENTRY
 CTE3     LDD    CM+3        ABSOLUTE ADDRESS OF TABLE ENTRY
          SHN    14 
          LMD    CM+4 
          NJN    CTEX        IF TABLE ENTRY CREATED 
*         STD    CM+1 
          LDD    T2          ISSUE EVENT
          STD    CM+4 
          MONITOR  EATM 
*         LDN    0
  
 CTE      SUBR               ENTRY/EXIT 
          STD    CM+2 
          LPC    773777      MASK OFF SYSTEM JOB FLAG 
          STD    T2          SAVE TABLE IDENTIFIER
          LMN    PQFT 
          ZJN    CTE2        IF QFT AND NO JSN OVERRIDE 
          LDD    CM+3 
          NJN    CTE1        IF VALUE DEFINED 
          LCN    1
          STD    CM+3 
 CTE1     LDD    MA          STORE VALUE FOR TABLE ENTRY
          CWD    CM+3 
          LDN    0           SELECT CREATION MODE 
          STD    CM+1 
          MONITOR  MTRM      REQUEST TABLE ENTRY
          UJN    CTE3        CHECK RESPONSE 
 CTE      SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CTE      EQU    /COMPCTE/CTE 
 QUAL$    ENDIF 
          ENDX
