COMCLFM 
COMMON
          CTEXT  COMCLFM - LOCAL FILE MANAGER PROCESSOR.
 LFM      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCLFM
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 LFM      SPACE  4
***       LFM - LOCAL FILE MANAGER PROCESSOR. 
*         G. R. MANSFIELD.  70/10/09. 
 LFM      SPACE  4
***              LFM PROCESSES REQUESTS FOR THE LOCAL FILE MANAGER PP 
*         PROGRAM *LFM*.
*         IF THE SPECIFIED FET IS BUSY, A FILE RECALL IS PERFORMED. 
*         IF THE SPECIFIED FET IS BLANK, LFM RETURNS WITH NO ACTION 
*         TAKEN.
* 
*         ENTRY  (X2) = ADDRESS OF FET. 
*                (X7) = FUNCTION CODE.
* 
*         EXIT   (X2) = ADDRESS OF FET. 
* 
*         USES   X - 1, 6, 7. 
*                B - NONE.
*                A - 1. 
* 
*         CALLS  SYS=.
  
  
 LFM2     RJ     =XSYS= 
  
 LFM=     PS                 ENTRY/EXIT 
          SA1    X2          CHECK FILE STATUS
          LX1    59 
          NG     X1,LFM1     IF NOT BUSY
          ZR     X1,LFM=     RETURN IF BLANK FET
          RECALL X2 
 LFM1     SA1    X2          SET FET BUSY 
          MX6    59 
          BX6    X6*X1
          SA6    A1 
          SA1    LFMA        SET *LFM* REQUEST
          LX7    24 
          BX1    X1+X7
          BX6    X1+X2
          EQ     LFM2 
  
 LFMA     CON    0LLFM+1S40 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 LFM=     EQU    /COMCLFM/LFM=
 QUAL$    ENDIF 
          ENDX
