*DECK     INIT20 (2,0) OVERLAY INITIALIZATION 
          IDENT  INIT20 
 INIT20   SECT   (INITIALIZE CONTROLLER OVERLAY.),INI20 
 INIT20   SPACE  4,10 
*         IN FTN
          EXT    CP.AFLS,CP.IFMT,FV.LGO,F.LGO,IDPCHK,SYS=,INT.FL
  
*         IN IDP
          EXT    IDP= 
  
*         IN PUC
          EXT    PUC
  
*         IN UTILITY
          EXT    RPV= 
 END20    SPACE  4,10 
 END20    BSS    0           ALL CODE PAST HERE IS OVERLAYED
 INIT20   SPACE  4,10 
**        INIT20 - INITIALIZE CONTROLLER OVERLAY. 
* 
*         ENTRY  THE (2,0) HAS JUST BEEN LOADED.
* 
*         EXIT   TO *PUC* TO BEGIN NEXT PROGRAM UNIT. 
  
 FTN20    BSSENT
  
*         TURN ON REPRIEVE. 
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
          SA1    RA.SSW      SENSE SWITCH WORD
          LX1    59-5-6      GET SWITCH 6 
          MI     X1,INI1     IF SWITCH 6 ON 
 .TEST    ENDIF 
  
          RPVON              TURN ON REPRIEVE 
  
*         CHECK FOR IDP BREAK REQUEST.
  
 .TEST    IFEQ   TEST,ON     IF TEST MODE 
 INI1     BSS    0
 #OS      IFNE   .OS,2
          CALL   IDPCHK      CHECK FOR IDP REQUEST
          PL     B7,INI2     IF IDP NOT REQUESTED 
 FTN20    BREAK 
 #OS      ENDIF 
 .TEST    ENDIF 
  
*         INITIALIZE OVERLAY. 
  
 INI2     SA1    CP.AFLS     CURRENT FL 
          BX6    X1 
          SA6    INT.FL      SAVE INITIAL FL
          SA1    CP.IFMT
          PL     X1,PUC      IF NOT EOR, LAST READ
          SA1    FV.LGO 
          ZR     X1,PUC      IF NO BINARY FILE
          SETFIL FILE=F.LGO,MODE=INIT,FWA=END20 
          EQ     PUC         EXIT TO PROGRAM UNIT CONTROLLER... 
          SPACE  4
          LIST   -X          COMFCIP IS LISTED IN *FTN* 
*CALL     COMFCIP            COMPILER INSTALLATION PARAMETERS 
          LIST   *
 OVERLAY  SPACE  4,10 
**        SET UP FWA OF SECONDARY OVERLAYS. 
  
  
 FWA21    EQUENT END20       SET START OF (2,1) TO END OF (2,0) 
 FWA22    EQUENT END20+Z.ILB+Z.PBB SET START OF (2,2) AFTER BUFFERS 
 FW.ILB   EQUENT END20       SET IL BUFFER TO END OF (2,0)
 FW.PBB   EQUENT FW.ILB+Z.ILB      PUT PB BUFFER AFTER IL BUFFER
 FWA23    EQUENT END20       SET START OF (2,3) TO END OF (2,0) 
  
  
          LIST   D
          ENTRY  B=LWA20
 B=LWA20  END                MARK LWA OF OVERLAY FOR RPV
