*COMDECK DMSCON1
      /*****************************************************************
      * 
      * SINCE THE USER IS ALLOWED TO SPLIT LOGICAL LINES OVER TWO OR
      * MORE PHYSICAL LINES, GENERATE MUST BE ABLE TO CONSOLIDATE THE 
      * INFORMATION CONTAINED IN SPLIT LINES.  THE CONSOLIDATE UTILITIES
      * TAKE THE INFORMATION NEEDED FROM EACH LOGICAL CATEGORY LINE USED
      * BY CDCS GENERATE AND STORES IT IN THE CONSOLIDATE HOLDING AREA. 
      * IF ANY FIELD IS DUPLICATED WITHIN THE LOGICAL LINE, THE LAST
      * VALUE GIVEN IS THE ONE SAVED.  UPON RETURN, THE NEXT NEW LINE 
      * WILL HAVE BEEN MOVED INTO "CAT-WORK". 
  
  
      ******************************************************************
      * 
      * CON-SCH-STC.
      * 
      * A NEW SCHEMA STRUCTURE LINE IS INDICATED BY A NON-BLANK CATNAME 
      * FIELD.
  
       CON-SCH-STC. 
  
      * FIND FIRST VALID LINE.  DIAGNOSE ANY PREVIOUS LINE WITHOUT
      * CATNAME.
           MOVE SPACES TO CONSOLID-LINE.
           PERFORM UNTIL DATA-RETURN-CODE NOT = ZERO
             OR STC-SCH-CATNAME NOT = SPACES
  
             MOVE IDX-700 TO MSG-IDX
             MOVE CAT-LINE TO MSG-LINE
             MOVE "SCHEMA" TO MSG-NAME
             PERFORM ERROR-TYPE3 THRU ERROR-TYPE3-XIT 
  
             PERFORM MOVE-NEXT-LINE THRU MOVE-NEXT-LINE-XIT 
             PERFORM CHECK-COMMENTS THRU CHECK-COMMENTS-XIT 
           END-PERFORM
  
      * IF FOUND NO VALID LINE, EXIT. 
           IF DATA-RETURN-CODE NOT = ZERO 
           THEN 
             GO TO CON-SCH-STC-XIT
           END-IF 
  
       LOOP-SCH-STC.
  
      * SAVE ALL VALUES GIVEN IN THIS LINE. 
           IF STC-SCH-CATNAME NOT = SPACES
             MOVE STC-SCH-CATNAME TO SCH-STC-CNAME. 
           IF STC-SCH-NAME-TYPE NOT = SPACES
             MOVE STC-SCH-NAME-TYPE TO SCH-STC-CTYPE. 
           IF STC-SCH-INCLUDE NOT = SPACES
             MOVE STC-SCH-INCLUDE TO SCH-STC-INCL.
           IF STC-SCH-MASTER NOT = SPACES 
             MOVE STC-SCH-MASTER TO SCH-STC-AVERS.
  
      * MOVE NEXT LINE INTO "CAT-WORK" -- CHECK IF EXTENSION OF PREVIOUS
      * LINE. 
           PERFORM MOVE-NEXT-LINE THRU MOVE-NEXT-LINE-XIT.
           PERFORM CHECK-COMMENTS THRU CHECK-COMMENTS-XIT.
           IF DATA-RETURN-CODE = ZERO 
             AND STC-SCH-CATNAME = SPACES 
           THEN 
             GO TO LOOP-SCH-STC 
           END-IF 
  
       CON-SCH-STC-XIT. 
           EXIT.
