*COMDECK  DISPLAY2
00001                                                                    DISPLAY
00002 ******************************************************************DISPLAY2
00003 *  LOGICAL I/O FOR PRINTER                                           LV002
00004 ******************************************************************   CL**2
00005  DISPLAY-LINE.                                                    DISPLAY2
00006      IF LINE-CT LESS THAN MAX-LINES                               DISPLAY2
00007          GO TO 0500-DISPLAY-LINE.                                 DISPLAY2
00008      MOVE PRT-CTL TO SAVE-PRT-CTL.                                   CL**2
00009      IF LINE-CT EQUAL 99                                             CL**2
00010          GO TO 0100-DISPLAY-LINE.                                 DISPLAY2
00011 ****************************************************************  DISPLAY2
00012 *        PRINT END OF PAGE MESSAGE                                   CL**2
00013 ****************************************************************  DISPLAY2
00014      MOVE SPACE-1 TO PRT-CTL.                                        CL**2
00015      MOVE EOP-MSG TO PRT-EOP-MSG.                                 DISPLAY2
00016      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                      DISPLAY2
00017  0100-DISPLAY-LINE.                                                  CL**2
00018 ****************************************************************  DISPLAY2
00019 *         PRINT HEADING LINES                                        CL**2
00020 ****************************************************************  DISPLAY2
00021      ADD 1 TO PAGE-NO.                                            DISPLAY2
00022      MOVE PAGE-NO TO PRT-PAGE-NO.                                    CL**2
00023      IF 8BY11-FLAG EQUAL "D"                                      DISPLAY2
00024          GO TO 0100-TERMINAL.                                     DISPLAY2
00025      MOVE CON-TITLE TO PRT-PROP.                                     CL**2
00026      IF 8BY11-FLAG EQUAL "N"                                         CL**2
00027          MOVE PRT-PAGE-CON TO PRT-PAGE.                              CL**2
00028      MOVE HOF-IND TO PRT-CTL.                                     DISPLAY2
00029      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                      DISPLAY2
00030      IF 8BY11-FLAG EQUAL "N"                                         CL**2
00031          MOVE CON-USER TO PRT-PROP                                   CL**2
00032          MOVE PRT-DATE1-CON TO PRT-DATE1                             CL**2
00033      ELSE                                                            CL**2
00034          MOVE CON-USER TO CON-USER-811                               CL**2
00035          MOVE PRT-DATE1-CON TO DATE1-811                             CL**2
00036          MOVE PRT-PAGE-CON TO PAGE-811.                              CL**2
00037      MOVE SPACE-1 TO PRT-CTL.                                     DISPLAY2
00038      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                      DISPLAY2
00039      IF 8BY11-FLAG EQUAL "Y"                                      DISPLAY2
00040          MOVE CON-DC TO PRT-TITLE-811                                CL**2
00041          MOVE PRT-REV-NO-CON TO PRT-DATE1-811                     DISPLAY2
00042      ELSE MOVE CON-DC TO PRT-DC                                   DISPLAY2
00043          MOVE PRT-REV-NO-CON TO PRT-DATE1.                        DISPLAY2
00044      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                      DISPLAY2
00045      IF 8BY11-FLAG EQUAL "Y"                                      DISPLAY2
00046          MOVE REPORT-TITLE-LONG TO PRT-TITLE-811                     CL**2
00047          MOVE PRT-DATE2-CON TO PRT-DATE1-811                      DISPLAY2
00048      ELSE MOVE PRT-DATE2-CON TO PRT-DATE1.                        DISPLAY2
00049      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00050      IF 8BY11-FLAG EQUAL "N"                                         CL**2
00051          MOVE REPORT-TITLE-LONG TO PRT-TITLE                      DISPLAY2
00052          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                   DISPLAY2
00053          MOVE 6 TO LINE-CT                                        DISPLAY2
00054      ELSE MOVE 5 TO LINE-CT.                                         CL**2
00055      IF USER-TITLE EQUAL SPACE                                       CL**2
00056          GO TO 0300-DISPLAY-LINE.                                    CL**2
00057      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00058      IF 8BY11-FLAG EQUAL "Y"                                         CL**2
00059          MOVE USER-TITLE TO PRT-TITLE-811                            CL**2
00060      ELSE                                                            CL**2
00061          MOVE USER-TITLE TO PRT-TITLE.                               CL**2
00062      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00063      ADD 2 TO LINE-CT.                                               CL**2
00064  0300-DISPLAY-LINE.                                                  CL**2
00065      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00066      PERFORM USER-ROUTINE THRU USER-ROUTINE-XIT.                     CL**2
00067      MOVE SAVE-PRT-CTL TO PRT-CTL.                                DISPLAY2
00068 ****************************************************************  DISPLAY2
00069 *         PRINT THE LINE                                             CL**2
00070 ****************************************************************  DISPLAY2
00071  0500-DISPLAY-LINE.                                               DISPLAY2
00072      PERFORM RPT-PRINT811 THRU RPT-PRINT811-XIT.                     CL**2
00073      ADD PRT-CTL TO LINE-CT.                                         CL**2
00074      MOVE STD-REPORT-REC TO PRINT-DATA.                              CL**2
00075      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00076      MOVE 1 TO PRT-CTL.                                              CL**2
00077      MOVE SPACES TO STD-REPORT-REC.                                  CL**2
00078  DISPLAY-LINE-XIT.                                                DISPLAY2
00079      EXIT.                                                        DISPLAY2
00080  0100-TERMINAL.                                                   DISPLAY2
00081      GO TO DISPLAY-LINE-XIT.                                      DISPLAY2
00082  EOP-RT.                                                             CL**2
00083      MOVE 2 TO PRT-CTL.                                              CL**2
00084      MOVE EOP-MSG TO PRT-EOP-MSG.                                    CL**2
00085      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00086  EOP-RT-XIT.                                                         CL**2
00087      EXIT.                                                           CL**2
