*DECK     DCRPT260
00001  IDENTIFICATION DIVISION.                                         04/25/78
       PROGRAM-ID. RPT260.
*CALL COPYRIGHT 
      *    THIS MODULE PRINTS A SYSTEM FOR A $REPORT OR $FILE REQUEST 
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR SYSTEMS. THE MODULE ALSO FORMATS INDEX REPORT
      *    DETAIL RECORDS.
      *    ENTRY TYPE 60 = SYSTEM 
00011  ENVIRONMENT DIVISION.                                            DCRPT260
00012  CONFIGURATION SECTION.                                           DCRPT260
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
00015  INPUT-OUTPUT SECTION.                                            DCRPT260
00016  DATA DIVISION.                                                   DCRPT260
*CALL RPTCS 
*CALL     WRKSTG77                                                         CL**5
*CALL     MAST1WS                                                          CL**5
*CALL     TESTWACOM                                                        CL**5
*CALL     DCDWA60                                                          CL**5
00021  01  COMMON-RPTDATA.                                              DCRPT260
00022 *                                                                 DCRPT260
00023 *    THIS REFINES LINE FORMATS  FIELD VALUES, CODES AND WORK AREASDCRPT260
00024 *    WHICH ARE COMMON TO ALL ENTRY TYPES.                         DCRPT260
00025 ******************************************************************DCRPT260
00026 *    STANDARD CATEGORY RPT DETAIL LINES COMMON TO ALL ENTRY TYPES DCRPT260
00027 ******************************************************************DCRPT260
00028      03  00-CAT-DETAIL-LINES.                                     DCRPT260
00029 *    CONTROL CATEGORY                                             DCRPT260
00030          05  CAT00010-LINE.                                       DCRPT260
00031              07  FLD0001005-HDG  PICTURE X(11).                   DCRPT260
00032              07  FLD0001005-VAL  PICTURE X(32).                   DCRPT260
00033              07  FILLER          PICTURE X.                       DCRPT260
00034              07  FLD0001010-HDG  PICTURE X(7).                    DCRPT260
00035              07  FLD0001010-VAL.                                     CL**2
00036                  09  FLD0001010-POS1 PICTURE X.                      CL**2
00037                  09  FILLER          PICTURE X(7).                   CL**2
00038              07  FILLER          PICTURE X.                       DCRPT260
00039              07  FLD0001015-HDG  PICTURE X(9).                    DCRPT260
00040              07  FLD0001015-VAL  PICTURE X.                       DCRPT260
00041 *    KEYWORD CATEGORY                                             DCRPT260
00042          05  CAT00020-LINE REDEFINES CAT00010-LINE.               DCRPT260
00043              07  FLD0002005-HDG  PICTURE X(3).                    DCRPT260
00044              07  FLD0002005-VAL PICTURE X(67).                       CL**2
00045 *    DESCRIPTION CATEGORY                                            CL**2
00046          05  CAT00030-LINE REDEFINES CAT00020-LINE.               DCRPT260
00047              07  FLD0003005-VAL  PICTURE X.                       DCRPT260
00048              07  FLD0003010-VAL  PICTURE X(66).                   DCRPT260
00049              07  FILLER          PICTURE X(3).                    DCRPT260
00050 *    OTHER CATEGORY                                               DCRPT260
00051          05  CAT00900-LINE REDEFINES CAT00030-LINE.                  CL**2
00052              07  FLD0090005-VAL  PICTURE X.                       DCRPT260
00053              07  FLD0090010-VAL  PICTURE X(66).                   DCRPT260
00054              07  FILLER          PICTURE X(3).                    DCRPT260
00055 ******************************************************************DCRPT260
00056 *    STANDARD FIELD HEADING CONSTANTS FOR DETAIL LINES            DCRPT260
00057 *        COMMON TO ALL ENTRY TYPES                                DCRPT260
00058 ******************************************************************DCRPT260
00059      03  00-FIELD-HDG-CONSTANTS.                                  DCRPT260
00060          05  FLD0001005-HCONA    PICTURE X(11)  VALUE             DCRPT260
00061             "  ALIAS OF ".                                        DCRPT260
00062          05  FLD0001010-HCON     PICTURE X(7)   VALUE             DCRPT260
00063             "STATUS=".                                            DCRPT260
00064          05  FLD0001015-HCON     PICTURE X(9)   VALUE             DCRPT260
00065             "SECURITY=".                                          DCRPT260
00066          05  FLD0002005-HCON     PICTURE X(3)   VALUE             DCRPT260
00067             "   ".                                                   CL**2
00068          05  FLD0001005-HCONV    PICTURE X(11)  VALUE             DCRPT260
00069             "VERSION OF ".                                        DCRPT260
00070          05  SUB-HEADING-LINE.                                       CL**2
00071              07  FILLER          PICTURE X(14)   VALUE               CL**2
00072             "CATALOGUE NAME".                                        CL**2
00073              07  FILLER          PICTURE X(8)    VALUE SPACE.        CL**2
00074              07  FILLER          PICTURE X(8)    VALUE               CL**2
00075             "REV LINE".                                              CL**2
00076              07  FILLER          PICTURE X(5)    VALUE SPACE.        CL**2
00077              07  FILLER          PICTURE X(4)    VALUE               CL**2
00078             "TYPE".                                                  CL**2
00079              07  FILLER          PICTURE X(92)   VALUE SPACE.        CL**2
00080          05  CONTINUATION-LINE.                                      CL**2
00081              07  CATA-NAME-LINE  PICTURE X(56)   VALUE SPACE.        CL**2
00082              07  FILLER          PICTURE X(72)   VALUE SPACE.        CL**2
00083              07  STATEMENT-LINE.                                     CL**2
00084                  09  FILLER      PICTURE X(5)    VALUE SPACE.        CL**2
00085                  09  FILLER      PICTURE X(30)   VALUE               CL**2
00086                 "* CONTINUED FROM PREVIOUS PAGE".                    CL**2
00087                  09  FILLER      PICTURE X(97)   VALUE SPACE.        CL**2
00088 *****************************************************************    CL**2
00089 *    FIELD CODES AND THIER MEANINGS                                  CL**2
00090 *       COMMON TO ALL ENTRY TYPES-FOR COMMON CATS                    CL**2
00091 **********************************************************           CL**2
00092      03  00-CAT-CODES.                                               CL**2
00093 *  STATUS OF ENTRY                                                   CL**2
00094          05  FLD0001010-CV       PICTURE X(4)    VALUE               CL**2
00095         "EPO9".                                                      CL**2
00096          05  FLD0001010-CD  REDEFINES  FLD0001010-CV.                CL**2
00097              07  FLD0001010-CODES PICTURE X OCCURS 4.                CL**2
00098          05  FLD0001010-MV       PICTURE X(32)   VALUE               CL**2
00099         "EXISTINGPROPOSEDOBSOLETEXXXXXXXX".                          CL**2
00100          05  FLD0001010-MD   REDEFINES FLD0001010-MV.                CL**2
00101              07  FLD0001010-MNG  PICTURE X(8) OCCURS 4.              CL**2
00102      03  WORK-FIELDS.                                             DCRPT260
00103          05  DATA-OPEN-SW PICTURE X.                                 CL**2
00104          05  HIT-WORK-REC.                                        DCRPT260
00105              07  HIT-WORK-NAME       PICTURE X(32).                  CL**2
00106              07  HIT-WORK-ENTTYPE    PICTURE XX.                     CL**2
00107          05  HIT-TBL-LIMIT       PICTURE   99    VALUE            DCRPT260
00108            25.                                                    DCRPT260
00109          05  HIT-TBL-LIMIT-PLUS1 PICTURE   99    VALUE            DCRPT260
00110              26.                                                  DCRPT260
00111          05  FRLINE-LIMIT        PICTURE 9(4).                    DCRPT260
00112          05  TOLINE-LIMIT        PICTURE 9(4).                    DCRPT260
00113          05  FORLINE-LIMIT       PICTURE 9(4).                    DCRPT260
00114          05  CATLINE-COUNTER     PICTURE 9(4).                    DCRPT260
00115          05  ENTRY-NAME          PICTURE X(32).                   DCRPT260
00116          05  ENTRY-TYPE-NO       PICTURE 99.                      DCRPT260
00117          05  ENTRY-TYPE-NAME     PICTURE X(8).                    DCRPT260
00118          05  CATEGORY-NUMBER     PICTURE XXX.                     DCRPT260
00119          05  CATEGORY-OUTPUT-SW  PICTURE X.                       DCRPT260
00120          05  1ST-HIT-OVER-SW  PICTURE X VALUE "X".                   CL**2
00121          05  HIT-COUNTER   PICTURE 9(5) VALUE 0.                     CL**2
00122          05  HITS-PER-RECORD  PICTURE 99 VALUE 91.                   CL**2
00123          05  CON-KEY          PICTURE S9(8) COMP SYNC.               CL**2
00124          05  SUB1                PICTURE   S99  COMP SYNC.        DCRPT260
00125          05  SUB2                PICTURE   S99  COMP SYNC.        DCRPT260
00126          05  SUB3                PICTURE   S99  COMP SYNC.        DCRPT260
00127          05  SUB4                PICTURE   S99  COMP SYNC.        DCRPT260
00128          05  SUB5                PICTURE   S99  COMP SYNC.        DCRPT260
00129          05  SUB6                PICTURE   S99  COMP SYNC.        DCRPT260
00130          05  DISPLAY-LINE-LENGTH     PICTURE XXX VALUE "132".        CL**2
00131      03  QUERY-MESSAGES.                                          DCRPT260
00132          05  NO-LINES-MSG.                                        DCRPT260
00133              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT260
00134              07  NLM             PICTURE X(55)   VALUE            DCRPT260
00135             "DCRPT-015-I * REQUESTED LINES NOT PRESENT FOR CATEGOR   CL**2
00136 -           "Y.".                                                 DCRPT260
00137          05  NO-CAT-MSG.                                          DCRPT260
00138              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT260
00139              07  NC7             PICTURE X(45)   VALUE            DCRPT260
00140             "DCRPT-020-I * REQUESTED CATEGORY NOT DEFINED.".         CL**2
00141              07  FILLER          PICTURE X(9) VALUE SPACES.       DCRPT260
00142          05  NO-CATS-MSG.                                         DCRPT260
00143              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT260
00144              07  NCPM            PICTURE X(47)   VALUE            DCRPT260
00145             "DCRPT-025-I * REQUESTED CATEGORIES NOT DEFINED.".       CL**2
00146              07  FILLER          PICTURE X(9)    VALUE SPACES.    DCRPT260
00153          05  LIST-LINE-MSG.                                       DCRPT260
00154              07 FILLER           PICTURE XX    VALUE SPACES.      DCRPT260
00155              07  LIST-LINE-NAME  PICTURE X(32).                   DCRPT260
00156              07  FILLER          PICTURE XX    VALUE SPACES.      DCRPT260
00157              07  LIST-LINE-ENTTYPE PICTURE X(8) VALUE                CL**2
00158             "SYSTEM  ".                                              CL**2
00159              07  FILLER          PICTURE X(12) VALUE SPACES.      DCRPT260
*CALL     RPTDEF60                                                         CL**5
*CALL     QTBL2                                                            CL**2
*CALL     RPTWORK                                                          CL**2
00179                                                                    DCRPT26
00180  PROCEDURE DIVISION.                                                 CL**2
*CALL     CATRTS                                                           CL**2
00188 *                                                                 DCRPT260
00189 *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY                   DCRPT260
00190 *                                                                 DCRPT260
00191  3400-INIT-LINELIMS.                                              DCRPT260
00192      IF QTBL-OUT-FRLINE EQUAL TO SPACES                           DCRPT260
00193          MOVE 0001 TO FRLINE-LIMIT                                DCRPT260
00194         ELSE                                                      DCRPT260
00195          MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.                    DCRPT260
00196      IF QTBL-OUT-TOLINE EQUAL TO SPACES                           DCRPT260
00197          MOVE 9999 TO TOLINE-LIMIT                                DCRPT260
00198         ELSE                                                      DCRPT260
00199          MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.                    DCRPT260
00200      IF QTBL-OUT-FORLINES EQUAL TO SPACES                         DCRPT260
00201          MOVE 9999 TO FORLINE-LIMIT                               DCRPT260
00202         ELSE                                                      DCRPT260
00203          MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT.                 DCRPT260
00204 *                                                                 DCRPT260
00205 *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY        DCRPT260
00206 *                                                                 DCRPT260
00207      MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.                           CL**2
00208      MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME.                       DCRPT260
00209      MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.                    DCRPT260
00210      MOVE "N" TO CATEGORY-OUTPUT-SW.                              DCRPT260
00211      IF CATEGORY-NUMBER EQUAL TO "999"                            DCRPT260
00212          GO TO 3450-SHOW-ALL.                                     DCRPT260
00213      IF CATEGORY-NUMBER EQUAL TO "998"                               CL**2
00214          GO TO 3465-SHOW-COMP.                                       CL**2
00215      IF CATEGORY-NUMBER EQUAL TO "996"                            DCRPT260
00216          GO TO 3450-SHOW-ALL.                                     DCRPT260
00217      IF CATEGORY-NUMBER EQUAL TO "997"                            DCRPT260
00218          GO TO 3460-SHOW-CHAR.                                    DCRPT260
00219      IF CATEGORY-NUMBER EQUAL TO "995"                               CL**2
00220          GO TO 3467-SHOW-PERS.                                       CL**2
00221 *                                                                 DCRPT260
00222 *    SHOW ONE CATEGORY HE ASKED FOR                               DCRPT260
00223 *                                                                    CL**2
00224      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00225      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00226 *                                                                 DCRPT260
00227 *    SHOW ALL                                                     DCRPT260
00228 *                                                                 DCRPT260
00229  3450-SHOW-ALL.                                                   DCRPT260
00230      MOVE "010" TO CATEGORY-NUMBER.                               DCRPT260
00231      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00232      MOVE "020" TO CATEGORY-NUMBER.                               DCRPT260
00233      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00234 *                                                                    CL**2
00235  3460-SHOW-CHAR.                                                  DCRPT260
00236 *                                                                    CL**2
00237      MOVE "030" TO CATEGORY-NUMBER.                               DCRPT260
00238      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00239      IF QTBL-OUT-CAT EQUAL TO "996"                               DCRPT260
00240          GO TO 3470-CHECK-SUPER.                                  DCRPT260
00241      MOVE "140" TO CATEGORY-NUMBER.                                  CL**2
00242      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00243      MOVE "200" TO CATEGORY-NUMBER.                                  CL**2
00244      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00245      MOVE "900" TO CATEGORY-NUMBER.                                  CL**2
00246      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT260
00247      IF QTBL-OUT-CAT EQUAL TO "997"                                  CL**2
00248          GO TO 3470-CHECK-SUPER.                                     CL**2
00249  3465-SHOW-COMP.                                                     CL**2
00250      IF QTBL-OUT-CAT EQUAL TO "999"                                  CL**2
00251          GO TO 3466-JUST-COMP.                                       CL**2
00252      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00253      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00254  3466-JUST-COMP.                                                     CL**2
00255      MOVE "800" TO CATEGORY-NUMBER.                                  CL**2
00256      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00257      GO TO 3470-CHECK-SUPER.                                         CL**2
00258  3467-SHOW-PERS.                                                     CL**2
00259      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00260      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00261      MOVE "140" TO CATEGORY-NUMBER.                                  CL**2
00262      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00263 *                                                                 DCRPT260
00264 *    CHECK TO SEE IF ANY OUTPUT FOR SYSTEMS                          CL**2
00265 *                                                                 DCRPT260
00266  3470-CHECK-SUPER.                                                DCRPT260
00267      IF CATEGORY-OUTPUT-SW EQUAL TO "Y"                           DCRPT260
00268          GO TO 1100-NEXT-OUTPUT.                                     CL**2
00269  3475-NO-CATS.                                                    DCRPT260
00270      MOVE NO-CATS-MSG TO STD-RPT-MESSAGE.                         DCRPT260
00271      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00272          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00273      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00274      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00275                                                                    DCRPT26
00276 ******************************************************************DCRPT260
00277 *                                                                 DCRPT260
00278 *    DISPLAY CATEGORY                                             DCRPT260
00279 *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS       DCRPT260
00280 *        EITHER A 70, 80 OR 132 CHARACTER LINE                    DCRPT260
00281 *                                                                 DCRPT260
00282 ******************************************************************DCRPT260
00283  3500-DISPLAY-CATEGORY.                                           DCRPT260
00284      MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.                      DCRPT260
00285      MOVE 0001 TO CATLINE-COUNTER.                                DCRPT260
00286      PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.                DCRPT260
00287      IF DATA-RETURN-CODE EQUAL TO "0"                                CL**2
00288          GO TO 3510-CK-1ST-LINE.                                     CL**2
00289 *                                                                    CL**2
00290 *    CHECK FOR SUPER CAT AND BYPASS MSG                              CL**2
00291 *                                                                    CL**2
00292      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00293          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00294      GO TO 3715-NOCAT-LINE.                                          CL**2
00295 *                                                                 DCRPT260
00296 *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE             DCRPT260
00297 *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT        DCRPT260
00298 *                                                                 DCRPT260
00299  3510-CK-1ST-LINE.                                                DCRPT260
00300      IF CAT-LINE LESS THAN FRLINE-LIMIT                           DCRPT260
00301          GO TO 3515-BYPASS-LINE.                                  DCRPT260
00302 *                                                                 DCRPT260
00303 *    RETRIEVE 1ST LINE OF CATEGORY                                DCRPT260
00304 *                                                                 DCRPT260
00305      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT260
00306          GO TO 3517-CK-SUPER-CAT.                                    CL**2
00307      GO TO 3520-OUTPUT-CATHDR.                                    DCRPT260
00308  3515-BYPASS-LINE.                                                DCRPT260
00309      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT260
00310      IF DATA-RETURN-CODE EQUAL TO "0" OR "3"                      DCRPT260
00311          GO TO 3510-CK-1ST-LINE.                                  DCRPT260
00312  3517-CK-SUPER-CAT.                                                  CL**2
00313      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00314          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00315      GO TO 3715-NOCAT-LINE.                                          CL**2
00316 *                                                                 DCRPT260
00317 *    LOOKUP AND OUTPUT CATEGORY HEADER LINE                       DCRPT260
00318 *                                                                 DCRPT260
00319  3520-OUTPUT-CATHDR.                                              DCRPT260
00320      MOVE 1 TO SUB4.                                              DCRPT260
00321  3525-NEXT-CATNUM.                                                DCRPT260
00322      IF ENT60-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER                CL**2
00323          GO TO 3530-DISPLAY-HDG.                                  DCRPT260
00324      ADD 1 TO SUB4.                                               DCRPT260
00325      GO TO 3525-NEXT-CATNUM.                                      DCRPT260
00326  3530-DISPLAY-HDG.                                                DCRPT260
00327      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00328          GO TO 3532-FMT-FILE-DETAIL.                                 CL**2
00329      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00330      MOVE ENT60-CATHDRS (SUB4) TO CATEGORY-HEADER.                   CL**2
00331      MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.                     CL**2
00332      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00333          MOVE "Y" TO CATEGORY-811-SW                                 CL**2
00334          MOVE CATEGORY-HEADER TO CAT-HEADER-811                      CL**2
00335          MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.                 CL**2
00336      MOVE 2 TO PRT-CTL.                                              CL**2
00337      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00338      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00339      MOVE 1 TO PRT-CTL.                                              CL**2
00340      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00341      MOVE "Y" TO CATEGORY-OUTPUT-SW.                              DCRPT260
00342 *****************************************************************    CL**2
00343 *                                                                    CL**2
00344 *     FORMAT$FILE REQUEST DETAIL RECORDS                             CL**2
00345 *          A RECORD IS FORMATTED FOR EACH SELECTED LINE              CL**2
00346 *                                                                    CL**2
00347 ***************************************************************      CL**2
00348  3532-FMT-FILE-DETAIL.                                               CL**2
00349      IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"               CL**2
00350          GO TO 3540-FMT-CAT-DETAIL.                                  CL**2
00351 *                                                                    CL**2
00352 *     USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY     CL**2
00353 *                                                                    CL**2
00354      MOVE 1 TO HDG-SUB.                                              CL**2
00355 *     FIND THE FIRST DASH IN THE HDG                                 CL**2
00356  3534-FIND-DASH.                                                     CL**2
00357      IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"                     CL**2
00358          ADD 1 TO HDG-SUB                                            CL**2
00359          GO TO 3534-FIND-DASH.                                       CL**2
00360  3536-BYPASS-DASH.                                                   CL**2
00361      IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-"                      CL**2
00362          ADD 1 TO HDG-SUB                                            CL**2
00363          GO TO 3536-BYPASS-DASH.                                     CL**2
00364      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.           CL**2
00365      ADD 1 TO HDG-SUB.                                               CL**2
00366      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.           CL**2
00367      ADD 1 TO HDG-SUB.                                               CL**2
00368      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.           CL**2
00369 *                                                                    CL**2
00370 *     FORMAT DETAIL RECORD                                           CL**2
00371 *                                                                    CL**2
00372      MOVE SPACES TO USER-LINE200-REC.                                CL**2
00373      MOVE RTBL-HDR-REQNO TO USER-L200-REQNO.                         CL**2
00374      MOVE EXT-HOLD-CATNAME TO USER-L200-CNAME.                       CL**2
00375      MOVE EXT-HOLD-TYPE TO USER-L200-ENTTYPE.                        CL**2
00376      MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT.                      CL**2
00377      MOVE CAT-LENGTH    TO USER-L200-LENGTH.                         CL**2
00378      MOVE CAT-LINE      TO USER-L200-LINE.                           CL**2
00379      MOVE CAT-REV       TO USER-L200-REV.                            CL**2
00380      MOVE CAT-DETAIL    TO USER-L200-DATA.                           CL**2
00381      MOVE "U" TO CATTBL-FILE-TYPE.                                   CL**2
00382      IF CAT-LENGTH GREATER THAN 67                                   CL**2
00383      MOVE "5" TO USER-L200-RECTYPE                                   CL**2
00384          MOVE "5" TO CATTBL-RECORD-TYPE                              CL**2
00385      ELSE                                                            CL**2
00386      MOVE "4" TO USER-L200-RECTYPE                                   CL**2
00387          MOVE "4" TO CATTBL-RECORD-TYPE.                             CL**2
00388      PERFORM 0900-USERFILE-OUT THRU 0999-USERFILE-OUT-XIT.           CL**2
00389      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00390          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00391 *                                                                 DCRPT260
00392 *    FORMAT CATEGORY DETAIL LINES                                 DCRPT260
00393 *        IF 70 CHR FORMAT PUT OUT LINE NO ON SEP LINE             DCRPT260
00394 *                                                                 DCRPT260
00395  3540-FMT-CAT-DETAIL.                                             DCRPT260
00396      IF RTBL-OPT-FORMAT EQUAL "S"                                    CL**2
00397          GO TO 3550-FMT-LINE-PREFIX.                                 CL**2
00398      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00399          GO TO 3550-FMT-LINE-PREFIX.                              DCRPT260
00400      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00401      GO TO 3560-FORMAT-REPORT.                                       CL**2
00402  3550-FMT-LINE-PREFIX.                                            DCRPT260
00403      IF CATEGORY-NUMBER NOT EQUAL TO "800"                           CL**2
00404          GO TO 3555-MOVE-LINE.                                       CL**2
00405      IF FIRST-REC-SW EQUAL TO "Y"                                    CL**2
00406          GO TO 3560-FORMAT-REPORT.                                   CL**2
00407  3555-MOVE-LINE.                                                     CL**2
00408      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00409          MOVE 98765 TO STDRPT-REVNO                                  CL**2
00410          MOVE CAT-LINE TO STDRPT-LINE                                CL**2
00411          GO TO 3560-FORMAT-REPORT                                    CL**2
00412      ELSE                                                            CL**2
00413          MOVE CAT-REV TO STDRPT-REVNO                                CL**2
00414      MOVE CAT-LINE TO STDRPT-LINE.                                   CL**2
00415 *                                                                 DCRPT260
00416 *    CHECK FOR COMMENT LINE                                       DCRPT260
00417  3560-FORMAT-REPORT.                                                 CL**2
00418      IF CAT-COMMENT NOT EQUAL TO "*"                                 CL**2
00419          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00420      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00421          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00422      PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT.               CL**2
00423      GO TO 3700-GET-NEXT-LINE.                                       CL**2
00424 *                                                                 DCRPT260
00425 *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT           DCRPT260
00426 *                                                                 DCRPT260
00427  3565-CATEGORY-CHECK.                                                CL**2
00428      IF CATEGORY-NUMBER EQUAL TO "010"                            DCRPT260
00429          PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT         DCRPT260
00430          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00431      IF CATEGORY-NUMBER EQUAL TO "020"                            DCRPT260
00432          PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT         DCRPT260
00433          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00434      IF CATEGORY-NUMBER EQUAL TO "030"                            DCRPT260
00435          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT         DCRPT260
00436          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00437      IF CATEGORY-NUMBER EQUAL TO "140"                               CL**2
00438          PERFORM 26000-FMT-CAT-140 THRU 26099-FMT-CAT140-XIT         CL**2
00439          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00440      IF CATEGORY-NUMBER EQUAL TO "200"                               CL**2
00441          PERFORM 26200-FMT-CAT-200 THRU 26299-FMT-CAT200-XIT         CL**2
00442          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00443      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00444          PERFORM 26800-FMT-CAT-800 THRU 26899-FMT-CAT60800-XIT       CL**2
00445          GO TO 3700-GET-NEXT-LINE.                                DCRPT260
00446      IF CATEGORY-NUMBER EQUAL TO "900"                            DCRPT260
00447          PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT         DCRPT260
00448          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00449      GO TO 3710-NOCAT-DATA.                                          CL**2
00450 *                                                                 DCRPT260
00451 *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END                  DCRPT260
00452 *                                                                 DCRPT260
00453  3700-GET-NEXT-LINE.                                              DCRPT260
00454      IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT                    DCRPT260
00455        GO TO 3749-DISPLAY-CAT-XIT.                                DCRPT260
00456      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT260
00457      IF DATA-RETURN-CODE EQUAL TO  1 OR 2                         DCRPT260
00458          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT260
00459      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT260
00460          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT260
00461      ADD 1 TO CATLINE-COUNTER.                                       CL**2
00462      GO TO 3532-FMT-FILE-DETAIL.                                     CL**2
00463  3749-DISPLAY-CAT-XIT.                                            DCRPT260
00464      EXIT.                                                        DCRPT260
00465                                                                    DCRPT26
00466 *                                                                 DCRPT260
00467 *   FORMAT WARNING AND INFORMATION MESSAGES                       DCRPT260
00468 *                                                                 DCRPT260
00469  3710-NOCAT-DATA.                                                 DCRPT260
00470      MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE.                 DCRPT260
00471      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00472          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00473      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00474      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00475  3715-NOCAT-LINE.                                                 DCRPT260
00476      MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE.                 DCRPT260
00477      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00478          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00479      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00480      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00481                                                                    DCRPT26
00482  3800-NOMORE-HITS.                                                DCRPT260
00483 *                                                                 DCRPT260
00484 *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE                DCRPT260
00485 *                                                                 DCRPT260
00486      GO TO 1500-REPORT-END.                                          CL**2
00487                                                                    DCRPT26
00488 ***************************************************************** DCRPT260
00489 *                                                                 DCRPT260
00490 *    FORMAT CATEGORY 010 DETAIL LINE                              DCRPT260
00491 *        CATEGORY 010 = CONTROL                                   DCRPT260
00492 *                                                                 DCRPT260
00493 ***************************************************************** DCRPT260
00494  5100-FMT-CAT010.                                                 DCRPT260
00495      MOVE SPACES TO CAT00010-LINE.                                DCRPT260
00496 *                                                                 DCRPT260
00497 *    FORMAT ALIAS VERSION FIELD                                   DCRPT260
00498 *                                                                 DCRPT260
00499  5105-FMT-FLD05.                                                  DCRPT260
00500      IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.        DCRPT260
00501      IF DATA-ENTRY-TYPE GREATER THAN 15                           DCRPT260
00502          MOVE FLD0001005-HCONV TO FLD0001005-HDG                  DCRPT260
00503       ELSE                                                        DCRPT260
00504          MOVE FLD0001005-HCONA TO FLD0001005-HDG.                 DCRPT260
00505      MOVE CTL-ALY-VER TO FLD0001005-VAL.                          DCRPT260
00506 *                                                                 DCRPT260
00507 *     FORMAT STATUS FIELD                                         DCRPT260
00508 *                                                                 DCRPT260
00509  5110-FMT-FLD010.                                                 DCRPT260
00510      IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015.         DCRPT260
00511      MOVE FLD0001010-HCON TO FLD0001010-HDG.                         CL**2
00512          GO TO 5112-INTERPRET-CODE.                                  CL**2
00513  5111-JUST-CODE.                                                     CL**2
00514      MOVE CTL-STATUS TO FLD0001010-POS1.                             CL**2
00515      GO TO 5115-FMT-FLD015.                                          CL**2
00516  5112-INTERPRET-CODE.                                                CL**2
00517      MOVE 01 TO SUB3.                                                CL**2
00518  5113-NEXT-CODE-CK.                                                  CL**2
00519      IF FLD0001010-CODES (SUB3) EQUAL TO "9"                         CL**2
00520          GO TO 5111-JUST-CODE.                                       CL**2
00521      IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS                  CL**2
00522          GO TO 5114-EXTRACT-MNG.                                     CL**2
00523      ADD 1 TO SUB3.                                                  CL**2
00524      GO TO 5113-NEXT-CODE-CK.                                        CL**2
00525  5114-EXTRACT-MNG.                                                   CL**2
00526      MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.                   CL**2
00527 *                                                                 DCRPT260
00528 *     FORMAT SECURITY FIELD                                       DCRPT260
00529 *                                                                 DCRPT260
00530  5115-FMT-FLD015.                                                 DCRPT260
00531      IF CTL-SECURITY EQUAL TO SPACES                              DCRPT260
00532          GO TO 5120-OUTPUT-LINE.                                     CL**2
00533      MOVE FLD0001015-HCON TO FLD0001015-HDG.                      DCRPT260
00534      MOVE CTL-SECURITY    TO FLD0001015-VAL.                      DCRPT260
00535 *                                                                 DCRPT260
00536 *     FORMATTING OF CATEGORY LINE COMPLETE                        DCRPT260
00537  5120-OUTPUT-LINE.                                                DCRPT260
00538      IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.  DCRPT260
00539      MOVE CAT00010-LINE TO STDRPT-70CHR.                          DCRPT260
00540      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00541 *                                                                 DCRPT260
00542  5199-FMT-CAT010-XIT.                                             DCRPT260
00543      EXIT.                                                        DCRPT260
00544                                                                    DCRPT26
00545 ***************************************************************** DCRPT260
00546 *                                                                 DCRPT260
00547 *    FORMAT CATEGORY 020 LINE                                     DCRPT260
00548 *        CATEGORY 020 = KEYWORD                                   DCRPT260
00549 *                                                                 DCRPT260
00550 ***************************************************************** DCRPT260
00551  5200-FMT-CAT020.                                                 DCRPT260
00552      MOVE SPACES TO CAT00020-LINE.                                DCRPT260
00553 *                                                                 DCRPT260
00554 *    FORMAT KEYWORD FIELD                                         DCRPT260
00555 *                                                                 DCRPT260
00556  5205-FMT-FLD05.                                                  DCRPT260
00557      MOVE FLD0002005-HCON TO FLD0002005-HDG.                      DCRPT260
00558      MOVE KEY-WORDS TO FLD0002005-VAL.                            DCRPT260
00559 *                                                                 DCRPT260
00560 *    FORMATTING OF CATEGORY LINE COMPLETE                         DCRPT260
00561 *                                                                 DCRPT260
00562  5210-OUTPUT-LINE.                                                DCRPT260
00563      MOVE CAT00020-LINE TO STDRPT-70CHR.                          DCRPT260
00564      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00565  5299-FMT-CAT020-XIT.                                             DCRPT260
00566      EXIT.                                                        DCRPT260
00567                                                                    DCRPT26
00568 ***************************************************************** DCRPT260
00569 *                                                                 DCRPT260
00570 *    FORMAT CATEGORY 030 LINE                                     DCRPT260
00571 *        CATEGORY 030 = DESCRIPTION                               DCRPT260
00572 *                                                                 DCRPT260
00573 ***************************************************************** DCRPT260
00574  5300-FMT-CAT030.                                                 DCRPT260
00575      MOVE SPACES TO CAT00030-LINE.                                   CL**2
00576      MOVE DESC-FLAG      TO FLD0003005-VAL.                       DCRPT260
00577      MOVE DESC-COMMENT   TO FLD0003010-VAL.                       DCRPT260
00578  5310-OUTPUT-LINE.                                                DCRPT260
00579      MOVE CAT00030-LINE  TO STDRPT-70CHR.                         DCRPT260
00580      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00581  5399-FMT-CAT030-XIT.                                             DCRPT260
00582      EXIT.                                                        DCRPT260
00583                                                                    DCRPT26
00584 ***************************************************************** DCRPT260
00585 *                                                                 DCRPT260
00586 *    FORMAT CATEGORY 900 LINE                                     DCRPT260
00587 *        CATEGORY 900 = OTHER                                     DCRPT260
00588 ***************************************************************** DCRPT260
00589  5900-FMT-CAT900.                                                 DCRPT260
00590      MOVE SPACES TO CAT00900-LINE.                                   CL**2
00591      MOVE DESC-FLAG    TO FLD0090005-VAL.                            CL**2
00592      MOVE DESC-COMMENT TO FLD0090010-VAL.                            CL**2
00593  5910-OUTPUT-LINE.                                                DCRPT260
00594      MOVE CAT00900-LINE TO STDRPT-70CHR.                             CL**2
00595      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT260
00596  5999-FMT-CAT900-XIT.                                             DCRPT260
00597      EXIT.                                                        DCRPT260
00598                                                                    DCRPT26
*CALL     RPTRT60                                                          CL**5
*CALL     DISPLAY2                                                         CL**2
*CALL     WRITELNI                                                         CL**2
00602  USER-ROUTINE.                                                       CL**2
00603      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00604          MOVE SUB-HEAD-811 TO PRINT-DATA                             CL**2
00605          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00606          MOVE SUB-HEAD2-811 TO PRINT-DATA                            CL**2
00607      ELSE                                                            CL**2
00608          MOVE SUB-HEADING-LINE TO PRINT-DATA.                        CL**2
00609      ADD 2 TO LINE-CT.                                               CL**2
00610      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00611      MOVE SPACES TO PRINT-DATA.                                      CL**2
00612      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00613      IF SEC-PAGE-SW EQUAL TO "Y"                                     CL**2
00614          MOVE LIST-LINE-MSG TO CATA-NAME-LINE                        CL**2
00615          MOVE CONTINUATION-LINE TO PRINT-DATA                        CL**2
00616          MOVE 1 TO PRT-CTL                                           CL**2
00617          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00618          MOVE 1 TO PRT-CTL                                           CL**2
00619          MOVE STATEMENT-LINE TO PRINT-DATA                           CL**2
00620          PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                     CL**2
00621      MOVE "Y" TO SEC-PAGE-SW.                                        CL**2
00622  USER-ROUTINE-XIT.                                                   CL**2
00623      EXIT.                                                           CL**2
*CALL     RPT811                                                           CL**2
00628                                                                    DCRPT26
*CALL     MAST1RFL                                                         CL**2
*CALL     MAST1RFC                                                         CL**5
*CALL     MAST1RNL                                                         CL**5
*CALL     MAST1EXT                                                         CL**5
*CALL     MAST1RDR                                                         CL**2
*CALL     MAST1ALG                                                         CL**5
