COMPCDB 
COMMON
          CTEXT  COMPCDB - COUNT DEFERRED BATCH JOBS. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPCDB
          SPACE  4,10 
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       CDB - COUNT DEFERRED BATCH JOBS.
* 
*         M. J. CARIDDI.     81/08/26.
          SPACE  4,10 
***       *COMPCDB* COUNTS THE NUMBER OF *EJT* AND *QFT* ENTRIES, 
*         WHICH BELONG TO A SPECIFIED USER.  OWNERSHIP IS 
*         DETERMINED BY THE FAMILY ORDINAL AND USER INDEX 
*         IN THE *EJT* AND *QFT* ENTRY. 
 CDB      SPACE  4,10 
**        CDB - COUNT DEFERRED BATCH JOBS.
* 
*         *COMPCDB* (COUNT DEFERRED BATCH) COUNTS ALL THE *QFT* 
*         ENTRIES BELONGING TO THE SPECIFIED USER.
*         (EXCLUDING *TXOT* INPUT FILES), PLUS ALL OWNED *EJT*
*         ENTRIES WITH *NICS* (NON-INTERACTIVE) CONNECTION STATUS.
* 
*         ENTRY  (T2) = FO. (FAMILY ORDINAL)
*                (T2 - T3) = UI. (USER INDEX) 
* 
*         EXIT   (T4) = NUMBER OF *QFT* AND *EJT* ENTRIES, MEETING
*                THE ABOVE CRITERIA AND BELONGING TO THE USER.
* 
*         USES   T1, CM - CM+4. 
* 
*         CALLS  CMP. 
* 
*         XREF   COMSPIM, COMPMAC.
  
  
 CDB      SUBR               ENTRY/EXIT 
          LDN    0           INITIALIZE COUNTER 
          STD    T4 
          LDN    EJTP        GET MAXIMUM NUMBER OF *EJT* ENTRIES
          CRD    CM 
          AOM    CMPA        SET SEARCH *EJT* FLAG
          LDD    CM          SET FWA OF *EJT* TABLE 
          LMC    ADCI 
          STM    CMPC 
          LDD    CM+1 
          STM    CMPC+1 
          LDD    CM+2        SET NUMBER OF *EJT-S*
          STD    T1 
          RJM    CMP         COMPARE FO,UI
  
*         COUNT *QFT* ENTRIES.
  
          SOM    CMPA        FLAG NOT SEARCHING *QFT-S* 
          LDN    QFTP        GET MAXIMUM NUMBER OF *QFT* ENTRIES
          CRD    CM 
          LDD    CM 
          LMC    ADCI 
          STM    CMPB 
          LDD    CM+1 
          STM    CMPB+1 
          LDD    CM+2        SET NUMBER OF *QFT* ENTRIES
          STD    T1 
          RJM    CMP         COMPARE FO,UI
          LJM    CDBX        RETURN 
 CMP      SPACE  4,10 
**        CMP - COMPARE ENTRIES.
* 
*         ENTRY  (CMPA) = 0, IF SEARCH *QFT*. 
*                (CMPA) = 1, IF SEARCHING *EJT*.
*                (T1) = NUMBER OF ENTRIES.
*                (T2) = FO.  (FAMILY ORDINAL) 
*                (T2 - T3) = UI.  (USER INDEX)
*                (T4) = NUMBER OF ENTRIES THAT MATCHED. 
* 
*         EXIT   (T4) = ADVANCED, IF MATCH IS FOUND.
*                (A) = 0, IF SEARCH COMPLETE. 
* 
*         USES   T1, T4, CM - CM+4, CN - CN+4.
* 
*         MACROS CFI. 
  
  
 CMP5     SOD    T1          DECREMENT COUNTER
          NJN    CMP1        IF NOT END OF SEARCH 
  
 CMP      SUBR               ENTRY
 CMP1     LDN    0           SEARCH *QFT* 
*         LDN    1           SEARCH *EJT* 
 CMPA     EQU    *-1
          NJN    CMP2        IF SEARCHING *EJT-S* 
  
*         READ NEXT *QFT* ENTRY.
  
          CFI    QFT,T1      CALCULATE *QFT* ENTRY ADDRESS
          ADC    ** 
 CMPB     EQU    *-2         (FWA OF *QFT*) 
          ADK    JSNQ 
          CRD    CM 
          ADN    SCLQ 
          CRD    CN 
          LDD    CM 
          ZJN    CMP5        IF NO ENTRY
          LDD    CN          CHECK ORIGIN TYPE
          LPN    77 
          LMN    TXOT 
          NJN    CMP3        IF NOT A *TXOT* JOB
          LDD    CM+4        CHECK QUEUE TYPE 
          SHN    -11
          LMK    INQT 
          ZJN    CMP5        IF THIS IS A *TXOT* INPUT FILE 
          UJN    CMP3        COMPARE FO,UI
  
*         READ NEXT *EJT* ENTRY.
  
 CMP2     CFI    EJT,T1      CALCULATE *EJT* ENTRY ADDRESS
          ADC    ** 
 CMPC     EQU    *-2         (FWA OF *EJT*) 
          ADK    JSNE 
          CRD    CM 
          LDD    CM 
          ZJN    CMP4        IF NO *EJT* ENTRY
          LDD    CM+4        CHECK CONNECTION STATUS
          SHN    -7 
          LPN    17 
          LMK    NICS 
          NJN    CMP4        IF NOT *NON - INTERACTIVE* 
  
*         CHECK OWNERSHIP OF ENTRY. 
  
 CMP3     LDD    T2          CHECK QUEUED FILE OWNERSHIP
          LMD    CM+2 
          NJN    CMP4        IF NO MATCH
          LDD    T3 
          LMD    CM+3 
          NJN    CMP4        IF NO MATCH
          AOD    T4          INCREMENT JOB COUNT
 CMP4     LJM    CMP5        LOOP FOR NEXT TABLE ENTRY
          SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CDB      EQU    /COMPCDB/CDB 
 QUAL$    ENDIF 
          SPACE  4,10 
          ENDX
