*COMDECK  COMCCDD - CONVERT INTEGER TO DECIMAL DISPLAY CODE.
          CTEXT  COMCCDD - CONSTANT TO DECIMAL DISPLAY CODE CONVERSION. 
 CDD      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMCCDD
          BASE   D
*         COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994
 CDD      SPACE  4
***       CDD - CONSTANT TO DECIMAL DISPLAY CODE CONVERSION.
*         G. R. MANSFIELD.  70/12/18. 
*         ADAPTED FROM SUBROUTINE *CONDEC* IN *COMPASS VER 2.0*.
 CDD      SPACE  4
***              CDD CONVERTS UP TO 10 DIGITS TO DISPLAY CODE WITH
*         LEADING ZERO SUPPRESSION.  CONVERSION CONTAINS SPACE FILL 
*         AND IS RIGHT AND LEFT JUSTIFIED.
* 
*         ENTRY  (X1) = NUMBER TO BE CONVERTED. 
*                (B1) = 1.
* 
*         EXIT   (X6) = DPC CONVERSION RIGHT JUSTIFIED. 
*                (X4) = DPC CONVERSION LEFT JUSTIFIED.
*                (B2) = 6*COUNT OF DIGITS CONVERTED.
* 
*         USES   X - 1, 2, 3, 4, 6, 7.
*                B - 2, 3, 4. 
*                A - 2, 3, 4. 
* 
*         CALLS  NONE.
  
  
 CDD1     DX6    X1*X2       COMPUTE QUOTIENT 
          FX1    X1*X2
          UX7    X1          CHECK QUOTIENT 
          LX4    -6          SHIFT ASSEMBLY 
          SB2    B2+B4
          FX6    X6*X3       EXTRACT REMAINDER DIGIT
          SX6    X6+B3       CONVERT DIGIT
          IX4    X6+X4
          NZ     X7,CDD1     LOOP TO ZERO QUOTIENT
          LX4    -6          LEFT JUSTIFY ASSEMBLY
          LX6    X4,B2       RIGHT JUSTIFY ASSEMBLY 
  
 CDD      PS                 ENTRY/EXIT 
          SA2    CDDA        =.1P48+1 
          SA3    A2+B1       =10.P
          PX1    X1 
          SB2    B0          CLEAR JUSTIFY COUNT
          SA4    A3+B1       =1H
          SB3    1R0-1R      (B3) = CONVERSION CONSTANT 
          SB4    6           (B4) = SHIFT INCREMENT 
          EQ     CDD1 
  
 CDDA     CON    0.1P48+1 
          CON    10.P 
          CON    1H 
          SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 CDD      EQU    /COMCCDD/CDD 
 QUAL$    ENDIF 
          ENDX
