COMCSOE 
COMMON
          CTEXT  COMCSOE - SET OPTICAL DISK EXTENSION BUFFER ADDRESS. 
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SOE      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCSOE
          BASE   D
 SOE      SPACE  4
***       SOE - SET OPTICAL DISK EXTENSION BUFFER ADDRESS.
*         J. M. CYCHOSZ.     90/09/27.
 SOE      SPACE  4
***              SOE SETS THE OPTICAL DISK EXTENSION BUFFER POINTER 
*         IN THE FET IF THE FILE IS RESIDENT ON OPTICAL DISK. 
* 
* 
*         ENTRY  (X2) = ADDRESS OF FET. 
*                (X3) = OPTICAL DISK EXTENSION BUFFER POINTER DATA. 
*                     = 6/ LEN, 18/ FWA OF BUFFER.
* 
*         EXIT   (X1) = 0 IF FILE IS ASSIGNED TO OPTICAL DISK.
*                (X2) = ADDRESS OF FET. 
* 
*         USES   X - 1, 2, 6, 7.
*                A - 1, 6.
*                B - 7. 
* 
*         MACROS FILINFO. 
  
  
 SOE      SUBR               ENTRY/EXIT 
          SA1    X2          GET FILE NAME
          SB7    X2          SAVE FET ADDRESS 
          MX6    42 
          BX6    X1*X6
          SX7    50001B 
          BX6    X6+X7       MERGE FILE NAME/LENGTH/COMPLETE BIT
          SA6    SOEA        SET FILE NAME IN PARAMETER BLOCK 
          FILINFO A6         GET FILE INFORMATION 
          SA1    SOEA+1      GET DEVICE TYPE
          SX2    B7          RESTORE FET ADDRESS
          AX1    48 
          SX1    X1-2ROD     OPTICAL DISK DEVICE TYPE 
          NZ     X1,SOEX     RETURN, IF NOT OPTICAL DISK
          BX6    X3          SET POINTER WORD 
          SA6    X2+11B 
          EQ     SOEX        RETURN 
  
 SOEA     BSSZ   5           *FILINFO* PARAMETER BLOCK
          SPACE  4
          BASE   *
          IF     -DEF,QUAL$,2 
          QUAL   *
 SOE      EQU    /COMCSOE/SOE 
          ENDX
