COMCCPT 
COMMON
          CTEXT  COMCCPT - COPY PREFIX TABLE. 
 CPT      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCCPT
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CPT      SPACE  4
***       CPT - COPY PREFIX TABLE.
*         P. D. HAAS.  73/10/12.
 CPT      SPACE  4
***              CPT EXTRACTS COMMENTS FROM THE 7700 TABLE
*         TO A PRINT LINE.  GARBAGE IN THE TABLE IS DISCARDED 
*         AND COPY TERMINATES ON A ZERO BYTE OR *COPYRIGHT*.
* 
*         ENTRY  (A1) = PREFIX TABLE ADDRESS. 
*                (X1) = CONTROL WORD. 
*                (A6) = ADDRESS OF WORKING STORAGE. 
*                (B1) = 1.
* 
*         EXIT   NONE.
* 
*         USES   A - 3, 4, 6. 
*                B - 3, 4.
*                X - 1, 2, 3, 4, 6. 
* 
*         CALLS  NONE.
  
  
 CPT      PS     0           ENTRY/EXIT 
          LX1    18 
          SX3    X1-770000B  CHECK FOR PREFIX TABLE 
          LX1    6
          NZ     X3,CPT2     IF NO PREFIX TABLE 
          SB4    B1+B1
          SB3    X1+B1       SET LENGTH OF TABLE
          SA3    CPTA 
          LE     B3,B4,CPT2  IF TOO SHORT TO COPY 
          SA4    A1+B4       COPY DATE
          BX6    X4 
          SB4    X1-10B      CHECK LENGTH 
          SA6    A6+B1
          NG     B4,CPT2     IF TABLE .LT. 10B WORDS LONG 
          SB4    10B
          SA4    A1+B4
          MX1    -12
 CPT1     BX2    X4-X3
          LX6    X4 
          ZR     X2,CPT2     IF *COPYRIGHT* 
          BX4    -X1*X4 
          SA6    A6+B1
          ZR     X4,CPT      IF END OF DATA 
          SB4    B4+B1
          SA4    A1+B4       READ NEXT ENTRY
          NE     B4,B3,CPT1 
 CPT2     BX6    X6-X6       CLEAR END OF BUFFER
          SA6    A6+B1
          EQ     CPT         RETURN 
  
 CPTA     DATA   10HCOPYRIGHT 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CPT      EQU    /COMCCPT/CPT 
 QUAL$    ENDIF 
          ENDX
