DECKLIS 
.PROC,DECKLIS*I,
OPL     ' NAME OF MODIFY PL TO PRINT           '=(*N=DECKOPL,*F), 
REP     ' NUMBER OF ADDITIONAL COPIES          '=(*N=0,*A), 
MOD     ' FILE NAME OF MODSETS TO INCLUDE      '=(*N=,*F),
EXPAND  ' EXPAND COMMON DECK CALLS    (NO/YES) '
          =(*N=C,*K=C,YES=C,NO=S),
MODIF   ' PRINT MODIFY OUTPUT         (NO/YES) '=(*N=0,NO=0,
                                                  YES=LIST,*K=LIST),
UMODE   ' LIST ONLY MODIFIED DECKS    (NO/YES) '=(*N=F,NO=F,YES=U,*K=U),
. 
  
.*****  DECKLIS  LIST CONTENTS OF OPL.
.*
.*      *DECKLIS* GENERATES A LISTING OF *DECKOPL*. IT CAN PRODUCE
.*      A LISTING WITH COMMON DECKS EXPANDED (COMPILE FILE) OR A
.*      LISTING WITHOUT COMMON DECKS EXPANDED ( SOURCE FILE ).
  
.***    INVOCATION. 
.*
.*      BEGIN(DECKLIS,INSTALL,OPL,REP,MOD,\EXPAND,MODIF,UMODE)
.*
.*      OPL      OPL FILE NAME (PERMANENT).  DEFAULT IS *DECKOPL*.
.*      REP      NUMBER OF ADDITIONAL COPIES TO PRINT.
.*               DEFAULT IS 0.
.*      MOD      INCLUDE ALL MODSETS ON FILE 'MOD=MODFILE' ON 
.*               THE LISTING. 
.*      UMODE    LIST ONLY DECKS MODIFIED BY FILE 'MOD=MODFILE'.
.*      EXPAND   PRODUCE LISTING WITH COMMON DECK CALLS EXPANDED. 
.*               DEFAULT IS DECKS EXPANDED. 
.*      MODIF    KEYWORD OPTION TO PRINT MODIFY OUTPUT. 
.*
  
$RETURN(COMPILE,LIST) 
$ATTACH(OPL/NA) 
IFE(.NOT.FILE(OPL,AS),IND)
  $GET(OPL) 
ENDIF(IND)
$NOTE(LIST,NR)/1
  
.IF,$MOD$.NE.$$,MODASGN.
  IFE,.NOT.FILE(MOD,AS),GETMOD. 
    GET,MOD/NA. 
  IFE,.NOT.FILE(MOD,AS),GETMOD. 
    ATTACH,MOD/NA.
  IFE,.NOT.FILE(MOD,AS),GETMOD. 
    REVERT(ABORT) FILE MOD NOT FOUND. 
  ELSE,GETMOD.
    RENAME,MODIR1=MOD.
  ENDIF,GETMOD. 
.ENDIF,MODASGN. 
$RETURN(EXPAND_OUT) 
$RETURN(CIN)
$NOTE(CIN)+*READ,MODIR1,* 
$MODIFY(P=OPL,L=MODIF,UMODE,EXPAND=EXPAND_OUT,I=CIN)
$NOTE(LIST,NR)/1
$CATALOG,OPL,R,N,L=LIST.
$COPYSBF(EXPAND_OUT,LIST) 
$ROUTE(LIST,DC=PR,#REP=REP) 
$NOTE(OUTPUT,NR)/ / DECK LIST ROUTED TO #LOCAL SITE.
$RETURN(OPL,COMPILE)
$REVERT.  DECKLIS.
$EXIT.
$REVERT(ABORT)  DECKLIS.
.#DATA,MODIR1 
*WEOR 
