COMCSTF 
COMMON
          CTEXT  COMCSTF - SET TERMINAL FILE. 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   COMCSTF
 QUAL$    ENDIF 
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4
***       STF - SET TERMINAL OUTPUT FILE
*         J. L.  WARDELL     71/01/29.
*         R. E.  TATE        73/04/08.
          SPACE  4
***          *STF* DETERMINES WHETHER A FILE IS OR WILL BE
*         ASSIGNED TO AN INTERACTIVE TERMINAL (DEVICE TYPE *TT*). 
* 
*         ENTRY  (X2) = ADDRESS OF FET. 
*                FET MUST BE GREATER THAN FIVE WORDS IN LENGTH. 
* 
*         EXIT   (X6) = 0 IF FILE IS TERMINAL FILE. 
*                (X6) = 1 IF NULL FILE OR NOT TERMINAL FILE.
*                (X2) = ADDRESS OF FET. 
* 
*         USES   A - 1, 6.
*                X - 1, 6.
* 
*         MACROS OPEN.
  
  
 STF      PS                 ENTRY/EXIT 
          SA1    X2          CHECK FILE NAME AND STATUS 
          SX6    1
          BX6    X6+X1       SET PREVIOUS STATUS COMPLETE 
          ZR     X1,STF      IF NULL FILE, RETURN 
          SA6    STFA 
          OPEN   X2,ALTERNR,R  ISSUE *OPEN* REQUEST 
          SA1    STFA        RESTORE PREVIOUS FUNCTION CODE 
          BX6    X1 
          SA6    X2 
          SA1    X2+1        CHECK DEVICE TYPE
          AX1    48 
          SX6    X1-2RTT     (X6) = ZERO IF TYPE *TT* 
 STF1     ZR     X6,STF      IF TERMINAL FILE 
          SX6    1
          EQ     STF         RETURN 
  
 STFA     CON    0           SAVE FET FUNCTION CODE 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 STF      EQU    /COMCSTF/STF 
 QUAL$    ENDIF 
          ENDX
