COMPCDD 
COMMON
          CTEXT  COMPCDD - CONSTANT TO DECIMAL DISPLAY CODE CONVERSION. 
 COMPCDD  SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCDD
*COMMENT  COMPCDD - CONSTANT TO DECIMAL DISPLAY CODE CONVERSION.
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMPCDD  SPACE  4,10 
***       CDD - CONSTANT TO DECIMAL DISPLAY CODE CONVERSION.
*         P. D. FARRELL.     81/10/09.
 COMPCDD  SPACE  4,15 
***            *CDD* CONVERTS A BINARY CONSTANT TO UP TO TWO
*         DECIMAL DIGITS OF DISPLAY CODE (00 TO 99D) WITH 
*         LEADING ZEROES. 
* 
*         ENTRY  (A) = CONSTANT TO BE CONVERTED.
* 
*         EXIT   (A) = CONVERSION IF NO RANGE ERROR.
*                    = 2R** IF RANGE ERROR. 
  
  
 CDD3     LDC    2R**        SET (A) = RANGE ERROR
*         UJN    CDDX        RETURN 
  
*         CDD - ENTRY/EXIT. 
  
 CDD      SUBR               ENTRY/EXIT 
          MJN    CDD3        IF NEGATIVE VALUE
          STD    T0          SAVE CONSTANT
          SBK    100D        CHECK RANGE
          PJN    CDD3        IF RANGE ERROR 
          LDC    2R00+10D    INITIALIZE ASSEMBLY
          STM    CDDA 
 CDD1     LCN    10D         SUBTRACT 10D 
          RAD    T0 
          MJN    CDD2        IF .LT. 10D REMAINING
          LDD    HN          ADVANCE TENS DIGIT 
          RAM    CDDA 
          UJN    CDD1        LOOP FOR ALL MULTIPLES OF 10D
  
 CDD2     ADC    2R00+10D    ASSEMBLE TENS AND ONES DIGITS
 CDDA     EQU    *-1
          UJP    CDDX        RETURN 
 COMPCDD  SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CDD      EQU    /COMPCDD/CDD 
 QUAL$    ENDIF 
          ENDX
