*COMDECK  COMFGOI                  GLOBAL OVERLAY INITIALIZATION
          CTEXT  COMFGOI - GLOBAL OVERLAY INITIALIZATION
 COMFGOI  SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMFGOI
 COMFGOI  SPACE  4
**        GOI -  GLOBAL OVERLAY INITIALIZATION. 
* 
*         OVERLAY INITIALIZATION COMMON TO BOTH QCG OVERLAYS. 
* 
*         CALLS  ROR (COMFROR), 
*                FEI (COMFFEI). 
  
  
 GOI      SUBR               ENTRY/EXIT...
          SA1    CP.AFLS     CURRENT FL 
          BX6    X1 
          SA6    INT.FL      SAVE INITIAL FL
          SB3    FIN.OL      LWA+1 OF (1,0) OVERLAY (LWA OF LIST) 
          SA2    CO.LOO      MASTER OBJECT LIST FLAG
          MI     X2,GOI1     IF OBJECT LIST ON
          SB3    FIN.MAP     TRASH LIST CODE (LWA OF MAP) 
          SA2    CO.LOA 
          SA4    CO.LOM 
          SA5    CO.LOR 
          BX2    X2+X4
          BX2    X2+X5
          MI     X2,GOI1     IF MAP ON
          SB3    FIN         TRASH LIST AND MAP CODE (FWA OF MAP) 
 GOI1     SA2    CO.LOR      MASTER REFERENCE MAP FLAG
          PL     X2,GOI2     IF SHORT OR NO REF MAP 
          SETFIL FILE=F.REF,MODE=INIT,FWA=B3
 GOI2     SA1    FV.LGO 
          SA2    CO.LOO 
          BX1    X1+X2
          SX6    B3          LWA+1 OF REF BUFFER
          ZR     X1,GOI3     IF BINARY SUPRESSED AND NO OBJECT LISTING
          SETFIL FILE=F.PB,MODE=INIT,FWA=B3 
          SX6    B3          LWA+1 OF PB BUFFER 
          SA2    FV.LGO 
          ZR     X2,GOI3     IF BINARY SUPRESSED
          SB5    B3 
          SETFIL FILE=F.LGO,MODE=INIT,FWA==XOSTACK
          SX6    B5 
 GOI3     SA6    O.TABS      FWA OF TABLES
          SX7    X6+MIN.TABS+NOM.INC
          SA7    NOM.FL 
          SA2    CP.NFLS     CM FIELD LENGTH
          IX6    X2-X6
          SX4    X6-MIN.TABS
          PL     X4,GOI4     IF .GE. 1K OF TABLE SPACE
          SX3    MIN.TABS 
          IX1    X2-X4
          SA2    MAX.FL 
          AX2    30 
          IX2    X2-X1
          MI     X2,MEMERR   IF NOT ENOUGH MEMORY 
          SX7    X1+10+77B
          AX7    6
          LX7    30+6        ROUND UP TO NEXT 100, SHIFT INTO PLACE 
          SA7    L.TABS 
          MEMORY SCM,L.TABS,RCL 
          SA1    L.TABS      NEW FL 
          AX1    30 
          SX7    X1-10       LEAVE 10-WORD SAFETY ZONE
          SA7    CP.NFLS     UPDATE TO CURRENT UNRESERVED FL
          BX7    X1 
          SA7    CP.AFLS     UPDATE TO CURRENT FL 
          SA7    CP.MXFL     SET MAX FL 
          BX6    X3          SETUP X6 
  
 GOI4     SA6    L.TABS 
          AX6    FLSLOP 
          SX6    X6+FLSLUP
          SA6    THRESH      GIVE ALLOC ENOUGH ELBOW ROOM 
          SA4    FV.LGO 
          SA2    CO.LOO 
          BX4    X2+X4
          NZ     X4,GOI5     IF PREBINARY OR OBJECT LISTING REQUESTED 
          SX7    0220B       *JP B2*
          LX7    48 
          SA7    WIN         WIRE OFF PREBINARY 
          SA7    =XWTE       WIRE OFF *DATA* PREBINARY
  
 GOI5     RJ     FEI         FRONT END INITIALIZATION 
          SB2    F.SKEL 
          RJ     ROR         RESET OPCODE OF ROUNDABLES 
  
          EQ     EXIT.
 COMFGOI  SPACE  4,4
          IF     -DEF,QUAL$,2 
          QUAL   *
 GOI      EQU    /COMFGOI/GOI 
  
 COMFGOI  ENDX
