COMCPFM 
COMMON
          CTEXT  COMCPFM - PERMANENT FILE PROCESSOR.
 PFM      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCPFM
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 PFM      SPACE  4
***       PFM - PERMANENT FILE PROCESSOR. 
*         G. R. MANSFIELD.  70/10/09. 
 PFM      SPACE  4
***              PFM PERFORMS PERMANENT FILE ACTION FUNCTIONS VIA 
*         CALLS TO THE PP PROGRAM *PFM*.  THE OPERATION WILL BE 
*         PROCESSED WHEN THE BUFFER IS NOT BUSY.  IF FILE STATUS
*         WORD = 0, THE FUNCTION WILL NOT BE PROCESSED. 
* 
*         AUTO RECALL IS FORCED FOR ALL *PFM* REQUESTS EXCEPT 
*         *UGET* AND *UREPLACE*.
* 
*         ENTRY  (X2) = ADDRESS OF FET FOR FILE.
*                (X7) = FUNCTION CODE.
* 
*         EXIT   (X2) = ADDRESS OF FET FOR FILE.
* 
*         USES   X - 1, 2, 6, 7.
*                B - NONE.
*                A - 1. 
* 
*         CALLS  SYS=.
  
  
 PFM3     RJ     =XSYS= 
  
 PFM=     PS                 ENTRY/EXIT 
          SA1    X2          CHECK BUFFER STATUS
          LX1    59 
          NG     X1,PFM1     IF BUFFER NOT BUSY 
          ZR     X1,PFM=     IF BLANK FILE STATUS 
          RECALL X2 
 PFM1     SA1    X2          SET FET BUSY 
          MX6    59 
          BX6    X6*X1
          SA6    X2 
          SA1    PFMA        FORM CALL
          BX6    X1+X2
          SX1    X7-24B 
          ZR     X1,PFM2     IF *UGET* REQUEST
          SX1    X7-25B 
          ZR     X1,PFM2     IF *UREPLACE* REQUEST
          MX1    1           SET AUTORECALL BIT 
          LX1    40-59
          BX6    X6+X1
 PFM2     LX7    24          ADD REQUEST CODE TO CALL 
          BX6    X6+X7
          EQ     PFM3        PROCESS REQUEST
  
 PFMA     CON    0LPFM
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 PFM=     EQU    /COMCPFM/PFM=
 QUAL$    ENDIF 
          ENDX
