ACCJOBS 
.PROC,ACCJOBS*I"ACCESS THE FILE *JOBSTAT*", 
M       ' ACCESS MODE     (W,RESET)            '=(W,RESET), 
JOBSTAT ' JOB STATISTICS FILE                  '=(*N=JOBSTAT,*F), 
. 
*IF,DEF,PDOC
.HELP 
  
THIS PROCEDURE IS USED TO ACCESS THE FILE JOBSTAT.  THE PERMANENT 
FILE NAME TO ATTACH IS PASSED IN FROM THE CALLING PROCEDURE *ACCESS*. 
THE LOCAL FILE NAME IS ALWAYS JOBSTAT. THE FILE IS ALWAYS ATTACHED IN 
WRITE MODE. IF IT DOES NOT EXIST, IT IS CREATED.
  
.HELP,M 
  
*W* ATTACH FILE IN WRITE MODE, CREATE IT IF IT DOES NOT EXIST.
*RESET* PURGE FILE THEN DEFINE IT.
  
.ENDHELP
*ENDIF
  
*************** A C C J O B S ********************
  
RETURN(#JOBSTAT)
  
.IF, ( $M$ .EQ. $W$ ) ,ACCJOBS1.
  
  ATTACH(#JOBSTAT=JOBSTAT/#M=W,NA)
  IF, FILE(#JOBSTAT, .NOT. AS) ,ACCJOBS2. 
    DEFINE(#JOBSTAT=JOBSTAT)
  ENDIF(ACCJOBS2) 
  
.ELSE(ACCJOBS1) 
  
  PURGE(JOBSTAT/NA) 
  DEFINE(#JOBSTAT=JOBSTAT)
  WRITEF(#JOBSTAT)
  RETURN(#JOBSTAT)
  
.ENDIF(ACCJOBS1)
  
RETURN(CONVERT) 
  
REVERT. ACCJOBS **********************************
EXIT. ACCJOBS 
REVERT(ABORT) ACCJOBS ****************************
*WEOR 
