*DECK CBALIAS 
          IDENT ALIASIO 
          ENTRY ALIASRD 
          ENTRY ALIASRT 
          ENTRY  ALIASOP
          ENTRY  ALIASCL
          SST 
************************************************************************
*                                                                      *
*                  A L I A S R D                                       *
*                                                                      *
*  ALIASRD(WORKING STORAGE AREA, NBR WORDS, WORD ADDRESS)              *
*  ENTRY CONDITIONS                                                    *
*       1. THE ADDRESS OF THE WORKING STORAGE AREA WHERE THE RECORD    *
*          IS TO BE PLACED.                                            *
*       2. NUMBER OF WORDS TO BE READ.                                 *
*       3. WORD ADDRESS OF THE WORD ADDRESSABLE FILE WHERE THE READING *
*          IS TO START.                                                *
*                                                                      *
************************************************************************
ALIASRD   DATA   0
          SX7    A1 
          SA7    PARMADR       SAVE THE ADDRESS OF THE PARMETER LIST
RDSB      SA3    PARMADR
          SA1    X3            STORE THE ADDRESS OF THE WSA 
          SA2    A1+1          STORE THE ADDRESS OF THE NBR OF WORDS
          SA4    A1+2          STORE THE ADDRESS OF THE WA
          SA2    X2            STORE THE NUMBER OF WORDS
          SA3    X4            STORE THE WA 
          SX3    X3+1          ADJUST THE WORD ADDRESS  DDL STARTS AT 
*                              WORD 0  6RM STARTS AT WORD 1 
          SX5    X2 
          LX2    3             CONVERT THE NUMBER 
          LX5    1             OF WORDS TO THE
          IX2    X5+X2         NUMBER OF CHARACTERS 
          GET    CBALIAS,X1,X2,,X3
          EQ     ALIASRD
************************************************************************
*                                                                      *
*                  A L I A S R T                                       *
*                                                                      *
*  ALIASRT(WORKING STORAGE AREA, NBR WORDS, WORD ADDRESS)              *
*  ENTRY CONDITIONS                                                    *
*       1. THE ADDRESS OF THE WORKING-STORAGE AREA THAT CONTAINS THE   *
*          RECORD THAT IS TO BE WRITTEN ON THE ALIAS FILE.             *
*       2. THE NUMBER OF WORDS TO BE WRITTEN.                          *
*       3. THE WORD ADDRESS OF THE WORD ADDRESSABLE FILE WHERE THE     *
*          WRITE IS TO TAKE PLACE.                                     *
*                                                                      *
************************************************************************
ALIASRT   DATA   0
          SA4    A1+2          STORE THE ADDRESS OF WA
          SA2    A1+1          STORE THE ADDRESS OF THE NBR OF WORDS
          SA2    X2            STORE NUMBER OF WORD 
          SA3    X4            STORE WA 
          SX3    X3+1          ADJUST THE WORD ADDRESS  DDL STARTS AT 
*                              WORD0  6RM STARTS AT WORD 1
          SX5    X2 
          LX2    3             CONVERT NUMBER OF
          LX5    1             WORDS TO NUMBER OF 
          IX2    X5+X2         CHARACTERS 
          PUT    CBALIAS,X1,X2,,X3
          EQ     ALIASRT
************************************************************************
*                                                                      *
*                  A L I A S O P N                                     *
*                                                                      *
*   OPENS THE ALIAS FILE.                                              *
*                                                                      *
************************************************************************
ALIASOP   DATA   0
          OPENM  CBALIAS,I-O,N
          EQ     ALIASOP
************************************************************************
*                                                                      *
*                  A L I A S C L                                       *
*                                                                      *
*   CLOSES AND RETURNS THE ALIAS FILE.                                 *
*                                                                      *
************************************************************************
ALIASCL   DATA   0
          CLOSEM CBALIAS,U
          EQ     ALIASCL
************************************************************************
*                  A L I A S E X                                       *
*                                                                      *
*    CRM ERROR EXIT FOR FILE CBALIAS (ZZZZZCB).                        *
*    DECREMENT ERROR COUNT (LIMIT = 1) IF ERROR STATUS = 143.          *
************************************************************************
  
 ALIASEX  DATA 0
          FETCH  CBALIAS,ES,X4     FETCH ERROR STATUS 
          SX1    X4-143B
          ZR     X1,DECR           ERROR STATUS = 143 
          EQ     ALIASEX           RETURN TO CALL TO CRM
 DECR     FETCH  CBALIAS,ECT,X4    FETCH ERROR COUNT
          SX1    X4-1 
          STORE  CBALIAS,ECT=X1    DECREMENT ERROR COUNT
          EQ     ALIASEX           RETURN TO CALL TO CRM
 CBALIAS  FILE   LFN=ZZZZZCB,LT=UL,RT=U,FO=WA,ERL=2,FWB=ALISBUF,BFS=65,M
,RL=650,EX=ALIASEX
ALISBUF   BSSZ   65            CRM BUFFER 
PARMADR   BSSZ   1             ADDRESS OF THE PARAMETER LIST
          END 
