*DECK     INIT21 (2,1) OVERLAY INITIALIZATION 
          IDENT  INIT21 
 INIT21   SECT   (INITIALIZE FRONT END OVERLAY.),INI21
 INIT21   SPACE  4,10 
*         IN FEC
          EXT    FEC
  
*         IN FSNAP
          EXT    UKT=FE 
  
*         IN FSKEL
          EXT    F.SKEL 
  
*         IN FTN
          EXT    CO.ANSI,CO.LOR,CO.RNDA,CO.RNDS,CO.RNDM,CO.RNDD,CP.NFLS 
          EXT    F.IL,F.REF,IDPCHK,SYS=,WNB=
  
*         IN IDP
          EXT    IDP=,IDP=USY,UKT=LNK 
  
*         IN PAR
          EXT    SQZ
  
*         IN PEM
          EXT    ANSI.SW,ERRTYP 
  
*         IN PUC
          EXT    L.TABS,N.MAXIL,O.TABS,THRESH 
  
*         IN RPV20
          EXT    RPV2N
  
*         IN RPV21
          EXT    RPV21
  
*         IN UTILITY
          EXT    RPV= 
 INIT21   SPACE  4,10 
**        INIT21 - INITIALIZE FRONT END OVERLAY.
* 
*         ENTRY  THE (2,1) HAS JUST BEEN LOADED.
* 
*         EXIT   TO FRONT END CONTROLLER *FEC* TO BEGIN 
*                NEXT PROGRAM UNIT. 
  
 FTN21    BSSENT
  
*         LINK RPV TABLES.
  
          BX6    X6-X6
          SX7    RPV21       (X7) = FWA OF (2,1) RNA TABLE
          SA6    RPV2N       MARK END-OF-(2,0) RNA TABLE
          SA7    A6+1        STORE LINK TO (2,1) RNA TABLE
  
*         TURN ON REPRIEVE. 
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
          SA1    RA.SSW      SENSE SWITCH WORD
          LX1    59-5-6      GET SWITCH 6 
          MI     X1,INI1     IF SWITCH 6 ON 
 .TEST    ENDIF 
  
          RPVON              TURN ON REPRIEVE 
  
*         CHECK FOR IDP BREAK REQUEST.
* 
*         IF THERE ARE ANY IDP KEYWORDS THAT ARE (2,1) SPECIFIC,
*         THEN THIS IS THE PLACE TO LINK IDP TO THEM BY STORING 
*         THE FWA OF THE (2,1) IDP KEYWORD TABLE AT (UKT=LNK).
*         SEE *UKT=LNK* IN DECK *IDP*.
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
 INI1     BSS    0
 #OS      IFNE   .OS,2
          SX6    UKT=FE 
          SA6    UKT=LNK
          SX6    =YUSY=FE    (X6) = ADDR OF IDP SYMBOL SEARCH SUBR
          SA6    =XIDP=USY
          CALL   IDPCHK      CHECK FOR IDP REQUEST
          PL     B7,INI2     IF IDP NOT REQUESTED 
 FTN21    BREAK 
 #OS      ENDIF 
 .TEST    ENDIF 
  
*         INITIALIZE OVERLAY. 
  
 INI2     SB3    FTN21       END OF CODE IN OVERLAY 
          SA2    CO.LOR      MASTER REFERENCE MAP FLAG
          PL     X2,INI3     IF NO MAP
          SETFIL FILE=F.REF,MODE=INIT,FWA=B3  SET MAP BUFFER
 INI3     SETFIL FILE=F.IL,MODE=INIT,FWA=B3   SET IL BUFFER 
          SX6    B3          LWA+1 OF IL BUFFER 
          SA6    O.TABS      SET ORIGIN OF MANAGED TABLES 
          SA2    CP.NFLS
          IX6    X2-X6
          SA6    L.TABS      SET SIZE OF TABLE AREA 
          AX6    FLSLOP 
          SA6    THRESH      GIVE ALLOC SOME ELBOW ROOM 
          RJ     FEI         FRONT END INITIALIZATION 
          SB2    F.SKEL 
          RJ     ROR         RESET OPCODE OF ROUNDABLES 
  
**        SET (N.MAXIL) = ZERO IN CCG MODE.  THIS CAUSES AN IL
*         SEGMENT FLUSH AS OFTEN AS POSSIBLE.  CCG DIES IF SQUEEZE
*         CROSSES STATEMENT BOUNDARIES. 
  
 INI5     MX7    0
          SA7    N.MAXIL     FORCE MINIMAL IL SEGMENTS
          EQ     FEC         TRANSFER TO FRONT END CONTROLLER 
 DLF      SPACE  4,10 
**        DLF - DUMP LINK AND FILL TABLES.
* 
*         THIS IS A DUMMY ENTRY POINT FOR ALLOC.
  
 DLF      BSSENT 0           SATISFY EXTERNAL FOR ALLOC 
          IFEQ   TEST,ON,1   IF TEST MODE 
          EQ     "BLOWUP"    CAN'T CALL DLF IN PASS 1.
  
  
          LIST   -X          FA=SET, COMFFEI, COMSEIS AND COMFROR ARE 
                             LISTED IN DECK INIT00. 
  
  
*CALL     COMFFEI                  FRONT END INITIALIZATION 
  
*CALL COMSEIS 
  
*CALL COMFROR 
  
  
          LIST   D
          ENTRY  B=LWA21
 B=LWA21  END                MARK LWA OF OVERLAY FOR RPV
