COMCIQP 
COMMON
          CTEXT  COMCIQP - IQFT FILE PROCESSORS.
          SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCIQP
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 IQP      SPACE  4
***       COMCIQP - IQFT FILE PROCESSORS. 
*         A. J. BEEKMAN.     76/02/27.
          SPACE  4
***       COMCIQP CONTAINS ROUTINES THAT RETURN AND ATTACH
*         IQFT FILES.  THIS COMMON DECK REQUIRES COMMON DECKS 
*         COMSIOQ AND COMCQFM.
          SPACE  4
***       ENTRY CONDITIONS. 
* 
*         THE FOLLOWING ADDRESSES ARE REQUIRED BY CERTAIN ROUTINES
*         IN THIS COMMON DECK - 
* 
*                IBUFL - DEFAULT IQFT BUFFER LENGTH.
*                BUFFL - DEFAULT END OF PROGRAM BUFFERS LENGTH. 
 ATT      SPACE  4,20 
**        ATT - ATTACH IQFT FILE. 
* 
*         ATTACH THE IQFT FILE AND POSITION THE FILE AT EOI.
* 
*         ENTRY  (X2) = EST ORDINAL.
*                (X3) = IQFT FET ADDRESS. 
* 
*         EXIT   (X2) = IQFT FET ADDRESS. 
*                (X5) = 0 IF FILE ATTACHED SUCCESSFULLY.
*                     .NE. 0 IF ERROR IN FILE ATTACH. 
* 
*         USES   X - 0, 1, 2, 5, 6, 7.
*                A - 5, 6, 7. 
* 
*         MACROS QCALL. 
* 
*         XREF   COMCQFM, COMSIOQ.
  
  
 ATT      SUBR               ENTRY/EXIT 
          MX0    12 
          LX2    48          EST ORDINAL
          SA5    X3+7 
          SX1    IQFT*10000B SET SUBFUNCTION FOR IQFT 
          BX5    -X0*X5 
          LX0    24 
          IX6    X2+X5
          BX6    -X0*X6 
          IX6    X6+X1
          SA6    A5 
  
*         ATTACH IQFT FILE. 
  
          SX0    36000B      CLEAR ERROR FLAGS
          SA5    X3 
          BX7    -X0*X5 
          SA7    A5 
          QCALL  ATQF,X3     ATTACH FILE
          SA5    A5 
          BX5    X0*X5
          NZ     X5,ATTX     IF ERROR IN ATTACHING FILE 
          SX6    B1+
          SA6    ATTA        FLAG FILE ATTACH 
          EQ     ATTX 
  
 ATTA     CON    0           FILE ATTACHED FLAG 
 RAF      SPACE  4,20 
**        RAF - RETURN ATTACHED IQFT FILE.
* 
*         RELEASE ATTACHED IQFT FILES IF PRESENT. 
* 
*         ENTRY  (X3) = IQFT FET ADDRESS. 
*                (ATTA) .NE. 0 IF IQFT FILE ATTACHED. 
* 
*         EXIT   (X3) = IQFT FET ADDRESS. 
*                (ATTA) = 0.
*                FILE RETURNED IF PRESENT.
* 
*         USES   X - 5, 6.
*                A - 5, 6.
* 
*         MACROS QCALL. 
* 
*         XREF   COMCQFM, COMSIOQ.
  
  
 RAF      SUBR               ENTRY/EXIT 
          SA5    ATTA 
          ZR     X5,RAFX     IF NO FILE ATTACHED
          QCALL  DTQF,X3     RETURN IQFT FILE 
          BX6    X6-X6       CLEAR FLAG 
          SA6    A5 
          EQ     RAFX 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 ATT      EQU    /COMCIQP/ATT 
 ATTA     EQU    /COMCIQP/ATTA
 RAF      EQU    /COMCIQP/RAF 
 QUAL$    ENDIF 
          ENDX
