COMPCLX 
COMMON
          CTEXT  COMPCLX - CLEAR EXCHANGE PACKAGE.
 CLX      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPCLX
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CLX      SPACE  4
***       CLX - CLEAR EXCHANGE PACKAGE. 
*         G. R. MANSFIELD.  70/08/30. 
 CLX      SPACE  4
***              CLX PRESETS THE EXCHANGE PACKAGE AS FOLLOWS -
*         (P) = ENTRY ADDRESS.
*         (A0) = FL.
*         (X0) = ECS FL.
*         ALL OTHER REGISTERS = 0.
*         (RA) = SENSE SWITCHES.
*         (RA+1) = 0. 
* 
*         ENTRY  (A) = ENTRY ADDRESS. 
* 
*         USES   T1, CM - CM+4. 
  
  
 CLX      SUBR               ENTRY/EXIT 
          STD    CM+1        (P) = ENTRY ADDRESS
          SHN    -14
          STD    CM 
          LDD    FL          (A0) = FL
          STD    CM+2 
          LDN    0           CLEAR WORD 
          STD    CM+3 
          STD    CM+4 
          LDD    CP          STORE (P), (A0)
          CWD    CM 
          ADN    1
          STD    T1 
 CLX1     LDD    T1          READ EXCHANGE AREA 
          CRD    CM 
          LDN    0           CLEAR A, B REGISTERS 
          STD    CM+2 
          STD    CM+3 
          STD    CM+4 
          LDD    T1 
          LPN    77 
          LMN    3
          NJN    CLX1.1      IF NOT THE EXIT MODE WORD
          STD    CM+1        CLEAR POSSIBLE *PSD* ERRORS
 CLX1.1   LDD    T1          RESTORE WORD 
          CWD    CM 
          AOD    T1          ADVANCE EXCHANGE ADDRESS 
          LPN    7
          NJN    CLX1        LOOP FOR ALL A, B REGISTERS
          LDK    MEFL        GET USER EM SHIFT COUNT
          CRD    CM 
          LDD    CM+2 
          SHN    -11
          ADC    SHNI+17
          STM    CLXA 
          LDD    CP          FETCH ECS INFORMATION
          ADN    ECSW 
          CRD    CM 
          LDN    0           CLEAR PROTECT FLAGS
          STD    CM 
          STD    CM+1 
          STD    CM+2 
          LDD    CM+4        FLE
 CLXA     SHN    17 
*         SHN    17+UESC
          STD    CM+3 
          SHN    -6 
          SCN    77 
          STD    CM+4 
          LDD    T1          STORE X0 
          CWD    CM 
          LDD    CM+3 
          ADD    CM+4 
          NJN    CLX2        IF FLE (ECS FL IN ECSW) IS NON-ZERO
          LDD    CP          CHECK FLX CONTROL
          ADN    JCIW 
          CRD    CM 
          LDD    CM+3 
          SHN    21-12
          MJN    CLX2        IF PRESERVING FLX AT JOB STEP
          LDN    ZERL 
          CRD    CM 
          LDD    T1 
          SBN    3
          CWD    CM          ZERO OUT FLX (WORD 5 OF EXCHANGE PACKAGE)
 CLX2     LDN    ZERL        SET TO CLEAR EXCANGE PACKAGE X REGS
          CRD    CM 
 CLX3     AOD    T1 
          CWD    CM 
          LPN    17 
          LMN    17 
          NJN    CLX3        IF NOT ALL X REGISTERS CLEARED 
          LDD    RA          CLEAR (RA+1) 
          SHN    6
          ADN    1
          CWD    CM 
          LDD    CP          READ SWITCH WORD 
          ADN    SNSW 
          CRD    CM 
          LDN    0           CLEAR UPPER BYTES
          STD    CM 
          STD    CM+1 
          STD    CM+2 
          STD    CM+3 
          LDD    CM+4        COPY ONLY SENSE SWITCH BITS
          SCN    77 
          STD    CM+4 
          LDD    RA          STORE SENSE SWITCHES 
          SHN    6
          CWD    CM 
          LJM    CLXX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CLX      EQU    /COMPCLX/CLX 
 QUAL$    ENDIF 
          ENDX
