COMCCCE 
COMMON
          CTEXT  COMCCCE - CONVERT CATALOG ENTRY. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMCCCE
          BASE   D
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 CCE      SPACE  4,10 
***       CCE - CONVERT CATALOG ENTRY.
*         P. L. VERELL       78/09/05.
          SPACE  4,10 
***              CCE CONVERTS AN 8 WORD CATALOG ENTRY TO A 16 WORD
*         CATALOG ENTRY FORMAT. 
* 
*         ENTRY  (X4) = FWA OF CATALOG ENTRY IN 8 WORD FORMAT.
* 
*         EXIT   CATALOG ENTRY IN 16 WORD FORMAT. 
* 
*         USES   A - 1, 2, 7. 
*                X - 1, 2, 3, 4, 7. 
  
  
 CCE      SUBR               ENTRY/EXIT 
          SA1    X4+TCUC     RELOCATE USER CONTROL WORD 
          BX7    X1 
          SA7    X4+FCUC
          MX3    -3          SAVE SUB-SYSTEM CODE 
          LX3    14-2 
          BX2    -X3*X1 
          LX2    50-14
          SA1    X4+TCPW     RELOCATE FILE PASSWORD 
          BX7    X1 
          SA7    X4+FCPW
          SA1    X4+TCIW     RELOCATE INSTALLATION WORD 
          BX7    X1 
          SA7    X4+FCIW
          SA1    X4+FCMD     SET CHANGE MODIFICATION DATE/TIME
          MX3    -36
          BX7    -X3*X1 
          SA7    X4+FCKD
          BX7    X2+X7       RELOCATE SUB-SYSTEM CODE 
          SX2    RSDE        SET PREFERRED FESIDENCE CODE 
          LX2    59-2 
          BX7    X2+X7
          SX2    BRDE        SET BACKUP REQUIREMENT CODE
          LX2    56-2 
          BX7    X2+X7
          SA7    X4+FCUD     SET UTILITY CONTROL DATE/TIME
          BX7    X7-X7       CLEAR ALL CDC RESERVED WORDS 
          SA7    A7+2 
          SA7    A7+B1
          SA7    A7+B1
          SA7    A7+B1
          SA7    A7+B1
          SA7    A7+B1
          EQ     CCEX        EXIT 
          SPACE  4,10 
**        8 WORD FORMAT ENTRY LOCATIONS REQUIRING RELOCATION. 
  
 TCIW     EQU    5           INSTALLATION WORD (60 BITS)
 TCPW     EQU    6           FILE PASSWORD (42 BITS)
 TCUC     EQU    7           USER CONTROL WORD (60 BITS)
          SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CCE      EQU    /COMCCCE/CCE 
 QUAL$    ENDIF 
          ENDX
