MISCGET 
.PROC,MISCGET*I,
MOD     ' DESIRED MODSET NAME                  '=(*N=,*A),
PRD     ' DECK NAME (GETS ALL MODS FOR DECK)   '=(*N=,*A),
MISCIN  ' GET ALL MODS LISTED IN THIS LOC FILE '=(*N=,*A),
. 
.HELP 
   THIS PROCEDURE PUTS SELECTED MODSETS FROM MISCPL ON FILE *USER*. 
   THERE ARE 3 TYPES OF CALL.  USE ONE TYPE PER CALL
   USE..  BEGIN,MISCGET,INSTALL,MOD=HISTORY.  FOR ALL MODSET DESC.
   THE SELECTED MODSETS ARE APPENDED TO FILE USER WITH THE GTR COMMAND. 
   FILE USER IS DIRECTLY AVAILABLE FOR THE OBJECT BUILD JOB.
  
.HELP,MOD 
   TYPE 1 - SELECTS ONE MODSET. 
   BEGIN,,MISCGET,MOD=MODNAME.  PICKS UP MODSET NAMED - MODNAME 
        NOTE..  THIS OPTION CAN BE USED REPEATEDLY TO OPTAIN
                MULTIPLE MODSETS ON FILE USER.
.HELP,PRD 
   TYPE 2 - SELECTS ALL MODSETS ASSOCIATED WITH A NAMED DECK. 
   BEGIN,,MISCGET,PRD=DECKNAME.  PICKS UP ALL MODSETS ASSOCIATED WITH 
                                DECK *DECKNAME*.
                            EX: BEGIN,,MISCGET,PRD=CC4.  (CCP MODS) 
  
.HELP,MISCIN
   TYPE 3 - SELECTS DISCRETLY NAMED MODSETS.
   BEGIN,,MISCGET,MISCIN=LFN.  PICKS UP ALL MODSETS LISTED IN FILE *LFN*
     BUILD LFN WITH..      NOTE(IN,NR),.CC40589,.CC40715,.CC40725 
                           NOTE(IN,NR),.CC4C242,.CC40735
                           BEGIN,,MISCGET,MISCIN=IN.
     NOTE.. THIS CALL USES EDIT TO REPLACE '.' WITH '/CALL,'. 
  
     NOTE.. DECK NOS2P2(EMPTY DECK) IS MODIFIED TO INCLUDE THE ABOVE
            /CALL COMDECK CALLS FOR TYPE 1 AN 3 MISCGET CALLS.
  
  
.ENDHELP
ATTACH(MISCPL)
IFE($MISCIN$.NE.$$,A) 
  REWIND,*. 
  SKIPEI,ZZZIN. 
  COPYEI,MISCIN,ZZZIN.
  PACK(ZZZIN) 
  RETURN(MISCIN)
EDIT(ZZZIN,I=EDITIN,L=EDITOUT)  EDIT DOES NOT LIKE LEADING SPACES.
ENDIF(A)
IFE($PRD$.NE.$$,B)
  RENAME(ZZZIN=ZZINDK)
ENDIF(B)
UPDATE,Q,P=MISCPL,*=/,I=ZZZIN,L=1,D,8.
GTR,COMPILE,USER.TEXT/* 
RETURN,COMPILE,ZZZIN,ZZINDK,MISCPL,EDITIN,ZZZIN.
REVERT.MOD_PRD_MISCIN APPENDED TO FILE USER.
EXIT. 
REVERT(ABORT)  MISCGET
.DATA ZZZIN 
/IDENT MISCID 
/C NOS2P2 
/I NOS2P2.1 
/CALL MOD 
.DATA EDITIN
F;3 
D 
RS:+.+,+/CALL,+;* 
END 
.DATA ZZINDK
/IDENT MISCID 
/C PRD
*WEOR 
