COMPCIB 
COMMON
          CTEXT  COMPCIB - CHECK INPUT BUFFER.
          IF     -DEF,QUAL$,1 
          QUAL   COMPCIB
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CIB      SPACE  4
***       CIB - CHECK INPUT BUFFER. 
*         G. R. MANSFIELD.  09/27/69. 
 CIB      SPACE  4
***              CIB READS THE *OUT* POINTER FROM THE FET, AND COMPUTES 
*         THE AMOUNT OF SPACE IN THE CIRCULAR BUFFER. 
*         ENTRY  (IR+3 - IR+4) = FET ADDRESS. 
*                (FT - FT+1) = FIRST ADDRESS OF CM BUFFER.
*                (IN - IN+1) = NEXT INPUT ADDRESS.
*                (OT - OT+1) = NEXT OUTPUT ADDRESS. 
*                (LM - LM+1) = LIMIT ADDRESS OF CM BUFFER.
*         EXIT   (A) = WORD COUNT OF BUFFER.
*                (A) .LT. 0, IF OUT .GE. FL.
*                RESETS (OT - OT+1).
*         USES   CM - CM+4. 
  
  
 CIB3     LCN    0           SET ERROR RETURN 
  
 CIB      SUBR               ENTRY/EXIT 
          LDD    IR+3        READ OUT 
          SHN    6
          ADD    RA 
          SHN    6
          ADD    IR+4 
          ADN    3
          CRD    CM 
          LDD    CM+3        SET OUT
          LPN    37 
          STD    OT 
          SHN    14 
          LMD    CM+4 
          STD    OT+1 
          SHN    -6 
          SBD    FL 
          PJN    CIB3        IF OUT \ FL
          LDD    OT          LENGTH = OUT - IN
          SBD    IN 
          SHN    14 
          ADD    OT+1 
          SBD    IN+1 
          ZJN    CIB1        IF IN = OUT
          PJN    CIB2        IF OUT > IN
 CIB1     SHN    6           LENGTH = (LIMIT - IN) + OUT - FIRST) 
          ADD    LM 
          SBD    FT 
          SHN    14 
          ADD    LM+1 
          SBD    FT+1 
 CIB2     SBN    1           LENGTH - 1 
          LJM    CIBX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CIB      EQU    /COMPCIB/CIB 
 QUAL$    ENDIF 
          ENDX
