*COMDECK     COMMOVE    - MOVE BLOCK OF CENTRAL MEMORY WORDS. 
          LIST   F,X
          SYSCOM B1 
          TITLE  MOVE - MOVE BLOCK OF CENTRAL MEMORY WORDS. 
          COMMENT  MOVE BLOCK OF CENTRAL MEMORY WORDS.
 MOVE     SPACE  4,8
**        THE FOLLOWING MACRO IS COPIED FROM NOS SYSTEXT. 
*         IT SHOULD BE IN (COMMON) CPUTEXT BUT IS NOT, AT PRESENT.
 MOVE     SPACE  4,8
***       MOVE - MOVE DATA BLOCK. 
* 
* 
*         MOVE   COUNT,FROM,TO
*         ENTRY  *COUNT* = WORD COUNT OF BLOCK TO BE MOVED. 
*                *FROM* = ADDRESS OF FIRST WORD OF BLOCK. 
*                *TO* = ADDRESS OF FIRST WORD OF DESTINATION. 
*         CALLS  MVE= (COMCMVE).
  
  
          PURGMAC MOVE
  
 MOVE     MACRO  C,F,T
  R= X1,C 
  R= X2,F 
  R= X3,T 
  RJ =XMVE= 
  ENDM
 MOVE     SPACE  4,8
**        MOVE  -  MOVE BLOCK OF CENTRAL MEMORY WORDS.
* 
*         R. H. GOODELL.     76/06/18.
* 
*         SYMPL-CALLABLE ENTRY POINTS, FOR DIRECT AND INDIRECT
*         ADDRESSING OF DATA AREAS. 
 MOVE     SPACE  4,8
**        MOVE - DIRECT ADDRESSING. 
* 
*         CALL MOVE (NWORDS, FROM, TO). 
  
  
 MOVE     SUBR   =           ENTRY/EXIT 
          SB1    1           (B1) = 1 
          SA2    A1+B1       (X2) = FROM FWA
          SA3    A2+B1       (X3) = TO FWA
          SA1    X1          (X1) = NWORDS
          SX2    X2 
          SX3    X3          CLEAR UPPER BITS 
          SX1    X1 
          MOVE   X1,X2,X3    MOVE DATA
          JP     EXIT.       RETURN 
 MOVEI    SPACE  4,8
**        MOVEI - INDIRECT ADDRESSING.
* 
*         CALL MOVEI (NWORDS, LOC (FROM), LOC (TO) ). 
  
  
 MOVEI    SUBR   =           ENTRY/EXIT 
          SB1    1           (B1) = 1 
          SA2    A1+B1       (X2) = LOC (FROM FWA)
          SA3    A2+B1       (X3) = LOC (TO FWA)
          SA1    X1          (X1) = NWORDS
          SA2    X2          (X2) = FROM FWA
          SA3    X3          (X3) = TO FWA
          SX1    X1 
          SX2    X2          CLEAR UPPER BITS 
          SX3    X3 
          MOVE   X1,X2,X3    MOVE DATA
          JP     EXIT.       RETURN 
 COMCMVE  SPACE  4,8
**        COMCMVE - COMPASS-CALLABLE MOVE ROUTINE.
* 
*         MOVE   NWORDS,FROM,TO 
  
  
*CALL     COMCMVE            MOVE BLOCK OF DATA.
  
  
          ENTRY  MVE= 
 CMUR     EQU    RA.CMU      SIGN BIT IS CMU-AVAILABLE FLAG 
  
  
          END 
