COMCCVI 
COMMON
          CTEXT  COMCCVI - USER CONTROL LIMIT FORMULAE. 
 COMCCVI  SPACE  4
          BASE   DECIMAL
          IF     -DEF,QUAL$,1 
          QUAL   COMCCVI
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMCCVI  SPACE  4
***       COMCCVI - USER CONTROL LIMIT FORMULAE.
*         R. A. JAPS.        74/09/24.
 COMCCVI  SPACE  4
***       COMCCVI DEFINES THE FORMULAE FOR CONVERTING FROM AN INDEX 
*         VALUE INTO THE ACTUAL LIMIT VALUE FOR THE FOLLOWING SYSTEM
*         RESOURCES OR ACTIVITIES THAT INSTALLATIONS MAY CONTROL -
*                DT   NUMBER OF DETACHED JOBS 
*                DB   DEFERRED BATCH JOBS 
*                TL   TIME LIMIT (UNITS OF 10B) 
*                CM   FIELD LENGTH
*                PT   UNITS PLOTTED 
*                CP   CARDS PUNCHED 
*                LP   LINES PRINTED 
*                MS   MASS STORAGE PRUS 
*                DF   DAYFILE MESSAGES
*                CC   CONTROLCARD STATMENTS 
*                EC   EXTENDED MEMORY FIELD LENGTH
*                SL   SRU LIMIT (UNITS OF 10B)
*                DS   DIRECT ACCESS FILE SIZE 
*                FS   INDIRECT ACCESS FILE SIZE 
*                CS   CUMULATIVE FILE SIZE
*                FC   PERMANENT FILE COUNT
* 
* 
*         THE FORMULA WILL BE ASSEMBLED IF XXI$ IS DEFINED IN THE 
*         CALLING PROGRAM, WHERE XX IS ONE OF THE LIMIT MNEMONICS.
*         FOR EXAMPLE, THE DEFINITION NFI$ WILL CAUSE THE FORMULA 
*         FOR THE NUMBER OF LOCAL FILES TO BE ASSEMBLED.
* 
*         ALL FORMULAE HAVE THE FOLLOWING ENTRY/EXIT CONDITIONS.
* 
*         ENTRY  (X1) = INDEX VALUE RIGHT JUSTIFIED.
* 
*         EXIT   (X1) = LIMIT VALUE.
*                (X1) .LT. 0,  IF VALUE IS UNLIMITED. 
* 
*         USES   X - 0, 1, 2. 
*                A - 1. 
*                B - 2. 
* 
* 
*         NOTE - THIS COMMON DECK REQUIRES THAT *COMSACC* AND *COMSPFM* 
*         BE PRESENT SO THAT LIMIT BASE CONSTANTS AND PERMANENT FILE
*         CONSTANTS ARE AVAILABLE.
 CCI      SPACE  4,3
**        CCI - CONTROL CARD STATMENTS. 
* 
*         FORMULA IS -  (I * 100B) + KCCI 
  
  
 CCI      IF     DEF,CCI$ 
  
 CCI1     LX1    6           SET VALUE
          SX2    KCCI 
          IX1    X1+X2
  
 CCI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,CCI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     CCIX        RETURN 
  
 CCI      ENDIF 
 CMI      SPACE  4,3
**        CMI - CM FIELD LENGTH.
* 
*         FORMULA IS -  (I * 40B) + KCMI
  
  
 CMI      IF     DEF,CMI$ 
  
 CMI1     LX1    5           SET VALUE
          SX2    KCMI 
          IX1    X1+X2
  
 CMI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,CMI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     CMIX        RETURN 
  
 CMI      ENDIF 
 CPI      SPACE  4,3
**        CPI - CARDS PUNCHED.
* 
*         FORMULA IS -  (I * 100B) + KCPI 
  
  
 CPI      IF     DEF,CPI$ 
  
 CPI1     LX1    6           SET VALUE
          SX2    KCPI 
          IX1    X1+X2
  
 CPI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,CPI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     CPIX        RETURN 
  
 CPI      ENDIF 
 CSI      SPACE  4,3
**        CSI - CUMULATIVE FILE SIZE. 
* 
*         VALUE FOUND BY TABLE LOOK-UP METHOD.
  
  
 CSI      IF     DEF,CSI$ 
  
 CSI      SUBR               ENTRY/EXIT 
          MX0    -3 
          BX1    -X0*X1 
          SA1    X1+THCS
          EQ     CSIX        RETURN 
  
  
**        THCS - EQUIVALENCE TABLE FOR CUMULATIVE NUMBER OF 
*         SECTORS FOR ALL INDIRECT ACCESS FILES.
  
 THCS     BSS    0
          LOC    0
          CON    0
          CON    CSRNG1*100B
          CON    CSRNG2*100B
          CON    CSRNG3*100B
          CON    CSRNG4*100B
          CON    CSRNG5*100B
          CON    CSRNG6*100B
          CON    -1 
          LOC    *O 
  
 CSI      ENDIF 
 DBI      SPACE  4,3
**        DBI - DEFERRED BATCH JOB. 
* 
*         FORMULA IS -  (2 ** I)
*         EXCEPTION - ENTRY OF ZERO RETURNS ZERO. 
  
  
 DBI      IF     DEF,DBI$ 
  
 DBI      SUBR               ENTRY/EXIT 
          MX0    -3 
          BX1    -X0*X1 
          ZR     X1,DBIX     IF ZERO INDEX
          SB2    X1 
          SX2    X1-7 
          SX1    1
          LX1    B2,X1       SET VALUE
          NZ     X2,DBIX     IF NOT UNLIMITED 
          SX1    -1 
          EQ     DBIX        RETURN 
  
 DBI      ENDIF 
 DFI      SPACE  4,3
**        DFI - DAYFILE MESSAGES. 
* 
*         FORMULA IS -  (I * 100B) + KDFI 
  
  
 DFI      IF     DEF,DFI$ 
  
 DFI1     LX1    6           SET VALUE
          SX2    KDFI 
          IX1    X1+X2
  
 DFI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,DFI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     DFIX        RETURN 
  
 DFI      ENDIF 
 DSI      SPACE  4,3
**        DSI - DIRECT ACCESS FILE SIZE.
* 
*         VALUE FOUND BY TABLE LOOK-UP METHOD.
  
  
 DSI      IF DEF,DSI$ 
  
 DSI      SUBR               ENTRY/EXIT 
          MX0    -3 
          BX1    -X0*X1 
          SA1    X1+THDS
          EQ     DSIX        RETURB 
  
  
**        THDS - EQUIVALENCE TABLE FOR MAXIMUM NUMBER OF SECTORS
*         FOR ANY SINGLE DIRECT ACCESS PERMANENT FILE.
  
 THDS     BSS    0
          LOC    0
          CON    0
          CON    DSRNG1*100B
          CON    DSRNG2*100B
          CON    DSRNG3*100B
          CON    DSRNG4*100B
          CON    DSRNG5*100B
          CON    DSRNG6*100B
          CON    -1 
          LOC    *O 
  
 DSI      ENDIF 
**        DTI - NUMBER OF DETACHED JOBS.
* 
*         FORMULA IS - (I + KDTI).
  
  
 DTI      IF     DEF,DTI$ 
  
 DTI1     SX2    KDTI        ADD VALUE
          IX1    X1+X2
  
 DTI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,DTI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     DTIX        RETURN 
  
 DTI      ENDIF 
 ECI      SPACE  4,3
**        ECI - EXTENDED MEMORY FIELD LENGTH IN 1000B WORD BLOCKS.
* 
*         FORMULA IS - (I * 20B) + KECI 
  
  
 ECI      IF     DEF,ECI$ 
  
 ECI1     LX1    4           SET VALUE
          SX2    KECI 
          IX1    X1+X2
  
 ECI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,ECI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     ECIX        RETURN 
  
 ECI      ENDIF 
 FCI      SPACE  4,3
**        FCI - PERMANENT FILE COUNT. 
* 
*         VALUE FOUND BY TABLE LOOK-UP METHOD.
 FCI      IF     DEF,FCI$ 
  
 FCI      SUBR               ENTRY/EXIT 
          MX0    -3 
          BX1    -X0*X1 
          SA1    X1+THFC
          EQ     FCIX        RETURN 
  
  
**        THFC - EQUIVALENCE TABLE FOR MAXIMUM NUMBER OF INDIRECT 
*                ACCESS PERMANENT FILES.
  
 THFC     BSS    0
          LOC    0
          CON    0
          CON    NFRNG1*10B 
          CON    NFRNG2*10B 
          CON    NFRNG3*10B 
          CON    NFRNG4*10B 
          CON    NFRNG5*10B 
          CON    NFRNG6*10B 
          CON    -1 
          LOC    *O 
  
 FCI      ENDIF 
 FSI      SPACE  4,3
**        FSI - INDIRECT FILE SIZE. 
* 
*         VALUE FOUND BY TABLE LOOK-UP METHOD.
  
  
 FSI      IF     DEF,FSI$ 
  
 FSI      SUBR               ENTRY/EXIT 
          MX0    -3 
          BX1    -X0*X1 
          SA1    X1+THFS
          EQ     FSIX        RETURN 
  
  
**        THFS - EQUVALENCE TABLE FOR MAXIMUM NUMBER OF SECTORS 
*                FOR ANY SINGLE INDIRECT ACCESS FILE
  
 THFS     BSS    0
          LOC    0
          CON    0
          CON    FSRNG1*10B 
          CON    FSRNG2*10B 
          CON    FSRNG3*10B 
          CON    FSRNG4*10B 
          CON    FSRNG5*10B 
          CON    FSRNG6*10B 
          CON    -1 
          LOC    *O 
  
 FSI      ENDIF 
 LPI      SPACE  4,3
**        LPI - LINES PRINTED.
* 
*         FORMULA IS - (I * 2000B) + KLPI 
  
  
 LPI      IF     DEF,LPI$ 
  
 LPI1     LX1    10          SET VALUE
          SX2    KLPI 
          IX1    X1+X2
  
 LPI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,LPI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     LPIX        RETURN 
  
 LPI      ENDIF 
 MSI      SPACE  4,3
**        MSI - MASS STORAGE PRUS.
* 
*         FORMULA IS -  (I * 10000B) + KMSI 
  
  
 MSI      IF     DEF,MSI$ 
  
 MSI1     LX1    12          SET VALUE
          SX2    KMSI 
          IX1    X1+X2
  
 MSI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,MSI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     MSIX        RETURN 
  
 MSI      ENDIF 
 PTI      SPACE  4,10 
**        PTI - UNITS PLOTTED.
* 
*         FORMULA IS - ( I * 2000B ) + KPTI 
  
  
 PTI      IF     DEF,PTI$ 
  
 PTI1     LX1    10          SET VALUE
          SX2    KPTI 
          IX1    X1+X2
  
 PTI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,PTI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     PTIX        RETURN 
  
 PTI      ENDIF 
 SLI      SPACE  4,3
**        SLI - SRU LIMIT.
* 
*         FORMULA IS -  ((I**2)*10B) + KSLI 
* 
*         EXIT   (X1) = LIMIT VALUE/10B.
  
  
 SLI      IF     DEF,SLI$ 
  
 SLI1     IX1    X1*X1       SET VALUE
          LX1    3
          SX2    KSLI 
          IX1    X1+X2
  
 SLI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-73B 
          NG     X2,SLI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     SLIX        RETURN 
  
 SLI      ENDIF 
 TLI      SPACE  4,3
**        TLI - TIME LIMIT. 
* 
*         FORMULA IS -  (I * 100B) + KTLI 
* 
*         EXIT   (X1) = LIMIT VALUE/10B.
  
  
 TLI      IF     DEF,TLI$ 
  
 TLI1     LX1    6           SET VALUE
          SX2    KTLI 
          IX1    X1+X2
  
 TLI      SUBR               ENTRY/EXIT 
          MX0    -6 
          BX1    -X0*X1 
          SX2    X1-77B 
          NZ     X2,TLI1     IF NOT UNLIMITED 
          SX1    -1 
          EQ     TLIX        RETURN 
  
 TLI      ENDIF 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CCI$     IF     DEF,CCI$ 
 CCI      EQU    /COMCCVI/CCI 
 CCI$     ENDIF 
 CMI$     IF     DEF,CMI$ 
 CMI      EQU    /COMCCVI/CMI 
 CMI$     ENDIF 
 CPI$     IF     DEF,CPI$ 
 CPI      EQU    /COMCCVI/CPI 
 CPI$     ENDIF 
 CSI$     IF     DEF,CSI$ 
 CSI      EQU    /COMCCVI/CSI 
 CSI$     ENDIF 
 DBI$     IF     DEF,DBI$ 
 DBI      EQU    /COMCCVI/DBI 
 DBI$     ENDIF 
 DFI$     IF     DEF,DFI$ 
 DFI      EQU    /COMCCVI/DFI 
 DFI$     ENDIF 
 DSI$     IF     DEF,DSI$ 
 DSI      EQU    /COMCCVI/DSI 
 DSI$     ENDIF 
 DTI$     IF     DEF,DTI$ 
 DTI      EQU    /COMCCVI/DTI 
 DTI$     ENDIF 
 ECI$     IF     DEF,ECI$ 
 ECI      EQU    /COMCCVI/ECI 
 ECI$     ENDIF 
 FCI$     IF     DEF,FCI$ 
 FCI      EQU    /COMCCVI/FCI 
 FCI$     ENDIF 
 FSI$     IF     DEF,FSI$ 
 FSI      EQU    /COMCCVI/FSI 
 FSI$     ENDIF 
 LPI$     IF     DEF,LPI$ 
 LPI      EQU    /COMCCVI/LPI 
 LPI$     ENDIF 
 MSI$     IF     DEF,MSI$ 
 MSI      EQU    /COMCCVI/MSI 
 MSI$     ENDIF 
 PTI$     IF     DEF,PTI$ 
 PTI      EQU    /COMCCVI/PTI 
 PTI$     ENDIF 
 TLI$     IF     DEF,TLI$ 
 TLI      EQU    /COMCCVI/TLI 
 TLI$     ENDIF 
 SLI$     IF     DEF,SLI$ 
 SLI      EQU    /COMCCVI/SLI 
 SLI$     ENDIF 
 QUAL$    ENDIF 
          ENDX
