*COMDECK  COMFGFD - GENERATE FILE DECLARATIONS. 
 COMFGFD  CTEXT              GENERATE FILE DECLARATIONS.
  
**               GFD HANDLES THE (V=FILE) TURPLE FOR QCG AND BRIDGE.
* 
*         ENTRY  (B5) -> CURRENT TURPLE.
  
          SA1    "O$"SYM
          MX0    -"TP".BIASL
          =A2    B5+OR.1OP
          LX2    -"TP".BIASP
          BX4    -X0*X2      ISOLATE (X4) = SYMTAB *WB* INDEX 
          =B7    X1-WB.W+WC.W 
          SA3    X4+B7       FETCH SYMTAB *WC*
          LX3    -WC.BFLP 
          MX7    -WC.BFLL 
          BX6    -X7*X3      ISOLATE FILE INDEX (OR BUFFER LENGTH)
          LX3    WC.BFLP-WC.MRLP
          =A1    A3-WC.W+WB.W      *WB* 
          LX1    -WB.EQUP-1 
          PL     X1,GFD4     IF NOT EQUIVALENCED FILE 
  
*         EQUIVALENCED FILE.
  
          BX1    X4 
          BX4    X6 
          ISSUE  OC$FVEC,X1 
          ISSUE  OC$FVEC,X4 
          EQ     GFD6 
  
*         NON-EQUIVALENCED FILE.
  
 GFD4     SA1    =XCO.STAT
          PL     X1,GFD5     IF NOT *STATIC* MODE 
          SA1    =XN.BUF     X1 = BUFL,MRL,FIT SPACE SO FAR 
          IX1    X1+X6       ADD BUFL TO TOTAL
          SX7    X3          X7 = MRL (CHARS) 
          ERRNZ  WC.MRLL-18 
          CW     X2,X7       X2 = MRL (WORDS) 
 .RM      IFEQ   CP#RM,0
          SX2    X2+L.FIT6+L.FET6  X2 = MRL + FIT 
 .RM      ELSE
          SX2    X2+L.FIT7+L.FET7  X2 = MRL + FIT 
 .RM      ENDIF 
          IX7    X1+X2       X7 = BUFL + MRL + FIT + C(N.BUF) 
          SA7    N.BUF       UPDATE THE CELL
  
 GFD5     LX6    PB.BIASP-PB.TAGP 
          BX1    X4+X6       MERGE ORDINAL AND BUFL 
          SX4    X3 
          ERRNZ  WC.MRLL-18 
          ISSUE  OC$FVEC,X1 
          BX1    X4 
          LX1    PB.BIASP-PB.TAGP 
          ISSUE  OC$FVEC,X1 
  
 GFD6     BSS    0
  
          ENDX
