COMCOVL 
COMMON
          CTEXT  COMCOVL - OVERLAY LOAD PROCESSOR.
 OVL      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCOVL
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 OVL      SPACE  4
***       OVL - OVERLAY LOAD PROCESSOR. 
*         G. R. MANSFIELD.  70/12/20. 
 OVL      SPACE  4
***              OVL REQUESTS THE PP PROGRAM *LDR* TO LOAD A
*         SPECIFIED OVERLAY.
* 
*         ENTRY  (X1) = FILE/OVERLAY NAME.
*                (X2) = FWA FOR OVERLAY.
*                (X6) = LEVELS AND SYSTEM REQUEST BITS. 
* 
*         EXIT   (X1) = ENTRY ADDRESS.
* 
*         USES   X - 1, 2, 6. 
*                B - NONE.
*                A - 1, 2, 6. 
* 
*         CALLS  SYS=.
  
  
 OVL1     BX6    X1 
          RJ     =XSYS= 
          SA2    OVLB+1      SET ENTRY ADDRESS
          SX1    X2+
  
 OVL=     PS                 ENTRY/EXIT 
          LX6    42          SET WORD 2 
          BX6    X6+X2
          MX2    1
          LX2    42 
          BX6    X6+X2
          SA6    OVLB+1 
          BX6    X1          SET WORD 1 
          SA6    OVLB 
          SA1    OVLA 
          EQ     OVL1 
  
 OVLA     VFD    24/0LLDRP,18/0,18/OVLB 
  
 OVLB     CON    0,0
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 OVL=     EQU    /COMCOVL/OVL=
 QUAL$    ENDIF 
          ENDX
