*DECK     TXTANVF 
PROC  TXTANVF;
# TITLE TXTANVF - SYMPL TEXT FOR NVF RESIDENT CODE.                    #
  
      BEGIN #TXTANVF #
# 
**    TXTANVF - SYMPL TEXT FOR NVF RESIDENT CODE. 
* 
*     S. H. FISCHER.         81/12/01.
*     C. J. BRION.           83/04/21. 83/05/10. 83/09/08.
*     C. J. BRION            83/10/19.
* 
*     THIS SYMPL TEXT CONTAINS DEFINITIONS NEEDED BY SEVERAL NVF
*     RESIDENT PROCESSES. 
* 
*     PROC TXTANVF
* 
# 
  
      CONTROL STEXT;
  
# 
****
# 
      DEF  ABAP$    #3#;     # "ABAP" ACCOUNT MESSAGE TYPE             #
      DEF  ABUN$    #1#;     # "ABUN" ACCOUNT MESSAGE TYPE             #
      DEF  AEAP$    #4#;     # "AEAP" ACCOUNT MESSAGE TYPE             #
      DEF  AEUN$    #2#;     # "AEUN" ACCOUNT MESSAGE TYPE             #
      DEF  ABER$    #5#;     # "ABER" ACCOUNT MESSAGE TYPE             #
      DEF  ABIC$    #6#;     # "ABIC" ACCOUNT MESSAGE TYPE             #
      DEF  SIPI$    #7#;     # "SIPI" ACCONT MESSAGE TYPE              #
      DEF  ABAC$    #0#;     # A-A ACCOUNT MSG TYPES #
      DEF  ABAA$    #1#;
      DEF  ABAE$    #2#;
      DEF  ABEA$    #3#;
      DEF  ABRE$    #4#;
      DEF  AEAA$    #5#;
      DEF  ABAR$    #6#;
      DEF  SANW$    #0#;     # APPLICATION STATUS ACCOUNT MSG TYPES    #
      DEF  SBNW$    #1#;
      DEF  SBER$    #2#;
      DEF  SENW$    #3#;
      DEF  ALN$     #0#;     # APPL LIST NUMBER FOR THE CONNECTION     #
      DEF  AWTAPP$  #1#;     # AWAIT APPLICATION PROMPT - PTA$PROMPT   #
      DEF  AWTFAM$  #5#;     # AWAIT FAMILY PROMPT - PTA$PROMPT        #
      DEF  AWTPID$  #2#;     # AWAIT PERSONAL ID PROMPT - PTA$PROMPT   #
      DEF  AWTPWD$  #3#;     # AWAIT PASSWORD PROMPT - PTA$PROMPT      #
      DEF  AWTUSR$  #4#;     # AWAIT USER PROMPT - PTA$PROMPT          #
      DEF  CPMSIZ$  #15#;    # MAXIMUM NUMBER OF CPM PARAMETERS - 1    #
      DEF  CPM56B$  #O"56"#; # CPM VALIDATE FUNCTION CODE              #
      DEF  CPM73B$  #O"73"#; # CPM DECREMENT FAMILY COUNT FUNCTION CODE#
      DEF  DSPROUTE$ #O"77"#; # DSP ROUTE FUNCTION CODE                #
      DEF  GLIDCFC$ #O"65"#; # GETLID CONFIGURATION FUNCTION CODE      #
      DEF  GPIDAFC$ #O"66"#; # GET PID ATTRIBUTES FUNCTION CODE        #
      DEF  SPIDAFC$ #O"67"#; # SET PID ATTRIBUTES FUNCTION CODE        #
      DEF  PIDOPST$ # 1 #;   # SETPIDA NETWORK STATUS=PID AVAILABLE    #
      DEF  PIDINOP$ # 2 #;   # SETPIDA NETWORK STATUS=PID NOT AVAILABLE#
      DEF  GLIDBUFS$ #14#;   # GETLIDC FX MINIMUM BUFFER SIZE          #
      DEF  GPIDBUFS$ # 6#;   # GETPIDA FX BUFFER SIZE                  #
      DEF  SPIDBUFS$ # 4#;   # SETPIDA FX BUFFER SIZE                  #
      DEF  LPIDLEN$  #20#;   # CHAR LEN OF LID/PID FX REQ BUFFER       #
      DEF  GPIDABIAS$ #2#;   # ACPID ENTRY BIAS FOR GETPIDA MACRO CALL #
      DEF  GLIDCBIAS$ #3#;   # ACPID ENTRY BIAS FOR GETLIDC MACRO CALL #
      DEF  GETFC$   #O"76"#; # GET FILE INTERNAL FUNCTION CODE         #
      DEF  GETFETS$ #17#;    # GET MACRO CALL FET SIZE + 1             #
      DEF  CRQDSIZ$ #2#;     # NUM OF WRDS PER DECREMNT FAM CT CPM REQ #
      DEF  CRQVSIZ$ #4#;     # NUM OF WORDS PER VALIDATE CPM REQUEST   #
      DEF  DSPVSIZ$ #9#;     # NUM OF WORDS PER DSP ROUTE REQUEST      #
      DEF  TMBSIZ$  #4#;     # TIMER REQUEST BUFFER SIZE               #
      DEF  DEFAULT$ #2#;     # FAMILY/USER AUTOLOGIN TYPE INDICATOR    #
      DEF  EPFNBIT$ #16#;    # STARTING BIT FOR EP FIELD NUMBER (FN)   #
      DEF  EPFN$    #49#;    # EP FIELD NUMBER                         #
      DEF  EPON$    #X"45503D59"#;  # HEX CODE FOR "EP=Y"              #
      DEF  EPTLC$   #6#;     # CTLR/DEF ECHOPLEX TEXT LENGTH IN CHARS  #
      DEF  ICT$     #4#;     # INPUT CHARACTER TYPE FOR THE CONNECTION #
      DEF  LCTRLO$  #4#;     # CTRL/CHAR LENGTH IN OCTETS              #
      DEF  MATRY$   #128#;   # MAXIMUM NUMBER OF APPL RETRIES ALLOWED  #
      DEF  MLTRY$   #4#;     # MAXIMUM NUMBER OF LOGIN RETRIES ALLOWED #
      DEF  MNDATRY$ #1#;     # FAMILY/USER/APPL AUTOLOGIN TYPE IND     #
      DEF  NULL$    #0#;     # NULL PARAMETER                          #
      DEF  PRIMARY$ #3#;     # APPLICATION AUTOLOGIN TYPE INDICATOR    #
      DEF  RTCLC$   #6#;     # CTRL/RTC TEXT LENGTH IN CHARACTERS      #
      DEF  TCFNBIT$ #0#;     # STARTING BIT FOR TC FIELD NUMBER (FN)   #
      DEF  TCFN$    #34#;    # TC FIELD NUMBER                         #
      DEF  TC9$     #9#;     # SYNCHRONOUS TERMINAL CLASS              #
      DEF  VCBSIZ$  #8#;     # NUMBER OF WORDS PER VCB ENTRY           #
      DEF  NETPTIME$ # 300 #; # NETON PENDING TIMEOUT IN SECS          #
      DEF  RTRYTIME$ # 30 #; # RETRY CONNECTION TIMEOUT IN SECS        #
      DEF  CONNOK$  # 0 #;   # CONNECTION OK STATUS # 
      DEF  NOCONN$  # 1 #;   # NO CONNECTION POSSIBLE STATUS #
      DEF  NETP$    # 2 #;   # NETON PENDING STATUS # 
      DEF  MCLIMIT$ # 3 #;   # MAXIMUM CONNECTION/COPIES LIMIT REACHED #
      DEF  AACON$   # 1 #;   # AA CONNECTION TYPE ID     #
      DEF  TACON$   # 2 #;   # TA CONNECTION TYPE ID #
      DEF  ECABSY$  # 0 #;   # APPLICATION BUSY ERROR CODE #
      DEF  ECCANA$  # 7 #;   # CONCURRENT ACCESS PROHIBITED ERROR CODE #
      DEF  ECANP$   # 1 #;   # APPLICATION NOT PRESENT EC # 
      DEF  ECAPNETP$ # 2 #;  # APPLICATION NETON PENDING EC # 
# 
*     LID/PID MANAGEMENT FUNCTION REASON CODES. 
# 
      DEF  LPIDSMALL$ # 6 #; # RETURN INFO TOO LONG FOR BUFFER         #
      DEF  LPIDBADLP$ # 7 #; # PID/LID NOT LEGAL                       #
      DEF  LPIDBADAT$ #10 #; # INVALID ATTRIBUTE                       #
      DEF  LPIDLIDOV$ #12 #; # LID TABLE OVERFLOW                      #
      DEF  LPIDBUFSM$ #16 #; # BUFFER TOO SMALL                        #
  
# 
****
# 
  
# 
**    ACNST - ACN STATE DEFINITIONS.
* 
*     THIS STATUS LIST DEFINES THE SYMBOLS TO BE USED IN SETTING AND
*     CHECKING THE STATE OF A CONNECTION TO NVF BY THE C LAYER. 
* 
# 
  
      STATUS ACNST
        CREATE,                        # CREATE IN PROGRESS            #
        ACTIVE,                        # ACTIVE                        #
        BRKOUT,                        # BREAK OUTSTANDING             #
        BROKEN,                        # CONNECTION BROKEN             #
        ENDED,                         # CONNECTION ENDED (IN PROGRESS)#
        TRMPEND,                       # TERMINATE PENDING             #
        SWTPEND,                       # SWITCH PENDING                #
        CLEARI,                        # CLEAR INPUT                   #
        SWSTART,                       # SWITCH STARTED                #
        BRKCMD,                        # BRK PENDING/CMD IN PROGRESS   #
        ; 
  
# 
**    CTQSTAT - CONNECTION TRAFFIC QUEUE ENTRY DEFINITIONS. 
**    FOLLOWING STATUS IS FOR USE BY *NVFCDQE**AND *NVFTDQE**PROCESSES
*     FOR DISPATCHING ITS SMS.
# 
      STATUS CTQSTAT
          SACC,              # CR/ACC SM                               #
          SCB,               # CR/CB SM                                #
          SITE,              # CR/ITE SM                               #
          SIAP,              # CR/IAP SM #
          SRAP,              # CR/RAP SM #
          SRCN,              # CR/RCN SM #
          SSWHN,             # CR/SWH/N SM                             #
          STRMN,             # CR/TRM/N SM                             #
          SACK,              # FC/ACK SM                               #
          SBRK,              # FC/BRK SM                               #
          SIUSR,             # INTR/USR SM                             #
          SINA,              # FC/INACT - TIMER EXPIRED                #
          SINIT,             # FC/INIT SM                              #
          SNAK,              # FC/ACK SM                               #
          SBMRK,             # BI/MARK SM                              #
          SHBRK,             # HOP/BRK SM                              #
          SHCMD,             # HOP/CMD SM                              #
          SHEND,             # HOP/END SM                              #
          SHIG,              # HOP/IG SM                               #
          SHPAGE,            # HOP/PAGE SM                             #
          SHSTART,           # HOP/START SM                            #
          STCHAR,            # TCH/TCHAR SM                            #
          SSLL,              # CR/SLL SM                               #
          SFAI,              # FAI/APP/N SM                            #
          SNETN,             # NET/ON/N SM                             #
          SNETA;             # NET/ON/A SM                             #
  
# 
**    DTSTAT - DEVICE TYPE STATUS DEFINITIONS.
**    FOLLOWING STATUS IS FOR USE BY *NVFTACC*, *NVFTDSP**AND *NVFTITE**
*     PROCESSES FOR CASING ON DEVICE TYPE.
# 
      STATUS DTSTAT 
          SCON,              # CONSOLE DEVICE TYPE                   0 #
          SCR,               # CARD READER DEVICE TYPE               1 #
          SLP,               # LINE PRINTER DEVICE TYPE              2 #
          SCP,               # CARD PUNCH DEVICE TYPE                3 #
          SPL,               # PLOTTER DEVICE TYPE                   4 #
          SAA1,              # APPLICATION-TO-APPLICATION TYPE       5 #
          SAA2,              # APPLICATION-TO-APPLICATION TYPE       6 #
          SCLP,              # CDCNET LINE PRINTER  (PSU)            7 #
           ,,,,              #                               8,9,10,11,#
          SUSER;             # USER DEVICE TYPE                     12 #
  
# 
**    PDCTST - PDCT STATE DEFINITIONS.
* 
*     THIS STATUS LIST DEFINES THE SYMBOLS TO BE USED IN SETTING AND
*     CHECKING THE STATE OF A PDCT BY THE T-A PROCESS.
# 
      STATUS PDCTST 
          PDCNULL,           # NULL STATE - NOT USED                   #
          CONSWT,            # CONNECTION SWITCHED                     #
          AWTCVAL,           # AWAIT CONSOLE VALIDATION                #
          AWTCON;            # AWAIT CONSOLE                           #
  
# 
**    PAACST - STATE DEFINITIONS FOR PAAC ENTRIES.
# 
  
      STATUS PAACST 
        PANULL,         # S0 - NULL STATE/NO PAAC # 
        PAIAP,          # S1 - IAP REQUEST PROCESSED #
        PARAP,          # S2 - RAP REQUEST PROCESSED #
        PAAWTVAL,       # S3 - RAP AWAIT VALIDATION DATA #
        PAICBVCB,       # S4 - IAP - CB WAITING ON VCB DATA # 
        PARCBVCB,       # S5 - RAP - CB WAITING ON VCB DATA # 
        PAIRCNVCB,      # S6 - IAP - RCN WAITING ON VCB DATA #
        PARRCNVCB,      # S7 - RAP - RCN WAITING ON VCB DATA #
        PACB,           # S8 - CB ON NON NVF CONNECTION # 
        PAISWT,         # S9 - IAP SWITCH SUCCESSFUL - VCB STATE #
        PARSWT,         # S10 - RAP SWITCH SUCCESSFUL - VCB STATE # 
        PARCN,          # S11 - RCN ON NON NVF CONNECTION # 
        PANETP,         # NETON PENDING # 
        PAAWTLPID,      # AWAIT LID PID FUNCTION CALL # 
        PAERR;          # ERROR STATE # 
  
# 
**    PTACST - PTAC STATE DEFINITIONS.
* 
*     THIS STATUS LIST DEFINES THE SYMBOLS TO BE USED IN SETTING AND
*     CHECKING THE STATE OF A PTAC BY THE T-A PROCESS.
# 
      STATUS PTACST 
          PTANULL,           # NULL STATE - NOT USED                   #
          AWTRSP,            # AWAIT RESPONSE                          #
          AWTVAL,            # AWAIT VALIDATION                        #
          CONBROK,           # CONNECTION BROKEN                       #
          AWTVCBC,           # AWAIT VCB FOR A CR/CB                   #
          AWTVCBR,           # AWAIT VCB FOR A CR/RCN                  #
          AWTPRMT,           # AWAIT PROMPT                            #
          AWTNETP,           # AWAIT NETON PENDING                     #
          AWTAPPL,           # AWAIT CONSOLE SWITCH TO APPLICATION     #
          AWTVAA,            # AWAIT VALIDATE APPLICATION ACCESS       #
          AWTVCBL;           # AWAIT VCB FOR LOANED CR/RCN             #
  
# 
**    TABUF - LABELLED COMMON BLOCK.
* 
*     COMMON BLOCK OF BUFFERS USED BY THE TERMINAL-TO-APPLICATION 
*     PROCESS OF NVF. 
# 
      COMMON TABUF; 
      BEGIN 
# 
**    CRQBUF - CPM REQUEST BUFFER.
* 
*     BUFFER FOR CPM REQUEST 56B (VALID) AND 73B (DECREMENT FAMILY
*     COUNT). 
* 
* 
*     THE FOLLOWING IS THE FORMAT OF AN CRQ ENTRY.  EACH ENTRY
*     IS 4-WORDS LONG.
* 
* 
*                 1         2         3         4         5 
*       012345678901234567890123456789012345678901234567890123456789
*TEXT 
*T,WORD0,6/FC,18/,12/ACN,24/
*TEXT 
*T,WORD1,42/FNAME,16/ ,1/RETPED,1/RETPID
*ENDTEXT
*T,WORD2,42/PASSWD,16/,1/F,1/P
*T,WORD3,42/UNUM,18/
*ENDTEXT
* 
* 
# 
      BASED ARRAY CRQBUF[00:00] S(DSPVSIZ$);
        BEGIN 
# 
****
# 
        ITEM CRQ$FCWORD U(00,00,60);   # REFERENCE FUNCTION CODE WORD  #
        ITEM CRQ$FC     U(00,00,06);   # FUNCTION CODE OF REQUEST      #
        ITEM CRQ$ACN    U(00,24,12);   # APPLICATION CONNECTION NUMBER #
        ITEM CRQ$VCB    U(00,24,12);   # VCB ORDINAL                   #
        ITEM CRQ$QNUM   U(00,42,18);   # QUEUE NUMBER FOR RECVD DATA   #
        ITEM CRQ$FWORD  U(01,00,60);   # REFERENCE FAMILY WORD         #
        ITEM CRQ$FNAM   C(01,00,07);   # FAMILY NAME                   #
        ITEM CRQ$NOROUT B(01,57,01);   # NOT ROLL OUT JOB IF DEVICE ERR#
        ITEM CRQ$RETPED B(01,58,01);   # CPM TO RETURN PASSWRD EXP DATE#
        ITEM CRQ$RETPID B(01,59,01);   # CPM TO RETURN PERSONAL ID     #
        ITEM CRQ$PWORD  U(02,00,60);   # REFERENCE PASSWORD WORD       #
        ITEM CRQ$PASSWD C(02,00,07);   # PASSWORD                      #
        ITEM CRQ$IFCTF  B(02,58,01);   # INCREMENT FAMILY COUNT FLAG   #
        ITEM CRQ$VPWF   B(02,59,01);   # VALIDATE PASSWORD FLAG        #
        ITEM CRQ$UWORD  U(03,00,60);   # REFERENCE USER WORD           #
        ITEM CRQ$UNUM   C(03,00,07);   # USER NUMBER                   #
# 
****
# 
        END 
  
# 
**    CPMBUF - CONTROL POINT MANAGER REQUEST BUFFER.
* 
*     THE FOLLOWING ARRAY DEFINES THE PARAMETER BLOCK FOR CPM REQUEST.
# 
      ARRAY CPMBUF[00:CPMSIZ$] S(1);
        BEGIN 
        ITEM CPB$WORD   U(00,00,60);   # FULL WORD REFERENCE           #
        ITEM CPB$FNAM   C(00,00,07);   # FAMILY NAME                   #
        ITEM CPB$CBIT   B(00,59,01);   # COMPLETE BIT                  #
        END 
      ITEM WAITCPM      B = FALSE;     # TRUE WHEN CPM REQUEST ISSUED  #
      ITEM FXACTIVE     B = FALSE;     # FUNCTION ACTIVE FLAG          #
  
# 
**
*E
**    VCBBUF - VCB (VALIDATION CONTROL BLOCK) DATA BUFFER.
* 
*     BUFFER OF VCB DATA FOR WRITE VCB REQUEST. 
* 
* 
*     THE FOLLOWING IS THE FORMAT OF A T-A VCB ENTRY.  EACH ENTRY 
*     IS 8-WORDS LONG.
* 
* 
*TEXT 
*TEXT 
*T,WORD0,42/TN,1/H,1/N,1/C,1/I,1/ ,1/A,12/VCB 
*ENDTEXT
*T,WORD1,30/CNTIME,30/SWTIME
*T,WORD2,60/FWORD 
*T,WORD3,30/,4/DT,5/TC,12/AACN,9/ASORD
*T,WORD4,60/UWORD 
*T,WORD5,42/ALIFAM,3/FI,3/UI,1/ ,11/XBZ 
*T,WORD6,42/ALIUSR,6/UBZ,1/ ,11/DBZ 
*T,WORD7,42/ALIAPP,3/AI,1/V,4/SDT,4/DO,6/SL 
*ENDTEXT
* 
* 
# 
      BASED ARRAY VCBBUF[00:00] S(VCBSIZ$); 
        BEGIN 
# 
****
# 
        ITEM VCB$TN     C(00,00,07);   # TERMINAL NAME                 #
        ITEM VCB$HW     B(00,42,01);   # HARDWIRED TERMINAL FLAG       #
        ITEM VCB$NET    B(00,43,01);   # NETWORK TYPE                  #
        ITEM VCB$CACA   B(00,44,01);   # CONCURRENT ACCESS FLAG        #
        ITEM VCB$ICF    B(00,45,01);   # INTERACTIVE CAPABILITY FLAG   #
        ITEM VCB$ALIF   B(00,47,01);   # AUTO-LOGIN FLAG               #
        ITEM VCB$VCB    U(00,48,12);   # VCB ORDINAL                   #
        ITEM VCB$CNTIME U(01,00,30);   # CONNECT TIME - MODDHHMMSS     #
        ITEM VCB$CTIME  U(01,12,18);   # CONNECT TIME - HHMMSS         #
        ITEM VCB$SWTIME U(01,30,30);   # SWITCH TIME - MODDHHMMSS      #
        ITEM VCB$STIME  U(01,42,18);   # SWITCH TIME - HHMMSS          #
        ITEM VCB$FWORD  U(02,00,60);   # REFERENCE FAMILY WORD         #
        ITEM VCB$PRIAN  U(03,00,09);   # PRI APPL NUMBER               #
        ITEM VCB$VTP    U(03,09,08);   # VTP VERSION                   #
        ITEM VCB$ICMCN  B(03,26,01);   # THIS IS AN INCOMING CONNECTION#
        ITEM VCB$RCNA   B(03,28,01);   # CR/RCN/A SENT FLAG            #
        ITEM VCB$LCF    B(03,29,01);   # LOANED CONNECTION FLAG        #
        ITEM VCB$DT     U(03,30,04);   # DEVICE TYPE                   #
        ITEM VCB$TC     U(03,34,05);   # TERMINAL CLASS                #
        ITEM VCB$AACN   U(03,39,12);   # CONNECTED APPLICATION'S ACN   #
        ITEM VCB$SWAPAN U(03,51,09);   # APPLICATION NUMBER            #
        ITEM VCB$UWORD  U(04,00,60);   # REFERENCE USER WORD           #
        ITEM VCB$ALIFAM C(05,00,07);   # AUTO-LOGIN FAMILY NAME        #
        ITEM VCB$FAMIND U(05,42,03);   # MANDATORY/DEFAULT FAMILY      #
        ITEM VCB$USRIND U(05,45,03);   # MANDATORY/DEFAULT USER        #
        ITEM VCB$XBZ    U(05,49,11);   # TRANSMISSION BLOCK SIZE       #
        ITEM VCB$ALIUSR C(06,00,07);   # AUTO-LOGIN USER NAME          #
        ITEM VCB$UBZ    U(06,42,06);   # UPLINE BLOCK SIZE             #
        ITEM VCB$DBZ    U(06,49,11);   # DOWNLINE BLOCK SIZE           #
        ITEM VCB$ALIAPP C(07,00,07);   # AUTO-LOGIN APPLICATION NAME   #
        ITEM VCB$APPIND U(07,42,03);   # MANDATORY/PRIMARY APPLICATION #
        ITEM VCB$VDSF   B(07,45,01);   # VALIDUS APPL EXIST FLAG       #
        ITEM VCB$SDT    U(07,46,04);   # SUB-DEVICE TYPE               #
        ITEM VCB$DO     U(07,50,04);   # DEVICE ORDINAL                #
        ITEM VCB$SL     U(07,56,04);   # SECURITY LEVEL                #
 #
****
# 
# 
**
*E
*     THE FOLLOWING THE FORMAT OF A MULT-HOST A-A VCB ENTRY.
*     EACH ENTRY IS 8-WORDS LONG. 
* 
* 
*                 1         2         3         4         5 
*       012345678901234567890123456789012345678901234567890123456789
*TEXT 
*T,WORD0,18/ARHID,4/AMO,2/,12/ANACN,12/APACN,12/VCB 
*T,WORD1,4/ASL,2/,8/AIAPRC,1/ ,4/ADT,2/,3/AH,28/,8/APORT
*T,WORD2,42/AFAM,6/AFORD,7/,1/F,1/P,1/C,1/I,1/
*T,WORD3,42/AUSER,18/AUSRIDX
*T,WORD4,30/ACNTIME,30/ASWTIME
*T,WORD5,42/ASWAP,8/ASWAPAN,1/ ,9/ASWAPAST
*T,WORD6,8/ANUMOUT,1/ ,8/ASNODE,1/ ,8/ADNODE,34/
*T,WORD7,60/
*ENDTEXT
# 
  
# 
****
# 
        ITEM VCB$ATN         C(00,00,07); # A-A TERMINAL NAME          #
        ITEM VCB$AVCB        U(00,48,12); # VCB ORDINAL                #
        ITEM VCB$ACNTIME     U(01,00,30); # CONNECT TIME               #
        ITEM VCB$ACTIME      U(01,12,18); # CONNECT TIME HHMMSS        #
        ITEM VCB$ASWTIME     U(01,30,30); # SWITCH TIME                #
        ITEM VCB$ASTIME      U(01,42,18); # SWITCH TIME HHMMSS         #
        ITEM VCB$AFAM        C(02,00,07); # FAMILY NAME                #
        ITEM VCB$AFORD       U(02,48,06); # FAMILY ORDINAL             #
        ITEM VCB$AUPFCF      B(02,55,01); # INC FAM CNT FLAG           #
        ITEM VCB$AUPWF       B(02,56,01); # USE PASSWORD FLAG          #
        ITEM VCB$ASCINV      U(02,57,02); # REF SEC CNT & INV LOGIN    #
        ITEM VCB$ASCEF       B(02,57,01); # SEC CNT EXHAUSTED FLAG     #
        ITEM VCB$AINVLF      B(02,58,01); # INV LOGIN FLAG             #
        ITEM VCB$ARHID       C(03,00,03); # REMOTE HOST ID             #
        ITEM VCB$AMODE       U(03,18,04); # HOST MODE                  #
        ITEM VCB$ADT         U(03,30,04); # DEVICE TYPE                #
        ITEM VCB$ACNAA       U(03,39,12); # CONNECTED APPL ACN         #
        ITEM VCB$ASWAPAN     U(03,51,09); # CONNECTED APPL NUMBER      #
        ITEM VCB$AUSER       C(04,00,07); # USER NUMBER                #
        ITEM VCB$AUSRIDX     U(04,42,18); # USER INDEX                 #
        ITEM VCB$ASWAP       C(05,00,07); # SWITCHED APPL NAME         #
        ITEM VCB$ASL         U(05,42,04); # SECURITY LEVEL             #
        ITEM VCB$ASTATE      U(05,46,06); # PAAC STATE                 #
        ITEM VCB$AIAPRC      U(05,52,08); # CR/IAP REASON CODE         #
        ITEM VCB$ANUMOUT     U(06,00,08); # NUMBER OUTCALL ATTEMPTS    #
        ITEM VCB$ASNODE      U(06,08,08); # SOURCE NODE                #
        ITEM VCB$ADNOD       U(06,16,08); # DESTINATION NODE           #
        ITEM VCB$AVSTATE     U(06,24,06); # VCB STATE                  #
        ITEM VCB$AABITS      U(06,30,24); # REF APPL BITS OF AAWC      #
        ITEM VCB$ANACN       U(07,24,12); # NVF ACN                    #
        ITEM VCB$APORT       U(07,40,08); # ACCESS PORT NUMBER ON NPU  #
        ITEM VCB$WRD0        U(00,00,60); # WORD REFERENCES # 
        ITEM VCB$WRD1        U(01,00,60); 
        ITEM VCB$WRD2        U(02,00,60); 
        ITEM VCB$WRD3        U(03,00,60); 
        ITEM VCB$WRD4        U(04,00,60); 
        ITEM VCB$WRD5        U(05,00,60); 
        ITEM VCB$WRD6        U(06,00,60); 
# 
****
# 
        END 
# 
**    LPIDBUF - LID PID BUFFER FOR SFM FUNCTION CALLS.
# 
      BASED ARRAY LPIDBUF [00:00] S(2); 
        BEGIN 
        ITEM LPI$WORD0       U(00,00,60); 
        ITEM LPI$WORD1       U(01,00,60); 
        ITEM LPI$FC          U(00,00,06);   # FUNCTION CODE            #
        ITEM LPI$VCB         U(00,24,12);   # PAAC VCB ORDINAL         #
        ITEM LPI$QNUM        U(00,42,18);   # Q NUMBER FOR RETURN      #
        ITEM LPI$LID         C(01,00,03);   # LID IDENTIFIER           #
        ITEM LPI$ULID        U(01,00,18); 
        ITEM LPI$PID         C(01,18,03);   # PID IDENTIFIER           #
        ITEM LPI$UPID        U(01,18,18); 
        ITEM LPI$SIZE        U(01,36,13);   # ACPID TABLE SIZE NEEDED  #
        ITEM LPI$NWST        U(01,56,04);   # SETPIDA PID STATUS       #
        END 
  
      END  # END TABUF #
  
      END  # END TXTANVF #
  
TERM
