ACCDAYF 
.PROC,ACCDAYF*I"ACCESS THE FILE *DAYFILS*", 
M       ' ACCESS MODE     (W,RESET,RETURN)     '=(W,RESET,RETURN),
DAYFILS ' DAYFILES FILE                        '=(*N=DAYFILS,*F), 
DAYFTMP ' TEMPORARY DAYFILES FILE              '=(*N=DAYFTMP,*F), 
DAYFLOC ' LOCK OUT FILE                        '=(*N=DAYFLOC,*F), 
DAYFOLD ' BACKUP FILE                          '=(*N=DAYFOLD,*F), 
. 
*IF,DEF,PDOC
.HELP 
  
THIS PROCEDURE IS USED TO ACCESS THE FILE DAYFILS.  THE PERMANENT 
FILE NAME TO ATTACH IS PASSED IN FROM THE CALLING PROCEDURE *ACCESS*. 
THE LOCAL FILE NAME IS ALWAYS DAYFILS.
  
.HELP,M 
  
*W* ATTACH FILE IN WRITE MODE, CREATE IT IF IT DOES NOT EXIST.
*RESET* PURGE FILE THEN DEFINE IT.
*RETURN*
  
.ENDHELP
*ENDIF
  
*************** A C C D A Y F ********************
  
  
.IF, ( $M$ .EQ. $W$ ) ,ACCDAYF1.
  
  ATTACH(#DAYFLOC=DAYFLOC/#M=W,NA)
  IF, FILE(#DAYFLOC, .NOT. AS) ,ACCDAYF3. 
    DEFINE(#DAYFLOC=DAYFLOC)
  ENDIF(ACCDAYF3) 
  PURGE(DAYFTMP/NA) 
  RETURN(#DAYFTMP)
  DEFINE(#DAYFTMP=DAYFTMP/#M=R) 
  ATTACH(#DAYFOLD=DAYFILS/NA) 
  IF, FILE(#DAYFOLD, .NOT. AS) ,ACCDAYF3. 
    DEFINE(#DAYFOLD=DAYFILS)
  ENDIF(ACCDAYF3) 
  
.ELSE(ACCDAYF1) 
.IF, ( $M$ .EQ. $RESET$ ) ,ACCDAYF1.
  
  RETURN(#DAYFLOC,#DAYFILS) 
  PURGE(DAYFLOC/NA) 
  DEFINE(#DAYFLOC=DAYFLOC)
  PURGE(DAYFILS/NA) 
  DEFINE(#DAYFILS=DAYFILS)
  WRITEF(#DAYFILS)
  RETURN(#DAYFILS,#DAYFLOC) 
  
.ELSE(ACCDAYF1) 
  
  .* #M=RETURN
  PURGE(DAYFOLD/NA) 
  RETURN(#DAYFTMP,#DAYFOLD) 
  CHANGE(DAYFOLD=DAYFILS,DAYFILS=DAYFTMP) 
  PURGE(DAYFOLD/NA) 
  RETURN(#DAYFLOC)
  
.ENDIF(ACCDAYF1)
  
RETURN(CONVERT) 
  
REVERT. ACCDAYF **********************************
EXIT. ACCDAYF 
REVERT(ABORT) ACCDAYF ****************************
*WEOR 
