*DECK     DCRPT265
00001  IDENTIFICATION DIVISION.                                         04/25/78
       PROGRAM-ID. RPT265.
*CALL COPYRIGHT 
      *    THIS MODULE PRINTS A UNIT FOR A $REPORT OR $FILE REQUEST 
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR UNITS.  THE MODULE ALSO FORMATS INDEX REPORT 
      *    DETAIL RECORDS.
      *    ENTRY TYPE 65 = UNIT 
00011  ENVIRONMENT DIVISION.                                            DCRPT265
00012  CONFIGURATION SECTION.                                           DCRPT265
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
00015  INPUT-OUTPUT SECTION.                                            DCRPT265
00016  DATA DIVISION.                                                   DCRPT265
*CALL RPTCS 
*CALL     WRKSTG77                                                         CL**5
*CALL     MAST1WS                                                          CL**5
*CALL     TESTWACOM                                                        CL**5
*CALL     DCDWA65                                                          CL**5
00021  01  COMMON-RPTDATA.                                              DCRPT265
00022 *                                                                 DCRPT265
00023 *    THIS REFINES LINE FORMATS  FIELD VALUES, CODES AND WORK AREASDCRPT265
00024 *    WHICH ARE COMMON TO ALL ENTRY TYPES.                         DCRPT265
00025 ******************************************************************DCRPT265
00026 *    STANDARD CATEGORY RPT DETAIL LINES COMMON TO ALL ENTRY TYPES DCRPT265
00027 ******************************************************************DCRPT265
00028      03  00-CAT-DETAIL-LINES.                                     DCRPT265
00029 *    CONTROL CATEGORY                                             DCRPT265
00030          05  CAT00010-LINE.                                       DCRPT265
00031              07  FLD0001005-HDG  PICTURE X(11).                   DCRPT265
00032              07  FLD0001005-VAL  PICTURE X(32).                   DCRPT265
00033              07  FILLER          PICTURE X.                       DCRPT265
00034              07  FLD0001010-HDG  PICTURE X(7).                    DCRPT265
00035              07  FLD0001010-VAL.                                     CL**2
00036                  09  FLD0001010-POS1 PICTURE X.                      CL**2
00037                  09  FILLER          PICTURE X(7).                   CL**2
00038              07  FILLER          PICTURE X.                       DCRPT265
00039              07  FLD0001015-HDG  PICTURE X(9).                    DCRPT265
00040              07  FLD0001015-VAL  PICTURE X.                       DCRPT265
00041 *    KEYWORD CATEGORY                                             DCRPT265
00042          05  CAT00020-LINE REDEFINES CAT00010-LINE.               DCRPT265
00043              07  FLD0002005-HDG  PICTURE X(3).                    DCRPT265
00044              07  FLD0002005-VAL PICTURE X(67).                       CL**2
00045 *"   DESCRIPTION CATEGORY                                         DCRPT265
00046          05  CAT00030-LINE REDEFINES CAT00020-LINE.               DCRPT265
00047              07  FLD0003005-VAL  PICTURE X.                       DCRPT265
00048              07  FLD0003010-VAL  PICTURE X(66).                   DCRPT265
00049              07  FILLER          PICTURE X(3).                    DCRPT265
00050 *    OTHER CATEGORY                                               DCRPT265
00051          05  CAT00900-LINE REDEFINES CAT00020-LINE.               DCRPT265
00052              07  FLD0090005-VAL  PICTURE X.                       DCRPT265
00053              07  FLD0090010-VAL  PICTURE X(66).                   DCRPT265
00054              07  FILLER          PICTURE X(3).                    DCRPT265
00055 ******************************************************************DCRPT265
00056 *    STANDARD FIELD HEADING CONSTANTS FOR DETAIL LINES            DCRPT265
00057 *        COMMON TO ALL ENTRY TYPES                                DCRPT265
00058 ******************************************************************DCRPT265
00059      03  00-FIELD-HDG-CONSTANTS.                                  DCRPT265
00060          05  FLD0001005-HCONA    PICTURE X(11)  VALUE             DCRPT265
00061             "  ALIAS OF ".                                        DCRPT265
00062          05  FLD0001010-HCON     PICTURE X(7)   VALUE             DCRPT265
00063             "STATUS=".                                            DCRPT265
00064          05  FLD0001015-HCON     PICTURE X(9)   VALUE             DCRPT265
00065             "SECURITY=".                                          DCRPT265
00066          05  FLD0002005-HCON     PICTURE X(3)   VALUE             DCRPT265
00067             "   ".                                                   CL**2
00068          05  FLD0001005-HCONV    PICTURE X(11)  VALUE             DCRPT265
00069             "VERSION OF ".                                        DCRPT265
00070          05  SUB-HEADING-LINE.                                       CL**2
00071              07  FILLER          PICTURE X(14)   VALUE               CL**2
00072             "CATALOGUE NAME".                                        CL**2
00073              07  FILLER          PICTURE X(8)    VALUE SPACE.        CL**2
00074              07  FILLER          PICTURE X(8)    VALUE               CL**2
00075             "REV LINE".                                              CL**2
00076              07  FILLER          PICTURE X(5)    VALUE SPACE.        CL**2
00077              07  FILLER          PICTURE X(4)    VALUE               CL**2
00078             "TYPE".                                                  CL**2
00079              07  FILLER          PICTURE X(92)   VALUE SPACE.        CL**2
00080          05  CONTINUATION-LINE.                                      CL**2
00081              07  CATA-NAME-LINE  PICTURE X(56)   VALUE SPACE.        CL**2
00082              07  FILLER          PICTURE X(72)   VALUE SPACE.        CL**2
00083              07  STATEMENT-LINE.                                     CL**2
00084                  09  FILLER      PICTURE X(5)    VALUE SPACE.        CL**2
00085                  09  FILLER      PICTURE X(30)   VALUE               CL**2
00086                 "* CONTINUED FROM PREVIOUS PAGE".                    CL**2
00087                  09  FILLER      PICTURE X(97)   VALUE SPACE.        CL**2
00088 *****************************************************************    CL**2
00089 *    FIELD CODES AND THIER MEANINGS                                  CL**2
00090 *       COMMON TO ALL ENTRY TYPES-FOR COMMON CATS                    CL**2
00091 **********************************************************           CL**2
00092      03  00-CAT-CODES.                                               CL**2
00093 *  STATUS OF ENTRY                                                   CL**2
00094          05  FLD0001010-CV       PICTURE X(4)    VALUE               CL**2
00095         "EPO9".                                                      CL**2
00096          05  FLD0001010-CD REDEFINES FLD0001010-CV.                  CL**2
00097              07  FLD0001010-CODES PICTURE X OCCURS 4.                CL**2
00098          05  FLD0001010-MV       PICTURE X(32)   VALUE               CL**2
00099         "EXISTINGPROPOSEDOBSOLETEXXXXXXXX".                          CL**2
00100          05  FLD0001010-MD   REDEFINES FLD0001010-MV.                CL**2
00101              07  FLD0001010-MNG  PICTURE X(8) OCCURS 4.              CL**2
00102      03  WORK-FIELDS.                                             DCRPT265
00103          05  DATA-OPEN-SW PICTURE X.                                 CL**2
00104          05  HIT-WORK-REC.                                        DCRPT265
00105          07  HIT-WORK-NAME       PICTURE X(32).                   DCRPT265
00106          07  HIT-WORK-ENTTYPE    PICTURE XX.                      DCRPT265
00107          05  HIT-TBL-LIMIT       PICTURE   99    VALUE            DCRPT265
00108            25.                                                    DCRPT265
00109          05  HIT-TBL-LIMIT-PLUS1 PICTURE   99    VALUE            DCRPT265
00110              26.                                                  DCRPT265
00111          05  FRLINE-LIMIT        PICTURE 9(4).                    DCRPT265
00112          05  TOLINE-LIMIT        PICTURE 9(4).                    DCRPT265
00113          05  FORLINE-LIMIT       PICTURE 9(4).                    DCRPT265
00114          05  CATLINE-COUNTER     PICTURE 9(4).                    DCRPT265
00115          05  ENTRY-NAME          PICTURE X(32).                   DCRPT265
00116          05  ENTRY-TYPE-NO       PICTURE 99.                      DCRPT265
00117          05  ENTRY-TYPE-NAME     PICTURE X(8).                    DCRPT265
00118          05  CATEGORY-NUMBER     PICTURE XXX.                     DCRPT265
00119          05  CATEGORY-OUTPUT-SW  PICTURE X.                       DCRPT265
00120          05  1ST-HIT-OVER-SW  PICTURE X VALUE "X".                   CL**2
00121          05  HIT-COUNTER   PICTURE 9(5) VALUE 0.                     CL**2
00122          05  HITS-PER-RECORD  PICTURE 99 VALUE 91.                   CL**2
00123          05  CON-KEY          PICTURE S9(8) COMP SYNC.               CL**2
00124          05  SUB1                PICTURE   S99  COMP SYNC.        DCRPT265
00125          05  SUB2                PICTURE   S99  COMP SYNC.        DCRPT265
00126          05  SUB3                PICTURE   S99  COMP SYNC.        DCRPT265
00127          05  SUB4                PICTURE   S99  COMP SYNC.        DCRPT265
00128          05  SUB5                PICTURE   S99  COMP SYNC.        DCRPT265
00129          05  SUB6                PICTURE   S99  COMP SYNC.        DCRPT265
00130           05  DISPLAY-LINE-LENGTH PICTURE XXX VALUE "132".           CL**2
00131      03  QUERY-MESSAGES.                                          DCRPT265
00132          05  NO-LINES-MSG.                                        DCRPT265
00133              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT265
00134              07  NLM             PICTURE X(55)   VALUE            DCRPT265
00135             "DCRPT-015-I * REQUESTED LINES NOT PRESENT FOR CATEGOR   CL**2
00136 -           "Y.".                                                 DCRPT265
00137          05  NO-CAT-MSG.                                          DCRPT265
00138              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT265
00139              07  NC7             PICTURE X(45)   VALUE            DCRPT265
00140             "DCRPT-020-I * REQUESTED CATEGORY NOT DEFINED.".         CL**2
00141              07  FILLER          PICTURE X(9) VALUE SPACES.       DCRPT265
00142          05  NO-CATS-MSG.                                         DCRPT265
00143              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT265
00144              07  NCPM            PICTURE X(47)   VALUE            DCRPT265
00145             "DCRPT-025-I * REQUESTED CATEGORIES NOT DEFINED.".       CL**2
00146              07  FILLER          PICTURE X(9)    VALUE SPACES.    DCRPT265
00153          05  LIST-LINE-MSG.                                       DCRPT265
00154              07 FILLER           PICTURE XX    VALUE SPACES.      DCRPT265
00155              07  LIST-LINE-NAME  PICTURE X(32).                   DCRPT265
00156              07  FILLER          PICTURE XX    VALUE SPACES.      DCRPT265
00157              07  LIST-LINE-ENTTYPE PICTURE X(8) VALUE                CL**2
00158             "USERS   ".                                              CL**2
00159              07  FILLER          PICTURE X(12) VALUE SPACES.      DCRPT265
*CALL     RPTDEF65                                                         CL**5
*CALL     QTBL2                                                            CL**2
*CALL     RPTWORK                                                          CL**2
00179                                                                    DCRPT26
00180  PROCEDURE DIVISION.                                                 CL**2
*CALL     CATRTS                                                           CL**2
00188 *                                                                 DCRPT265
00189 *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY                   DCRPT265
00190 *                                                                 DCRPT265
00191  3400-INIT-LINELIMS.                                              DCRPT265
00192      IF QTBL-OUT-FRLINE EQUAL TO SPACES                           DCRPT265
00193          MOVE 0001 TO FRLINE-LIMIT                                DCRPT265
00194         ELSE                                                      DCRPT265
00195          MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.                    DCRPT265
00196      IF QTBL-OUT-TOLINE EQUAL TO SPACES                           DCRPT265
00197          MOVE 9999 TO TOLINE-LIMIT                                DCRPT265
00198         ELSE                                                      DCRPT265
00199          MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.                    DCRPT265
00200      IF QTBL-OUT-FORLINES EQUAL TO SPACES                         DCRPT265
00201          MOVE 9999 TO FORLINE-LIMIT                               DCRPT265
00202         ELSE                                                      DCRPT265
00203          MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT.                 DCRPT265
00204 *                                                                 DCRPT265
00205 *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY        DCRPT265
00206 *                                                                 DCRPT265
00207      MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.                           CL**2
00208      MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME.                       DCRPT265
00209      MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.                    DCRPT265
00210      MOVE "N" TO CATEGORY-OUTPUT-SW.                              DCRPT265
00211      IF CATEGORY-NUMBER EQUAL TO "999"                            DCRPT265
00212          GO TO 3450-SHOW-ALL.                                     DCRPT265
00213      IF CATEGORY-NUMBER EQUAL TO "998"                               CL**2
00214          GO TO 3465-SHOW-COMP.                                       CL**2
00215      IF CATEGORY-NUMBER EQUAL TO "996"                            DCRPT265
00216          GO TO 3450-SHOW-ALL.                                     DCRPT265
00217      IF CATEGORY-NUMBER EQUAL TO "997"                            DCRPT265
00218          GO TO 3460-SHOW-CHAR.                                    DCRPT265
00219      IF CATEGORY-NUMBER EQUAL TO "995"                               CL**2
00220          GO TO 3467-SHOW-PERS.                                       CL**2
00221 *                                                                 DCRPT265
00222 *    SHOW ONE CATEGORY HE ASKED FOR                               DCRPT265
00223 *                                                                    CL**2
00224      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00225      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00226 *                                                                 DCRPT265
00227 *    SHOW ALL                                                     DCRPT265
00228 *                                                                 DCRPT265
00229  3450-SHOW-ALL.                                                   DCRPT265
00230      MOVE "010" TO CATEGORY-NUMBER.                               DCRPT265
00231      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00232      MOVE "020" TO CATEGORY-NUMBER.                               DCRPT265
00233      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00234 *                                                                    CL**2
00235  3460-SHOW-CHAR.                                                  DCRPT265
00236 *                                                                    CL**2
00237      MOVE "030" TO CATEGORY-NUMBER.                               DCRPT265
00238      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00239      IF QTBL-OUT-CAT EQUAL TO "996"                               DCRPT265
00240          GO TO 3470-CHECK-SUPER.                                  DCRPT265
00241      MOVE "700" TO CATEGORY-NUMBER.                                  CL**2
00242      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00243      MOVE "900" TO CATEGORY-NUMBER.                                  CL**2
00244      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT265
00245      IF QTBL-OUT-CAT EQUAL TO "997"                                  CL**2
00246          GO TO 3470-CHECK-SUPER.                                     CL**2
00247  3465-SHOW-COMP.                                                     CL**2
00248      IF QTBL-OUT-CAT EQUAL TO "999"                                  CL**2
00249          GO TO 3466-JUST-COMP.                                       CL**2
00250      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00251      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00252  3466-JUST-COMP.                                                     CL**2
00253      MOVE "800" TO CATEGORY-NUMBER.                                  CL**2
00254      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00255      GO TO 3470-CHECK-SUPER.                                         CL**2
00256  3467-SHOW-PERS.                                                     CL**2
00257      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00258      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00259      MOVE "140" TO CATEGORY-NUMBER.                                  CL**2
00260      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00261 *                                                                 DCRPT265
00262 *    CHECK TO SEE IF ANY OUTPUT FOR UNIT                             CL**2
00263 *                                                                 DCRPT265
00264  3470-CHECK-SUPER.                                                DCRPT265
00265      IF CATEGORY-OUTPUT-SW EQUAL TO "Y"                           DCRPT265
00266          GO TO 1100-NEXT-OUTPUT.                                     CL**2
00267  3475-NO-CATS.                                                    DCRPT265
00268      MOVE NO-CATS-MSG TO STD-RPT-MESSAGE.                         DCRPT265
00269      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00270          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00271      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00272      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00273                                                                    DCRPT26
00274 ******************************************************************DCRPT265
00275 *                                                                 DCRPT265
00276 *    DISPLAY CATEGORY                                             DCRPT265
00277 *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS       DCRPT265
00278 *        EITHER A 70, 80 OR 132 CHARACTER LINE                    DCRPT265
00279 *                                                                 DCRPT265
00280 ******************************************************************DCRPT265
00281  3500-DISPLAY-CATEGORY.                                           DCRPT265
00282      MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.                      DCRPT265
00283      MOVE 0001 TO CATLINE-COUNTER.                                DCRPT265
00284      PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.                DCRPT265
00285      IF DATA-RETURN-CODE EQUAL TO "0"                                CL**2
00286          GO TO 3510-CK-1ST-LINE.                                     CL**2
00287 *                                                                    CL**2
00288 *    CHECK FOR SUPER CAT AND BYPASS MSG                              CL**2
00289 *                                                                    CL**2
00290      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00291          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00292      GO TO 3715-NOCAT-LINE.                                          CL**2
00293 *                                                                 DCRPT265
00294 *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE             DCRPT265
00295 *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT        DCRPT265
00296 *                                                                 DCRPT265
00297  3510-CK-1ST-LINE.                                                DCRPT265
00298      IF CAT-LINE LESS THAN FRLINE-LIMIT                           DCRPT265
00299          GO TO 3515-BYPASS-LINE.                                  DCRPT265
00300 *                                                                 DCRPT265
00301 *    RETRIEVE 1ST LINE OF CATEGORY                                DCRPT265
00302 *                                                                 DCRPT265
00303      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT265
00304          GO TO 3517-CK-SUPER-CAT.                                    CL**2
00305      GO TO 3520-OUTPUT-CATHDR.                                    DCRPT265
00306  3515-BYPASS-LINE.                                                DCRPT265
00307      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT265
00308      IF DATA-RETURN-CODE EQUAL TO "0" OR "3"                      DCRPT265
00309          GO TO 3510-CK-1ST-LINE.                                  DCRPT265
00310      GO TO 3715-NOCAT-LINE.                                          CL**2
00311  3517-CK-SUPER-CAT.                                                  CL**2
00312      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00313          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00314      GO TO 3715-NOCAT-LINE.                                          CL**2
00315 *                                                                 DCRPT265
00316 *    LOOKUP AND OUTPUT CATEGORY HEADER LINE                       DCRPT265
00317 *                                                                 DCRPT265
00318  3520-OUTPUT-CATHDR.                                              DCRPT265
00319      MOVE 1 TO SUB4.                                              DCRPT265
00320  3525-NEXT-CATNUM.                                                DCRPT265
00321      IF ENT65-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER                CL**2
00322          GO TO 3530-DISPLAY-HDG.                                  DCRPT265
00323      ADD 1 TO SUB4.                                               DCRPT265
00324      GO TO 3525-NEXT-CATNUM.                                      DCRPT265
00325  3530-DISPLAY-HDG.                                                DCRPT265
00326      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00327          GO TO 3532-FMT-FILE-DETAIL.                                 CL**2
00328      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00329      MOVE ENT65-CATHDRS (SUB4) TO CATEGORY-HEADER.                   CL**2
00330      MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.                     CL**2
00331      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00332          MOVE "Y" TO CATEGORY-811-SW                                 CL**2
00333          MOVE CATEGORY-HEADER TO CAT-HEADER-811                      CL**2
00334          MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.                 CL**2
00335      MOVE 2 TO PRT-CTL.                                              CL**2
00336      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00337      MOVE 1 TO PRT-CTL.                                              CL**2
00338      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00339      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00340      MOVE "Y" TO CATEGORY-OUTPUT-SW.                              DCRPT265
00341 *****************************************************************    CL**2
00342 *                                                                    CL**2
00343 *     FORMAT$FILE REQUEST DETAIL RECORDS                             CL**2
00344 *          A RECORD IS FORMATTED FOR EACH SELECTED LINE              CL**2
00345 *                                                                    CL**2
00346 ***************************************************************      CL**2
00347  3532-FMT-FILE-DETAIL.                                               CL**2
00348      IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"               CL**2
00349          GO TO 3540-FMT-CAT-DETAIL.                                  CL**2
00350 *                                                                    CL**2
00351 *     USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY     CL**2
00352 *                                                                    CL**2
00353      MOVE 1 TO HDG-SUB.                                              CL**2
00354 *     FIND THE FIRST DASH IN THE HDG                                 CL**2
00355  3534-FIND-DASH.                                                     CL**2
00356      IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"                     CL**2
00357          ADD 1 TO HDG-SUB                                            CL**2
00358          GO TO 3534-FIND-DASH.                                       CL**2
00359  3536-BYPASS-DASH.                                                   CL**2
00360      IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-"                      CL**2
00361          ADD 1 TO HDG-SUB                                            CL**2
00362          GO TO 3536-BYPASS-DASH.                                     CL**2
00363      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.           CL**2
00364      ADD 1 TO HDG-SUB.                                               CL**2
00365      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.           CL**2
00366      ADD 1 TO HDG-SUB.                                               CL**2
00367      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.           CL**2
00368 *                                                                    CL**2
00369 *     FORMAT DETAIL RECORD                                           CL**2
00370 *                                                                    CL**2
00371      MOVE SPACES TO USER-LINE200-REC.                                CL**2
00372      MOVE RTBL-HDR-REQNO TO USER-L200-REQNO.                         CL**2
00373      MOVE EXT-HOLD-CATNAME TO USER-L200-CNAME.                       CL**2
00374      MOVE EXT-HOLD-TYPE TO USER-L200-ENTTYPE.                        CL**2
00375      MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT.                      CL**2
00376      MOVE CAT-LENGTH    TO USER-L200-LENGTH.                         CL**2
00377      MOVE CAT-LINE      TO USER-L200-LINE.                           CL**2
00378      MOVE CAT-REV       TO USER-L200-REV.                            CL**2
00379      MOVE CAT-DETAIL    TO USER-L200-DATA.                           CL**2
00380      MOVE "U" TO CATTBL-FILE-TYPE.                                   CL**2
00381      IF CAT-LENGTH GREATER THAN 67                                   CL**2
00382      MOVE "5" TO USER-L200-RECTYPE                                   CL**2
00383          MOVE "5" TO CATTBL-RECORD-TYPE                              CL**2
00384      ELSE                                                            CL**2
00385      MOVE "4" TO USER-L200-RECTYPE                                   CL**2
00386          MOVE "4" TO CATTBL-RECORD-TYPE.                             CL**2
00387      PERFORM 0900-USERFILE-OUT THRU 0999-USERFILE-OUT-XIT.           CL**2
00388      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00389          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00390 *                                                                 DCRPT265
00391 *    FORMAT CATEGORY DETAIL LINES                                 DCRPT265
00392 *        IF 70 CHR FORMAT PUT OUT LINE NO ON SEP LINE             DCRPT265
00393 *                                                                 DCRPT265
00394  3540-FMT-CAT-DETAIL.                                             DCRPT265
00395      IF RTBL-OPT-FORMAT EQUAL "S"                                    CL**2
00396          GO TO 3550-FMT-LINE-PREFIX.                              DCRPT265
00397      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00398          GO TO 3550-FMT-LINE-PREFIX.                                 CL**2
00399      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00400      GO TO 3560-FORMAT-REPORT.                                       CL**2
00401  3550-FMT-LINE-PREFIX.                                            DCRPT265
00402      IF CATEGORY-NUMBER NOT EQUAL TO "800"                           CL**2
00403          GO TO 3555-MOVE-LINE.                                       CL**2
00404      IF FIRST-REC-SW EQUAL TO "Y"                                    CL**2
00405          GO TO 3560-FORMAT-REPORT.                                   CL**2
00406  3555-MOVE-LINE.                                                     CL**2
00407      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00408          MOVE 98765 TO STDRPT-REVNO                                  CL**2
00409          MOVE CAT-LINE TO STDRPT-LINE                                CL**2
00410          GO TO 3560-FORMAT-REPORT                                    CL**2
00411      ELSE                                                            CL**2
00412          MOVE CAT-REV TO STDRPT-REVNO                                CL**2
00413      MOVE CAT-LINE TO STDRPT-LINE.                                   CL**2
00414 *                                                                 DCRPT265
00415 *    CHECK FOR COMMENT LINE                                       DCRPT265
00416  3560-FORMAT-REPORT.                                                 CL**2
00417      IF CAT-COMMENT NOT EQUAL TO "*"                                 CL**2
00418          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00419      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00420          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00421      PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT.               CL**2
00422      GO TO 3700-GET-NEXT-LINE.                                       CL**2
00423 *                                                                 DCRPT265
00424 *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT           DCRPT265
00425 *                                                                 DCRPT265
00426  3565-CATEGORY-CHECK.                                                CL**2
00427      IF CATEGORY-NUMBER EQUAL TO "010"                            DCRPT265
00428          PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT         DCRPT265
00429          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00430      IF CATEGORY-NUMBER EQUAL TO "020"                            DCRPT265
00431          PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT         DCRPT265
00432          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00433      IF CATEGORY-NUMBER EQUAL TO "030"                            DCRPT265
00434          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT         DCRPT265
00435          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00436      IF CATEGORY-NUMBER EQUAL TO "700"                               CL**2
00437          PERFORM 30000-FMT-CAT700 THRU 30070-FMT-CAT700-XIT          CL**2
00438          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00439      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00440          PERFORM 30800-FMT-CAT800 THRU 30899-FMT-CAT800-XIT          CL**2
00441          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00442      IF CATEGORY-NUMBER EQUAL TO "900"                            DCRPT265
00443          PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT         DCRPT265
00444          GO TO 3700-GET-NEXT-LINE.                                DCRPT265
00445      GO TO 3710-NOCAT-DATA.                                          CL**2
00446 *                                                                 DCRPT265
00447 *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END                  DCRPT265
00448 *                                                                 DCRPT265
00449  3700-GET-NEXT-LINE.                                              DCRPT265
00450      IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT                    DCRPT265
00451        GO TO 3749-DISPLAY-CAT-XIT.                                DCRPT265
00452      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT265
00453      IF DATA-RETURN-CODE EQUAL TO  1 OR 2                         DCRPT265
00454          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT265
00455      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT265
00456          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT265
00457      ADD 1 TO CATLINE-COUNTER.                                       CL**2
00458      GO TO 3532-FMT-FILE-DETAIL.                                     CL**2
00459  3749-DISPLAY-CAT-XIT.                                            DCRPT265
00460      EXIT.                                                        DCRPT265
00461                                                                    DCRPT26
00462 *                                                                 DCRPT265
00463 *   FORMAT WARNING AND INFORMATION MESSAGES                       DCRPT265
00464 *                                                                 DCRPT265
00465  3710-NOCAT-DATA.                                                 DCRPT265
00466      MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE.                 DCRPT265
00467      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00468          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00469      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00470      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00471  3715-NOCAT-LINE.                                                 DCRPT265
00472      MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE.                 DCRPT265
00473      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00474          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00475      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00476      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00477                                                                    DCRPT26
00478  3800-NOMORE-HITS.                                                DCRPT265
00479 *                                                                 DCRPT265
00480 *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE                DCRPT265
00481 *                                                                 DCRPT265
00482      GO TO 1500-REPORT-END.                                          CL**2
00483                                                                    DCRPT26
00484 ***************************************************************** DCRPT265
00485 *                                                                 DCRPT265
00486 *    FORMAT CATEGORY 010 DETAIL LINE                              DCRPT265
00487 *        CATEGORY 010 = CONTROL                                   DCRPT265
00488 *                                                                 DCRPT265
00489 ***************************************************************** DCRPT265
00490  5100-FMT-CAT010.                                                 DCRPT265
00491      MOVE SPACES TO CAT00010-LINE.                                DCRPT265
00492 *                                                                 DCRPT265
00493 *    FORMAT ALIAS VERSION FIELD                                   DCRPT265
00494 *                                                                 DCRPT265
00495  5105-FMT-FLD05.                                                  DCRPT265
00496      IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.        DCRPT265
00497      IF DATA-ENTRY-TYPE GREATER THAN 15                           DCRPT265
00498          MOVE FLD0001005-HCONV TO FLD0001005-HDG                  DCRPT265
00499       ELSE                                                        DCRPT265
00500          MOVE FLD0001005-HCONA TO FLD0001005-HDG.                 DCRPT265
00501      MOVE CTL-ALY-VER TO FLD0001005-VAL.                          DCRPT265
00502 *                                                                 DCRPT265
00503 *     FORMAT STATUS FIELD                                         DCRPT265
00504 *                                                                 DCRPT265
00505  5110-FMT-FLD010.                                                 DCRPT265
00506      IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015.         DCRPT265
00507      MOVE FLD0001010-HCON TO FLD0001010-HDG.                      DCRPT265
00508          GO TO 5112-INTERPRET-CODE.                                  CL**2
00509  5111-JUST-CODE.                                                     CL**2
00510      MOVE CTL-STATUS TO FLD0001010-POS1.                             CL**2
00511      GO TO 5115-FMT-FLD015.                                          CL**2
00512  5112-INTERPRET-CODE.                                                CL**2
00513      MOVE 01 TO SUB3.                                                CL**2
00514  5113-NEXT-CODE-CK.                                                  CL**2
00515      IF FLD0001010-CODES (SUB3) EQUAL TO "9"                         CL**2
00516          GO TO 5111-JUST-CODE.                                       CL**2
00517      IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS                  CL**2
00518          GO TO 5114-EXTRACT-MNG.                                     CL**2
00519      ADD 1 TO SUB3.                                                  CL**2
00520      GO TO 5113-NEXT-CODE-CK.                                        CL**2
00521  5114-EXTRACT-MNG.                                                   CL**2
00522      MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.                   CL**2
00523 *                                                                 DCRPT265
00524 *     FORMAT SECURITY FIELD                                       DCRPT265
00525 *                                                                 DCRPT265
00526  5115-FMT-FLD015.                                                 DCRPT265
00527      IF CTL-SECURITY EQUAL TO SPACES                              DCRPT265
00528          GO TO 5120-OUTPUT-LINE.                                     CL**2
00529      MOVE FLD0001015-HCON TO FLD0001015-HDG.                      DCRPT265
00530      MOVE CTL-SECURITY    TO FLD0001015-VAL.                      DCRPT265
00531 *                                                                 DCRPT265
00532 *     FORMATTING OF CATEGORY LINE COMPLETE                        DCRPT265
00533  5120-OUTPUT-LINE.                                                DCRPT265
00534      IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.  DCRPT265
00535      MOVE CAT00010-LINE TO STDRPT-70CHR.                          DCRPT265
00536      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00537 *                                                                 DCRPT265
00538  5199-FMT-CAT010-XIT.                                             DCRPT265
00539      EXIT.                                                        DCRPT265
00540                                                                    DCRPT26
00541 ***************************************************************** DCRPT265
00542 *                                                                 DCRPT265
00543 *    FORMAT CATEGORY 020 LINE                                     DCRPT265
00544 *        CATEGORY 020 = KEYWORD                                   DCRPT265
00545 *                                                                 DCRPT265
00546 ***************************************************************** DCRPT265
00547  5200-FMT-CAT020.                                                 DCRPT265
00548      MOVE SPACES TO CAT00020-LINE.                                DCRPT265
00549 *                                                                 DCRPT265
00550 *    FORMAT KEYWORD FIELD                                         DCRPT265
00551 *                                                                 DCRPT265
00552  5205-FMT-FLD05.                                                  DCRPT265
00553      MOVE FLD0002005-HCON TO FLD0002005-HDG.                      DCRPT265
00554      MOVE KEY-WORDS TO FLD0002005-VAL.                            DCRPT265
00555 *                                                                 DCRPT265
00556 *    FORMATTING OF CATEGORY LINE COMPLETE                         DCRPT265
00557 *                                                                 DCRPT265
00558  5210-OUTPUT-LINE.                                                DCRPT265
00559      MOVE CAT00020-LINE TO STDRPT-70CHR.                          DCRPT265
00560      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00561  5299-FMT-CAT020-XIT.                                             DCRPT265
00562      EXIT.                                                        DCRPT265
00563                                                                    DCRPT26
00564 ***************************************************************** DCRPT265
00565 *                                                                 DCRPT265
00566 *    FORMAT CATEGORY 030 LINE                                     DCRPT265
00567 *        CATEGORY 030 = DESCRIPTION                               DCRPT265
00568 *                                                                 DCRPT265
00569 ***************************************************************** DCRPT265
00570  5300-FMT-CAT030.                                                 DCRPT265
00571      MOVE SPACES TO CAT00030-LINE.                                   CL**2
00572      MOVE DESC-FLAG      TO FLD0003005-VAL.                       DCRPT265
00573      MOVE DESC-COMMENT   TO FLD0003010-VAL.                       DCRPT265
00574  5310-OUTPUT-LINE.                                                DCRPT265
00575      MOVE CAT00030-LINE  TO STDRPT-70CHR.                         DCRPT265
00576      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00577  5399-FMT-CAT030-XIT.                                             DCRPT265
00578      EXIT.                                                        DCRPT265
00579                                                                    DCRPT26
00580 ***************************************************************** DCRPT265
00581 *                                                                 DCRPT265
00582 *    FORMAT CATEGORY 900 LINE                                     DCRPT265
00583 *        CATEGORY 900 = OTHER                                     DCRPT265
00584 ***************************************************************** DCRPT265
00585  5900-FMT-CAT900.                                                 DCRPT265
00586      MOVE SPACES TO CAT00900-LINE.                                   CL**2
00587      MOVE DESC-FLAG    TO FLD0090005-VAL.                            CL**2
00588      MOVE DESC-COMMENT TO FLD0090010-VAL.                            CL**2
00589  5910-OUTPUT-LINE.                                                DCRPT265
00590      MOVE CAT00900-LINE TO STDRPT-70CHR.                             CL**2
00591      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT265
00592  5999-FMT-CAT900-XIT.                                             DCRPT265
00593      EXIT.                                                        DCRPT265
00594                                                                    DCRPT26
*CALL     RPTRT65                                                          CL**5
*CALL     DISPLAY2                                                         CL**2
*CALL     WRITELNI                                                         CL**2
00598  USER-ROUTINE.                                                       CL**2
00599      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00600          MOVE SUB-HEAD-811 TO PRINT-DATA                             CL**2
00601          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00602          MOVE SUB-HEAD2-811 TO PRINT-DATA                            CL**2
00603      ELSE                                                            CL**2
00604          MOVE SUB-HEADING-LINE TO PRINT-DATA.                        CL**2
00605      ADD 2 TO LINE-CT.                                               CL**2
00606      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00607      MOVE SPACES TO PRINT-DATA.                                      CL**2
00608      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00609      IF SEC-PAGE-SW EQUAL TO "Y"                                     CL**2
00610          MOVE LIST-LINE-MSG TO CATA-NAME-LINE                        CL**2
00611          MOVE CONTINUATION-LINE TO PRINT-DATA                        CL**2
00612          MOVE 1 TO PRT-CTL                                           CL**2
00613          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00614          MOVE 1 TO PRT-CTL                                           CL**2
00615          MOVE STATEMENT-LINE TO PRINT-DATA                           CL**2
00616          PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                     CL**2
00617      MOVE "Y" TO SEC-PAGE-SW.                                        CL**2
00618  USER-ROUTINE-XIT.                                                   CL**2
00619      EXIT.                                                           CL**2
*CALL     RPT811                                                           CL**2
00624                                                                    DCRPT26
*CALL     MAST1RFL                                                         CL**2
*CALL     MAST1RFC                                                         CL**5
*CALL     MAST1RNL                                                         CL**5
*CALL     MAST1EXT                                                         CL**5
*CALL     MAST1RDR                                                         CL**2
*CALL     MAST1ALG                                                         CL**5
