COMCZTB 
COMMON
          CTEXT  COMCZTB - CONVERT ZEROES TO BLANKS IN A WORD.
          IF     -DEF,QUAL$,1 
          QUAL   COMCZTB
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 ZTB      SPACE  4
***       ZTB - CONVERT ZEROES TO BLANKS IN A WORD. 
*         G. R. MANSFIELD.   70/12/08.
*         S. R. MCPHERSON.   74/11/15.
 ZTB      SPACE  4
***       ZTB - CONVERTS ZERO TO BLANKS IN A WORD.
* 
*         ENTRY  (X1) = NAME LEFT JUSTIFIED, ZERO FILL. 
*                (B1) = 1.
* 
*         EXIT   (X6) = NAME SPACE FILLED.
*                (X7) = FINAL CHARACTER MASK. 
* 
*         USES   X - 3, 6, 7. 
*                A - 3. 
  
  
 ZTB      PS                 ENTRY/EXIT 
          SA3    ZTBA 
          BX6    X3*X1       EXTRACT UPPER BIT FROM ALL CHARACTERS
          BX7    -X3*X1 
          IX6    X6+X3       ANY NON-ZERO CHARACTER PRODUCES CARRY
          BX6    X6+X7       MERGE UPPER BITS AND CARRIES 
          BX7    -X3*X6      ALL NON ZERO CHARACTERS = 40B
          SA3    A3+B1
          BX6    X7 
          LX7    -5          GENERATE SPACE MASK
          IX7    X6-X7
          BX7    X6+X7
          BX3    -X7*X3      SELECT SPACE CODES 
          BX6    X1+X3       MERGE ORIGINAL DATA WITH SPACES
          EQ     ZTB
  
 ZTBA     CON    37373737373737373737B
          CON    1H 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 ZTB      EQU    /COMCZTB/ZTB 
 QUAL$    ENDIF 
          ENDX
