COMCPFU 
COMMON
          CTEXT  COMCPFU - PERMANENT FILE UTILITY FUNCTION PROCESSOR. 
          SPACE  4
          IF -DEF,QUAL$,1 
          QUAL   COMCPFU
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4
***       PFU - PERMANENT FILE UTILITY FUNCTION PROCESSOR.
*         R. J. THIELEN.     75/08/01.
          SPACE  4
***              PFU PERFORMS PERMANENT FILE UTILITY FUNCTIONS VIA THE
*         PPU PROGRAM *PFU*.  *PFU* IS CALLED WHEN THE FET IS NON BUSY. 
* 
*         ENTRY  (X2) = FET ADDRESS.
*                (X7) = *PFU* FUNCTION CODE.
*                       IF (X7) .LT. 0, (X7) IS COMPLEMENT OF FUNCTION
*                       CODE AND *PFU* IS CALLED WITH AUTO RECALL.
* 
*         EXIT   (X2) = FET ADDRESS.
* 
*         USES   A - 1, 7.
*                X - 1, 6, 7. 
* 
*         CALLS  SYS=.
  
  
 PFU      SUBR               ENTRY/EXIT 
          RECALL X2          WAIT FOR FET NON BUSY
          SA1    X2          GET FET STATUS 
          LX7    18 
          SX6    3RPFU       SET PFU REQUEST
          PL     X7,PFU1     IF NO AUTO RECALL WITH REQUEST 
          BX7    -X7
          PX6    X6          SET AUTO RECALL
 PFU1     BX7    X7+X2       ADD PARAMETERS TO REQUEST
          LX6    42 
          BX6    X6+X7
          MX7    59          SET FET STATUS BUSY
          BX7    X7*X1
          SA7    A1 
          RJ     =XSYS=      ISSUE SYSTEM REQUEST FOR PFU 
          EQ     PFUX        EXIT 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 PFU      EQU    /COMCPFU/PFU 
 QUAL$    ENDIF 
          ENDX
