COMDDSP 
COMMON
          CTEXT  COMDDSP - DISPLAY PROGRAM ROUTINES.
 COMDDSP  SPACE  4
          QUAL   COMDDSP
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMDDSP  SPACE  4
***       COMDDSP - DISPLAY PROGRAM ROUTINES. 
*         G. R. MANSFIELD.  70/09/13. 
 COMDDSP  SPACE  4
***              COMDDSP CONTAINS ROUTINES FOR ACCESSING THE SYSTEM 
*         DISPLAY CONSOLE.
 DDS      SPACE  4,10 
***       DDS - DROP DISPLAY. 
* 
*         ENTRY  (DDSA) = EST ORDINAL.
*                (DDSB) = CHANNEL.
* 
*         EXIT   (A) = (DDSA) = (DDSB) = 0. 
* 
*         USES   CM - CM+4. 
* 
*         MACROS DCHAN, MONITOR.
  
  
 DDS      SUBR               ENTRY/EXIT 
          LDC    0           RELEASE EQUIPMENT
 DDSA     EQU    *-1
          ZJN    DDSX        IF NOT ASSIGNED
          STD    CM+1 
          LDN    0
          STD    CM+2 
          MONITOR DEQM
          LDC    0           RELEASE CHANNEL
 DDSB     EQU    *-1
          ZJN    DDS1        IF CHANNEL ALREADY DROPPED 
          DCHAN 
*         LDN    0           CLEAR CHANNEL NUMBER 
          STM    DDSB 
 DDS1     STM    DDSA        CLEAR EST ORDINAL
          UJN    DDSX        RETURN 
 HDC      SPACE  4,10 
***       HDC - HOLD DISPLAY CHANNEL. 
* 
*         ENTRY  (DDSB) = DISPLAY CHANNEL.
* 
*         USES   T1.
* 
*         CALLS  RDC. 
* 
*         MACROS DCHAN. 
  
  
 HDC      SUBR               ENTRY/EXIT 
          LDM    DDSB        CHECK DISPLAY CHANNEL
          STD    T1 
          LMN    CH 
          NJN    HDCX        IF NOT ASSEMBLED CHANNEL 
          LDD    T1          RELEASE CHANNEL
          DCHAN 
          LDC    10000
          SBN    1
          NJN    *-1         IF NOT THROUGH WITH DELAY
          RJM    RDC         REQUEST DISPLAY CHANNEL
          UJN    HDCX        EXIT 
 PSS      SPACE  4,10 
***       PSS - PAUSE FOR SYSTEM. 
* 
*         EXIT   (CM - CM+4) = CONTROL POINT STATUS WORD *STSW*.
* 
*         CALLS  DDS, DPP.
  
  
 PSS      SUBR               ENTRY/EXIT 
          PAUSE 
          LDD    CM+1 
          LMN    ODET 
          ZJN    PSS1        IF OPERATOR DROP 
          LMN    SVET&ODET
          ZJN    PSSX        IF SECURITY VIOLATION, DO NOT DROP 
          LDD    CM+1 
          SBN    SPET 
          MJN    PSSX        IF NOT A DROPOUT CONDITION 
  
*         DROP DISPLAY AND PP FOR ALL ERRORS ABOVE AND
*         INCLUDING *ODET*. 
  
 PSS1     RJM    DDS         DROP DISPLAY 
          LJM    DPP         DROP PP
 RDS      SPACE  4
***       RDS - REQUEST DISPLAY.
* 
*         EXIT   (DDSA) = EST ORDINAL.
*                (DDSB) = CHANNEL NUMBER. 
* 
*         USES   CM - CM+4, T0 - T4.
* 
*         CALLS  RDC, ROF.
* 
*         MACROS DELAY, MONITOR, PAUSE, SFA.
* 
*         XREF   COMSCPS. 
  
  
 RDS      SUBR               ENTRY/EXIT 
 RDS1     RJM    ROF         CHECK ROLLOUT FLAG AND PAUSE 
          LDN    DSEQ 
          SFA    EST         FETCH EST ENTRY FOR DISPLAY CONSOLE
          ADK    EQDE 
          CRD    T0 
          LDD    CP          READ OPERATOR ASSIGNMENT 
          ADN    OAEW 
          CRD    CM 
          LDD    CM+4 
          LMN    DSEQ 
          NJN    RDS3        IF NO OPERATOR ASSIGNMENT
 RDS2     STD    CM+2 
          ERRNZ  REQS        CODE ASSUMES *REQS* = 0
          STD    T3 
          LDN    DSEQ        REQUEST ACTIVE EQUIPMENT 
          STD    CM+1 
          MONITOR REQM
          LDD    CM+1        CHECK IF ASSIGNMENT MADE 
          NJP    RDS4        IF CONSOLE ASSIGNED
          DELAY  250D*10
          PAUSE  NE 
 RDS3     LDD    T3 
          LMC    2RDS 
*         LMC    DSEQ        (AFTER INITIAL ASSIGNMENT) 
 RDSA     EQU    *-1
          NJN    RDS3.1      IF ENTRIES DO NOT MATCH
          LDD    T0 
          LPN    3
          ZJN    RDS2        IF CONSOLE *ON*
 RDS3.1   LDD    CP 
          ADN    SNSW 
          CRD    CM 
          LDD    CM+3 
          SCN    1
          LMN    1
          STD    CM+3 
          LDD    CP 
          ADN    SNSW 
          CWD    CM 
          ADN    MS2W-SNSW
          CWM    RDSB,TR
          LJM    RDS1        LOOP 
  
*         EQUIPMENT ASSIGNED OR FOUND.
  
 RDS4     LDN    DSEQ        SET EQUIPMENT
          STM    DDSA 
          STM    RDSA 
          ERRZR  DSEQ        CODE DEPENDS ON VALUE
          LDD    CP 
          ADN    OAEW 
          CRD    CM 
          LDN    0
          STD    CM+4 
          LDD    CP          CLEAR OPERATOR ASSIGNMENT
          ADN    OAEW 
          CWD    CM 
          ADN    MS2W-OAEW   CLEAR CP MESSAGE 
          CWD    CM+4 
          SBN    MS2W-SNSW   READ SWITCH WORD 
          CRD    CM 
          LDD    CM+3        CLEAR PAUSE BIT
          SCN    1
          STD    CM+3 
          LDD    CP          STORE SWITCH WORD
          ADN    SNSW 
          CWD    CM 
          RJM    RDC
          LJM    RDSX        RETURN 
  
 RDSB     DATA   C*REQUEST DISPLAY.  ("NAME")*
 RDC      SPACE  4,10 
**        RDC - REQUEST DISPLAY CHANNEL.
* 
*         ENTRY  (T1) = CHANNEL.
* 
*         EXIT   CHANNEL ASSIGNED.
* 
*         USES   CM+1.
* 
*         CALLS  ROF. 
  
  
 RDC      SUBR
 RDC1     LDD    T1          CHECK CHANNEL
          LPN    77 
          STD    CM+1 
          STM    DDSB 
          MONITOR CCHM
          LDD    CM+2 
          NJN    RDCX        IF CHANNEL ASSIGNED
          STM    DDSB 
          RJM    ROF
          UJN    RDC1        LOOP 
 ROF      SPACE  4
***       ROF - CHECK ROLLOUT FLAG. 
* 
*         ENTRY  (ROFA)      MUST BE PRESET IF CALLING PROGRAM WANTS
*         CONTROL ON A ROLLOUT FLAG.  OTHERWISE THE OPERATOR DROP 
*         ERROR FLAG WILL BE SET. 
* 
*         USES   CM - CM+4. 
* 
*         CALLS  PSS. 
* 
*         MACROS MONITOR. 
  
  
 ROF1     LDN    ZERL        SET OPERATOR DROP ERROR FLAG 
          CRD    CM 
          LDN    ODET 
          STD    CM+1 
          MONITOR CEFM
  
 ROF      SUBR               ENTRY/EXIT 
          RJM    PSS         PAUSE
          LDD    CM+2 
          LPN    1
          ZJN    ROFX        IF NO ROLLOUT FLAG SET 
          LJM    ROF1        SET OPERATOR DROP ERROR FLAG 
 ROFA     EQU    *-1
          SPACE  4
          QUAL   *
 DDS      EQU    /COMDDSP/DDS 
 HDC      EQU    /COMDDSP/HDC 
 PSS      EQU    /COMDDSP/PSS 
 RDS      EQU    /COMDDSP/RDS 
 RDSOS    EQU    RDS-HDC     *RDS* OFFSET FROM *HDC*
          ENDX
