COMPCHD 
COMMON
          CTEXT  COMPCHD - CONVERT TWO HEX DIGITS TO DISPLAY CODE.
 CHD      SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCHD
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CHD      SPACE  4,10 
***       CHD - CONVERT TWO HEX DIGITS TO DISPLAY CODE. 
*         P. D. HAAS.       86/07/01. 
 CHD      SPACE  4,10 
*         ASSEMBLY CONSTANTS. 
  
  
 CA       DEFC   T3          CONVERSION ADDRESS 
 CHD      SPACE  4,10 
***              CHD CONVERTS TWO HEX DIGITS TO DISPLAY CODE. 
* 
*         ENTRY  (A) = HEX DATA RIGHT JUSTIFIED.
*                (CA) = ADDRESS TO STORE CONVERSION.
* 
*         EXIT   (CA) = CONVERSION ADDRESS ADVANCED.
*                (T0) = TWO HEX DIGITS JUST CONVERTED.
  
  
 CHD      SUBR               ENTRY/EXIT 
          LPC    377
          STD    T0 
          SHN    -4          EXTRACT LEADING DIGIT
          SBN    9D 
          MJN    CHD1        IF DIGIT .LT. 9
          NJN    CHD2        IF DIGIT .GT. 9
 CHD1     ADN    1R0+9D 
 CHD2     SHN    6           SAVE CONVERTED DIGIT 
          STI    CA 
          LDD    T0          EXTRACT LOWER DIGIT
          LPN    17 
          SBN    9D 
          MJN    CHD3        IF DIGIT .LT. 9
          NJN    CHD4        IF DIGIT .GT. 9
 CHD3     ADN    1R0+9D 
 CHD4     RAI    CA          APPEND TO CONVERSION 
          AOD    CA 
          UJN    CHDX        RETURN 
          SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CHD      EQU    /COMPCHD/CHD 
 QUAL$    ENDIF 
          ENDX
