COMCEDT 
COMMON
          CTEXT  COMCEDT - EDIT DATE OR TIME FROM PACKED FORMAT.
          SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCEDT
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4
***       EDT - EDIT DATE OR TIME FROM PACKED FORMAT. 
*         D. A. HIVELEY.  71/01/13. 
          SPACE  4
***              EDT EDITS A 19 BIT PACKED DATE OR TIME INTO
*         A 10 CHARACTER, DECIMAL DISPLAY, EDITED DATE OR TIME. 
* 
*         ENTRY  (X1) = PACKED NUMBER (LOWER 19 BITS).
*                (X2) = SEPARATOR CHARACTER.
*                        */* FOR DATE.
*                        *.* FOR TIME.
* 
*         EXIT   (X6) = EDITED DATE OR TIME.
*                        TIME = * HH.MM.SS.*. 
*                        DATE = * YY/MM/DD.*. 
* 
*         CALLS  CDD. 
* 
*         USES   A  1,2,3,6,7.
*                X  2,3,6,7.
*                B  NONE. 
  
  
 EDT      PS                 ENTRY/EXIT 
          SX3    1R          SET SEPARATORS IN MASK 
          LX2    18 
          LX3    54 
          BX6    X3+X2
          LX2    18 
          BX6    X6+X2
          LX1    48 
          SX3    1R.
          BX6    X6+X3
          MX3    -9          PICK OFF FIRST FIELD 
          SA6    EDTA 
          BX7    X1 
          BX1    -X3*X1 
          SA7    EDTB 
          RJ     CDD         CONVERT TO DECIMAL DISPLAY 
          MX2    -12
          BX6    -X2*X6 
          SA6    EDTC 
          SA1    A7          PICK OFF SECOND FIELD
          MX2    -6 
          LX1    6
          BX3    -X2*X1 
          SX1    X3+100 
          RJ     CDD         CONVERT TO DECIMAL DISPLAY 
          SA1    A6 
          LX1    18 
          MX3    -12
          BX6    -X3*X6 
          BX6    X1+X6
          SA1    A7          PICK OFF THIRD FIELD 
          LX6    18 
          MX2    -6 
          SA6    A6 
          LX1    12 
          BX3    -X2*X1 
          SX1    X3+100 
          RJ     CDD         CONVERT TO DECIMAL DISPLAY 
          SA1    A6 
          MX3    -12
          BX6    -X3*X6 
          BX6    X6+X1
          SA1    EDTA        BOOLEAN IN PUNCTUATION 
          LX6    6
          BX6    X6+X1
          EQ     EDT         RETURN 
  
  
 EDTA     BSS    1           MASK HOLD AREA 
 EDTB     BSS    1           PACKED DATA HOLD AREA
 EDTC     BSS    1           DISPLAY DATA HOLD AREA 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 EDT      EQU    /COMCEDT/EDT 
 QUAL$    ENDIF 
          ENDX
