COMPCMX 
COMMON
          CTEXT  COMPCMX - COMPUTE MAXIMUM FIELD LENGTH.
 COMPCMX  SPACE  4
          BASE   MIXED
          IF     -DEF,QUAL$,1 
          QUAL   COMPCMX
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMPCMX  SPACE  4
***       CMX - COMPUTE MAXIMUM FIELD LENGTH. 
*         B.T. ZEMLIN.       75/01/25.
*         M.J. CARIDDI       81/10/19.
 COMPCMX  SPACE  4
***               CMX COMPUTES THE MAXIMUM POSSIBLE FIELD LENGTH
*         FOR ANY JOB.  THE CALCULATION IN THE SUPPLIED VERSION 
*         OF THIS DECK IS AS FOLLOWS -
* 
*                MAXFL = MINIMUM(MACHINE SIZE - CMR SIZE - CONSTANT,
*                        MACHINE SIZE - CMR SIZE - CONSTANT - IAF FL
*                        - NETWORK CONSTANT (IF TXOT JOB),
*                        VALIDATION FL) 
* 
*         ENTRY  (A) - CM VALIDATION INDEX. 
*                (T1) = ORIGIN TYPE.
* 
*         EXIT   (A) - MAXFL/100. 
* 
*         USES   T2, T3, CM - CM+4. 
* 
*         CALLS  CMI. 
* 
*         XREF   COMPCVI (WITH CMI$ SELECTED), COMSREM. 
  
  
 CMX      SUBR               ENTRY/EXIT 
          RJM    CMI         CONVERT MEMORY INDEX 
          STD    T2          VALIDATION SIZE/100
          LDN    CMRL        CMR SIZE/100 
          CRD    CM 
          LDD    CM+4 
          ADK    CMXB 
          STD    T3 
          LDD    T1 
          LMN    TXOT 
          NJN    CMX0        IF NOT *TXOT* JOB
          LDC    /REM/VCPT*200+JCIW 
          CRD    CM 
          LDD    CM+2 
          LMC    IFSI 
          NJN    CMX0        IF *IAF* NOT PRESENT 
          LDC    /REM/VCPT*200+FLSW 
          CRD    CM 
          LDD    CM+4        ADJUST FOR *IAF* FL
          RAD    T3 
          LDC    /REM/NMFL/100  ADJUST FOR NAM
          RAD    T3 
 CMX0     LDC    MABL        GET MACHINE SIZE 
          CRD    CM 
          LDD    CM+2        CALCULATE MACHINE SIZE - CMR SIZE - CMXB 
          SHN    14 
          LMD    CM+3 
          SBD    T3 
          STD    T3 
          SHN    -14
          ZJN    CMX1        IF .LE. 7777 
          LCN    0
          STD    T3 
 CMX1     LDD    T2          VALIDATION SIZE
          SBD    T3          MACHINE MAXIMUM
          PJN    CMX2        IF VALIDATION LARGER 
          LDD    T2 
          UJN    CMX3        EXIT WITH VALIDATION 
  
 CMX2     LDD    T3          EXIT WITH MACHINE MAXIMUM
 CMX3     LJM    CMXX        RETURN 
  
 CMXB     EQU    20          ADDITIONAL MEMORY RESIDENT SIZE/100
 COMPCMX  SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CMX      EQU    /COMPCMX/CMX 
 QUAL$    ENDIF 
          ENDX
