*COMDECK     COMFIT     - FILE INFORMATION TABLE ACCESS ROUTINES. 
          LIST   F,X
          SST 
          TITLE  FIT - FILE INFORMATION TABLE ACCESS ROUTINES.
          COMMENT FILE INFORMATION TABLE ACCESS ROUTINES. 
 FIT      SPACE  4,8
**        FIT  -  FILE INFORMATION TABLE ACCESS ROUTINES. 
* 
*         R. H. GOODELL.     77/04/06.
* 
*         *FIT* IS A COLLECTION OF FUNCTIONS, EACH OF WHICH RETURNS 
*         THE VALUE OF A FIELD IN THE FILE INFORMATION TABLE (FIT)
*         IN THE DATA CONTROL PART OF THE SUB-SCHEMA DIRECTORY. 
 FO$AK    SPACE  4,8
**        FO$AK - TRUE IF FIT CONTAINS FO=AK PARAMETER
*                   (FILE ORGANISATION = ACTUAL KEY). 
* 
*         FUNC FO$AK B. 
  
  
 FO$AK    SUBR   =           ENTRY/EXIT 
          SA1    =XTSUB 
          SA2    =XFITP      GET FIT ADDRESS
          IX3    X1+X2
          FETCH  X3,FO,X4    FETCH FILE ORGANISATION
          SX7    X4-#AK#
          SX6    1           (X6) = 1 
          ZR,X7  EXIT.       RETURN IF ACTUAL KEY 
          MX6    0
          JP     EXIT.       RETURN WITH (X6) = 0 IF NOT
 FO$IS    SPACE  4,8
**        FO$IS - TRUE IF FIT CONTAINS FO=IS PARAMETER
*                   (FILE ORGANISATION = INDEXED SEQUENTIAL). 
* 
*         FUNC FO$IS B. 
  
  
 FO$IS    SUBR   =           ENTRY/EXIT 
          SA1    =XTSUB 
          SA2    =XFITP      GET FIT ADDRESS
          IX3    X1+X2
          FETCH  X3,FO,X4    FETCH FILE ORGANISATION
          SX7    X4-#IS#
          SX6    1           (X6) = 1 
          ZR,X7  EXIT.       RETURN IF INDEXED SEQUENTIAL 
          MX6    0
          JP     EXIT.       RETURN WITH (X6) = 0 IF NOT
  
  
          END 
