COMPCOB 
COMMON
          CTEXT  COMPCOB - CHECK OUTPUT BUFFER. 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCOB
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COB      SPACE  4
***       COB - CHECK OUTPUT BUFFER.
*         G. R. MANSFIELD.  09/27/69. 
 COB      SPACE  4
***              COB READS THE *IN* POINTER FROM THE FET, AND COMPUTES
*         THE AMOUNT OF DATE IN THE CIRCULAR BUFFER.
*         ENTRY  (IR+3 - IR+4) = ADDRESS OF FET.
*                (FT - FT+1) = FIRST ADDRESS OF CM BUFFER.
*                (IN - IN+1) = NEXT INPUT ADDRESS.
*                (OT - OT+1) = NEXT OUTPUT ADDRESS. 
*                (LM - LM+1) = LIMIT ADDRESS OF CM BUFFER.
*         EXIT   (A) = WORD COUNT OF BUFFER.
*                (A) .LT. 0, IF IN .GE. FL. 
*                RESETS (IN - IN+1).
*         USES   CM - CM+4. 
  
  
 COB1     LCN    0           SET ERROR RETURN 
  
 COB      SUBR               ENTRY/EXIT 
          LDD    IR+3        READ IN
          SHN    6
          ADD    RA 
          SHN    6
          ADD    IR+4 
          ADN    2
          CRD    CM 
          LDD    CM+3        SET IN 
          LPN    37 
          STD    IN 
          SHN    14 
          LMD    CM+4 
          STD    IN+1 
          SHN    -6 
          SBD    FL 
          PJN    COB1        IF IN \ FL 
          LDD    IN          LENGTH = IN - OUT
          SBD    OT 
          SHN    14 
          ADD    IN+1 
          SBD    OT+1 
          PJN    COBX        RETURN IF IN @ OUT 
          SHN    6           LENGTH = (LIMIT - OUT) + (IN - FIRST)
          ADD    LM 
          SBD    FT 
          SHN    14 
          ADD    LM+1 
          SBD    FT+1 
          UJN    COBX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 COB      EQU    /COMPCOB/COB 
 QUAL$    ENDIF 
          ENDX
