COMPCHM 
COMMON
          CTEXT  COMPCHM - REDEFINE I/O INSTRUCTIONS. 
          SPACE  4,10 
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CHM      SPACE  4,10 
*****     COMPCHM - REDEFINE I/O INSTRUCTIONS.
* 
*         P. D. HAAS.        78/08/09.
 CHM      SPACE  4,10 
***              *COMPCHM* REDEFINES I/O INSTRUCTIONS TO PRODUCE
*         CHANNEL TABLES WITH LABELED REMOTE CODE.
* 
*         ORIGINAL FORM MAY BE USED BY APPENDING A *.* TO THE ORIGINAL
*         OPCODE. 
* 
*         INSTRUCTIONS REDEFINED -
*                AJM
*                IJM
*                FJM
*                EJM
*                IAM
*                OAM
*                SCF
*                CCF
*                SFM
*                CFM
*                FNC
*                IAN
*                OAN
*                ACN
*                DCN
*                FAN
* 
*         THE NAME OF THE REMOTE TABLE IS DETERMINED BY THE *D* 
*         PORTION OF THE CHANNEL INSTRUCTION. 
* 
*         IF USED WITHIN A *LOC* BLOCK, CHANNEL INSTRUCTIONS
*         MUST BE MODIFIED BEFORE THE BLOCK IS MOVED. 
* 
*         IF THE SYMBOL *RINST$* IS DEFINED, INSTRUCTIONS WILL BE 
*         RESTORED ON EXIT FROM THIS DECK.
 CHM      SPACE  4,10 
**        CHIM - REDEFINE M-TYPE CHANNEL INSTRUCTIONS.
* 
* 
*         CHIM   OPC,CODE 
*         ENTRY  *OPC* = INSTRUCTION MNEMONIC.
*                *CODE* = OPERATION CODE. 
  
  
          PURGMAC  CHIM 
 CHIM     MACRO  OPC,CODE 
          PURGMAC OPC 
 OPC.     PPOP   7,CODE 
 OPC      MACRO  M,D
          LOCAL  A
          OPC.   M,D
          QUAL
 A        EQU    *O-2 
          QUAL   *
 CT_D     RMT 
          CON    A
          RMT 
 OPC      ENDM
 CHIM     ENDM
  
          CHIM   AJM,6400 
          CHIM   SCF,6440 
          CHIM   IJM,6500 
          CHIM   CCF,6540 
          CHIM   FJM,6600 
          CHIM   SFM,6640 
          CHIM   EJM,6700 
          CHIM   CFM,6740 
          CHIM   IAM,7100 
          CHIM   OAM,7300 
          CHIM   FNC,7700 
 CHM      SPACE  4,10 
**        CHIN - REDEFINE N-TYPE CHANNEL INSTRUCTIONS.
* 
* 
*         CHIN   OPC,CODE 
*         ENTRY  *OPC* = INSTRUCTION MNEMONIC.
*                *CODE* = OPERATION CODE. 
* 
*         NOTE   BIT 2**5 SET ON ALL *DCN* INSTRUCTIONS.
  
  
          PURGMAC  CHIN 
 CHIN     MACRO  OPC,CODE 
          PURGMAC OPC 
 OPC.     PPOP   4,CODE 
 OPC      MACRO  D
          LOCAL  A
          OPC.   D
          QUAL
 A        EQU    *O-1 
          QUAL   *
 CT_D     RMT 
          CON    A
          RMT 
 OPC      ENDM
 CHIN     ENDM
  
          CHIN   IAN,7000 
          CHIN   OAN,7200 
          CHIN   ACN,7400 
          CHIN   DCN,7540 
          CHIN   FAN,7600 
 CHM      SPACE  4,10 
**        CHTB - DEFINE CHANNEL TABLE.
*         CHANNEL TABLE IS TERMINATED BY A ZERO WORD. 
* 
* 
*         CHTB   D
*         ENTRY  *D* = NAME OF CHANNEL TABLE. 
  
  
          PURGMAC CHTB
 CHTB     MACRO  D
 CT_D     BSS    0
 CT_D     HERE
          CON    0           TERMINATE TABLE
 CHTB     ENDM
 CHM      SPACE  4,10 
**        RSTC - RESTORE CHANNEL INSTRUCTIONS.
* 
* 
*         RSTC
  
  
          PURGMAC RSTC
 RSTC     MACRO 
          PURGMAC AJM 
          PURGMAC SCF 
          PURGMAC IJM 
          PURGMAC CCF 
          PURGMAC FJM 
          PURGMAC SFM 
          PURGMAC EJM 
          PURGMAC CFM 
          PURGMAC IAN 
          PURGMAC IAM 
          PURGMAC OAN 
          PURGMAC OAM 
          PURGMAC ACN 
          PURGMAC DCN 
          PURGMAC FAN 
          PURGMAC FNC 
 AJM      OPSYN  AJM. 
 SCF      OPSYN  SCF. 
 IJM      OPSYN  IJM. 
 CCF      OPSYN  CCF. 
 FJM      OPSYN  FJM. 
 SFM      OPSYN  SFM. 
 EJM      OPSYN  EJM. 
 CFM      OPSYN  CFM. 
 IAN      OPSYN  IAN. 
 IAM      OPSYN  IAM. 
 OAN      OPSYN  OAN. 
 OAM      OPSYN  OAM. 
 ACN      OPSYN  ACN. 
 DCN      OPSYN  DCN. 
 FAN      OPSYN  FAN. 
 FNC      OPSYN  FNC. 
 RSTC     ENDM
  
  
          IF     DEF,RINST$ 
          RSTC               RESTORE CHANNEL INSTRUCTIONS 
          ENDIF 
 CHM      SPACE  4,10 
          BASE   *
          ENDX
