*COMDECK DMSADDSCH
  
  
      ******************************************************************
      * 
      * ADD-DBP-NAME
      * 
      * ADD-DBP-NAME READS THE FIRST RECORD OF THE GIVEN DBPROC,
      * DIAGNOSING IF ITS ENTRY IS MISSING.  THEN IT READS THE NAMES
      * CATEGORY AND OUTPUTS THE DBP'S DMSNAME.  ALL COMMENTS IN THE
      * NAMES CATEGORY ARE ALSO OUTPUT. 
      * 
      * INPUT:   DBP-CATNAME      - CATNAME OF THE REQUESTED DBPROC 
      * 
      * OUTPUT:  FOUND-ENTITY     - "N" IF CATALOGUE ENTRY EMPTY OR 
      *                             FOR ENTITY OTHER THAN DBPROC
  
       ADD-DBP-NAME.
           PERFORM SAVE-ITEM-INFO THRU SAVE-ITEM-INFO-XIT.
           PERFORM CLEAR-DATA-ENTRY THRU CLEAR-DATA-ENTRY-XIT.
           MOVE "N" TO FOUND-ENTITY.
  
      * READ FIRST RECORD OF DBPROC ENTRY INTO "DATA-RECORD". 
           MOVE DBP-CATNAME TO DATA-ENTRY-NAME. 
           PERFORM MOVE-CAT-LINE THRU MOVE-CAT-LINE-XIT.
  
      * IF DBPROC ENTRY MISSING, DIAGNOSE AND RETURN. 
           IF DATA-RETURN-CODE NOT = ZERO 
           THEN 
             MOVE IDX-500 TO MSG-IDX
             PERFORM ERROR-TYPE1 THRU ERROR-TYPE1-XIT 
             GO TO END-ADD-DBP-NAME 
           END-IF 
  
      * IF ENTRY NOT FOR DBPROC ENTITY, DIAGNOSE AND RETURN.
           IF DATA-HDR-ENT-ID NOT = ENT-ID-DBP
           THEN 
             MOVE IDX-520 TO MSG-IDX
             PERFORM ERROR-TYPE1 THRU ERROR-TYPE1-XIT 
             GO TO END-ADD-DBP-NAME 
           END-IF 
  
           MOVE "Y" TO FOUND-ENTITY.
  
      * MOVE PROCEDURE'S NAMES CATEGORY TO "CAT-WORK".
           MOVE CAT-NO-NAMES TO DATA-ENTRY-CAT. 
           PERFORM MOVE-CAT-LINE THRU MOVE-CAT-LINE-XIT.
           PERFORM CHECK-COMMENTS THRU CHECK-COMMENTS-XIT.
  
      * IF NO DMSNAME, ASSUME THE CATNAME.
           IF DATA-RETURN-CODE NOT = ZERO 
             OR NAME-DBP-DMSNAME = SPACES 
           THEN 
             MOVE DBP-CATNAME (1 : 7) TO OUT-FIELD
           ELSE 
             MOVE NAME-DBP-DMSNAME (1 : 7) TO OUT-FIELD 
           END-IF 
  
      * OUTPUT REMAINING COMMENTS IN THIS CATEGORY IF ANY.
           PERFORM CHECK-COMMENTS THRU CHECK-COMMENTS-XIT.
  
      * FIND LENGTH OF PROCEDURE-NAME AND ADD IT TO OUTPUT LINE.
           PERFORM FIND-LENGTH THRU FIND-LENGTH-XIT.
           PERFORM ADD-TO-STMT THRU STMT-XIT. 
  
       END-ADD-DBP-NAME.
           PERFORM RESTORE-ITEM-INFO THRU RESTORE-ITEM-INFO-XIT.
  
       ADD-DBP-NAME-XIT.
           EXIT.
