*DECK     DCRPT235
00001  IDENTIFICATION DIVISION.                                         04/25/78
       PROGRAM-ID. RPT235.
*CALL COPYRIGHT 
      *    THIS MODULE PRINTS A FORM FOR A $REPORT OR $FILE REQUEST 
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR FORMS. THE MODULE ALSO FORMATS INDEX REPORT
      *    DETAIL RECORDS.
      *    ENTRY TYPE35 = FORM
00011  ENVIRONMENT DIVISION.                                            DCRPT235
00012  CONFIGURATION SECTION.                                           DCRPT235
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
00015  INPUT-OUTPUT SECTION.                                            DCRPT235
00016  DATA DIVISION.                                                   DCRPT235
*CALL RPTCS 
*CALL     WRKSTG77                                                         CL**5
*CALL     MAST1WS                                                          CL**5
*CALL     TESTWACOM                                                        CL**5
*CALL     DCDWA35                                                          CL**5
00021  01  COMMON-RPTDATA.                                              DCRPT235
00022 *                                                                 DCRPT235
00023 *    THIS REFINES LINE FORMATS  FIELD VALUES, CODES AND WORK AREASDCRPT235
00024 *    WHICH ARE COMMON TO ALL ENTRY TYPES.                         DCRPT235
00025 ******************************************************************DCRPT235
00026 *    STANDARD CATEGORY RPT DETAIL LINES COMMON TO ALL ENTRY TYPES DCRPT235
00027 ******************************************************************DCRPT235
00028      03  00-CAT-DETAIL-LINES.                                     DCRPT235
00029 *    CONTROL CATEGORY                                             DCRPT235
00030          05  CAT00010-LINE.                                       DCRPT235
00031              07  FLD0001005-HDG  PICTURE X(11).                   DCRPT235
00032              07  FLD0001005-VAL  PICTURE X(32).                   DCRPT235
00033              07  FILLER          PICTURE X.                       DCRPT235
00034              07  FLD0001010-HDG  PICTURE X(7).                    DCRPT235
00035              07  FLD0001010-VAL.                                     CL**2
00036                  09  FLD0001010-POS1 PICTURE X.                      CL**2
00037                  09  FILLER          PICTURE X(7).                   CL**2
00038              07  FILLER          PICTURE X.                       DCRPT235
00039              07  FLD0001015-HDG  PICTURE X(9).                    DCRPT235
00040              07  FLD0001015-VAL  PICTURE X.                       DCRPT235
00041 *    KEYWORD CATEGORY                                             DCRPT235
00042          05  CAT00020-LINE REDEFINES CAT00010-LINE.               DCRPT235
00043              07  FLD0002005-HDG  PICTURE X(3).                    DCRPT235
00044              07  FLD0002005-VAL PICTURE X(67).                       CL**2
00045 *"   DESCRIPTION CATEGORY                                         DCRPT235
00046          05  CAT00030-LINE REDEFINES CAT00020-LINE.               DCRPT235
00047              07  FLD0003005-VAL  PICTURE X.                       DCRPT235
00048              07  FLD0003010-VAL  PICTURE X(66).                   DCRPT235
00049              07  FILLER          PICTURE X(3).                    DCRPT235
00050 *    OTHER CATEGORY                                               DCRPT235
00051          05  CAT00900-LINE REDEFINES CAT00020-LINE.               DCRPT235
00052              07  FLD0090005-VAL  PICTURE X.                       DCRPT235
00053              07  FLD0090010-VAL  PICTURE X(66).                   DCRPT235
00054              07  FILLER          PICTURE X(3).                    DCRPT235
00055 ******************************************************************DCRPT235
00056 *    STANDARD FIELD HEADING CONSTANTS FOR DETAIL LINES            DCRPT235
00057 *        COMMON TO ALL ENTRY TYPES                                DCRPT235
00058 ******************************************************************DCRPT235
00059      03  00-FIELD-HDG-CONSTANTS.                                  DCRPT235
00060          05  FLD0001005-HCONA    PICTURE X(11)  VALUE             DCRPT235
00061             "  ALIAS OF ".                                        DCRPT235
00062          05  FLD0001010-HCON     PICTURE X(7)   VALUE             DCRPT235
00063             "STATUS=".                                            DCRPT235
00064          05  FLD0001015-HCON     PICTURE X(9)   VALUE             DCRPT235
00065             "SECURITY=".                                          DCRPT235
00066          05  FLD0002005-HCON     PICTURE X(3)   VALUE             DCRPT235
00067             "   ".                                                   CL**2
00068          05  FLD0001005-HCONV    PICTURE X(11)  VALUE             DCRPT235
00069             "VERSION OF ".                                        DCRPT235
00070          05  SUB-HEADING-LINE.                                       CL**2
00071              07  FILLER          PICTURE X(14)   VALUE               CL**2
00072             "CATALOGUE NAME".                                        CL**2
00073              07  FILLER          PICTURE X(8)    VALUE SPACE.        CL**2
00074              07  FILLER          PICTURE X(9)    VALUE               CL**2
00075             "REV  LINE".                                             CL**2
00076              07  FILLER          PICTURE X(5)    VALUE SPACE.        CL**2
00077              07  FILLER          PICTURE X(4)    VALUE               CL**2
00078             "TYPE".                                                  CL**2
00079              07  FILLER          PICTURE X(92)   VALUE SPACE.        CL**2
00080          05  CONTINUATION-LINE.                                      CL**2
00081              07  CATA-NAME-LINE  PICTURE X(56)   VALUE SPACE.        CL**2
00082              07  FILLER          PICTURE X(72)   VALUE SPACE.        CL**2
00083              07  STATEMENT-LINE.                                     CL**2
00084                  09  FILLER      PICTURE X(5)    VALUE SPACE.        CL**2
00085                  09  FILLER      PICTURE X(30)   VALUE               CL**2
00086                 "* CONTINUED FROM PREVIOUS PAGE".                    CL**2
00087                  09  FILLER      PICTURE X(97)   VALUE SPACE.        CL**2
00088 *********************************************************            CL**2
00089 *     FIELD CODES AND THEIR MEANINGS                                 CL**2
00090 *       COMMON TO ALL ENTRY TYPES-FOR COMMON CATS                    CL**2
00091 **********************************************************           CL**2
00092      03  00-CAT-CODES.                                               CL**2
00093 *  STATUS OF ENTRY                                                   CL**2
00094          05  FLD0001010-CV       PICTURE X(4)    VALUE               CL**2
00095         "EPO9".                                                      CL**2
00096          05  FLD0001010-CD  REDEFINES  FLD0001010-CV.                CL**2
00097              07  FLD0001010-CODES PICTURE X OCCURS 4.                CL**2
00098          05  FLD0001010-MV       PICTURE X(32)   VALUE               CL**2
00099         "EXISTINGPROPOSEDOBSOLETEXXXXXXXX".                          CL**2
00100          05  FLD0001010-MD   REDEFINES FLD0001010-MV.                CL**2
00101              07  FLD0001010-MNG  PICTURE X(8) OCCURS 4.              CL**2
00102      03  WORK-FIELDS.                                             DCRPT235
00103          05  DATA-OPEN-SW PICTURE X.                                 CL**2
00104          05  HIT-WORK-REC.                                        DCRPT235
00105          07  HIT-WORK-NAME       PICTURE X(32).                   DCRPT235
00106          07  HIT-WORK-ENTTYPE    PICTURE XX.                      DCRPT235
00107          05  HIT-TBL-LIMIT       PICTURE   99    VALUE            DCRPT235
00108            25.                                                    DCRPT235
00109          05  HIT-TBL-LIMIT-PLUS1 PICTURE   99    VALUE            DCRPT235
00110              26.                                                  DCRPT235
00111          05  FRLINE-LIMIT        PICTURE 9(4).                    DCRPT235
00112          05  TOLINE-LIMIT        PICTURE 9(4).                    DCRPT235
00113          05  FORLINE-LIMIT       PICTURE 9(4).                    DCRPT235
00114          05  CATLINE-COUNTER     PICTURE 9(4).                    DCRPT235
00115          05  ENTRY-NAME          PICTURE X(32).                   DCRPT235
00116          05  ENTRY-TYPE-NO       PICTURE 99.                      DCRPT235
00117          05  ENTRY-TYPE-NAME     PICTURE X(8).                    DCRPT235
00118          05  CATEGORY-NUMBER     PICTURE XXX.                     DCRPT235
00119          05  CATEGORY-OUTPUT-SW  PICTURE X.                       DCRPT235
00120          05  1ST-HIT-OVER-SW  PICTURE X VALUE "X".                   CL**2
00121          05  HIT-COUNTER   PICTURE 9(5) VALUE 0.                     CL**2
00122          05  HITS-PER-RECORD  PICTURE 99 VALUE 91.                   CL**2
00123          05  CON-KEY          PICTURE S9(8) COMP SYNC.               CL**2
00124          05  SUB1                PICTURE   S99  COMP SYNC.        DCRPT235
00125          05  SUB2                PICTURE   S99  COMP SYNC.        DCRPT235
00126          05  SUB3                PICTURE   S99  COMP SYNC.        DCRPT235
00127          05  SUB4                PICTURE   S99  COMP SYNC.        DCRPT235
00128          05  SUB5                PICTURE   S99  COMP SYNC.        DCRPT235
00129          05  SUB6                PICTURE   S99  COMP SYNC.        DCRPT235
00130           05  DISPLAY-LINE-LENGTH PICTURE XXX VALUE "132".           CL**2
00131      03  QUERY-MESSAGES.                                          DCRPT235
00132          05  NO-LINES-MSG.                                        DCRPT235
00133              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT235
00134              07  NLM             PICTURE X(55)   VALUE            DCRPT235
00135             "DCRPT-015-I * REQUESTED LINES NOT PRESENT FOR CATEGOR   CL**2
00136 -           "Y.".                                                 DCRPT235
00137          05  NO-CAT-MSG.                                          DCRPT235
00138              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT235
00139              07  NC7             PICTURE X(45)   VALUE            DCRPT235
00140             "DCRPT-020-I * REQUESTED CATEGORY NOT DEFINED.".         CL**2
00141              07  FILLER          PICTURE X(9) VALUE SPACES.       DCRPT235
00142          05  NO-CATS-MSG.                                         DCRPT235
00143              07  FILLER          PICTURE XX VALUE SPACES.         DCRPT235
00144              07  NCPM            PICTURE X(47)   VALUE            DCRPT235
00145             "DCRPT-025-I * REQUESTED CATEGORIES NOT DEFINED.".       CL**2
00146              07  FILLER          PICTURE X(9)    VALUE SPACES.    DCRPT235
00153          05  LIST-LINE-MSG.                                       DCRPT235
00154              07 FILLER           PICTURE XX    VALUE SPACES.      DCRPT235
00155              07  LIST-LINE-NAME  PICTURE X(32).                   DCRPT235
00156              07  FILLER          PICTURE XX    VALUE SPACES.      DCRPT235
00157              07  LIST-LINE-ENTTYPE PICTURE X(8) VALUE                CL**2
00158             "FORM    ".                                              CL**2
00159              07  FILLER          PICTURE X(12) VALUE SPACES.      DCRPT235
*CALL     RPTDEF35                                                         CL**5
*CALL     QTBL2                                                            CL**2
*CALL     RPTWORK                                                          CL**2
00179                                                                    DCRPT23
00180  PROCEDURE DIVISION.                                                 CL**2
*CALL     CATRTS                                                           CL**2
00188 *                                                                 DCRPT235
00189 *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY                   DCRPT235
00190 *                                                                 DCRPT235
00191  3400-INIT-LINELIMS.                                              DCRPT235
00192      IF QTBL-OUT-FRLINE EQUAL TO SPACES                           DCRPT235
00193          MOVE 0001 TO FRLINE-LIMIT                                DCRPT235
00194         ELSE                                                      DCRPT235
00195          MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.                    DCRPT235
00196      IF QTBL-OUT-TOLINE EQUAL TO SPACES                           DCRPT235
00197          MOVE 9999 TO TOLINE-LIMIT                                DCRPT235
00198         ELSE                                                      DCRPT235
00199          MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.                    DCRPT235
00200      IF QTBL-OUT-FORLINES EQUAL TO SPACES                         DCRPT235
00201          MOVE 9999 TO FORLINE-LIMIT                               DCRPT235
00202         ELSE                                                      DCRPT235
00203          MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT.                 DCRPT235
00204 *                                                                 DCRPT235
00205 *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY        DCRPT235
00206 *                                                                 DCRPT235
00207      MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.                           CL**2
00208      MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME.                       DCRPT235
00209      MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.                    DCRPT235
00210      MOVE "N" TO CATEGORY-OUTPUT-SW.                              DCRPT235
00211      IF CATEGORY-NUMBER EQUAL TO "999"                            DCRPT235
00212          GO TO 3450-SHOW-ALL.                                     DCRPT235
00213      IF CATEGORY-NUMBER EQUAL TO "998"                               CL**2
00214          GO TO 3465-SHOW-COMP.                                       CL**2
00215      IF CATEGORY-NUMBER EQUAL TO "996"                            DCRPT235
00216          GO TO 3450-SHOW-ALL.                                     DCRPT235
00217      IF CATEGORY-NUMBER EQUAL TO "997"                            DCRPT235
00218          GO TO 3460-SHOW-CHAR.                                    DCRPT235
00219      IF CATEGORY-NUMBER EQUAL TO "995"                               CL**2
00220          GO TO 3467-SHOW-PERS.                                       CL**2
00221 *                                                                 DCRPT235
00222 *    SHOW ONE CATEGORY HE ASKED FOR                               DCRPT235
00223 *                                                                    CL**2
00224      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00225      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00226 *                                                                 DCRPT235
00227 *    SHOW ALL                                                     DCRPT235
00228 *                                                                 DCRPT235
00229  3450-SHOW-ALL.                                                   DCRPT235
00230      MOVE "010" TO CATEGORY-NUMBER.                               DCRPT235
00231      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00232      MOVE "020" TO CATEGORY-NUMBER.                               DCRPT235
00233      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00234 *                                                                    CL**2
00235  3460-SHOW-CHAR.                                                  DCRPT235
00236 *                                                                    CL**2
00237      MOVE "030" TO CATEGORY-NUMBER.                               DCRPT235
00238      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00239      IF QTBL-OUT-CAT EQUAL TO "996"                               DCRPT235
00240          GO TO 3470-CHECK-SUPER.                                  DCRPT235
00241      MOVE "140" TO CATEGORY-NUMBER.                                  CL**2
00242      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00243      MOVE "200" TO CATEGORY-NUMBER.                                  CL**2
00244      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00245      MOVE "210" TO CATEGORY-NUMBER.                                  CL**2
00246      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00247      MOVE "230" TO CATEGORY-NUMBER.                                  CL**2
00248      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00249      MOVE "240" TO CATEGORY-NUMBER.                                  CL**2
00250      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00251      MOVE "900" TO CATEGORY-NUMBER.                                  CL**2
00252      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT235
00253      IF QTBL-OUT-CAT EQUAL TO "997"                                  CL**2
00254          GO TO 3470-CHECK-SUPER.                                     CL**2
00255  3465-SHOW-COMP.                                                     CL**2
00256      IF QTBL-OUT-CAT EQUAL TO "999"                                  CL**2
00257          GO TO 3466-JUST-COMP.                                       CL**2
00258      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00259      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00260  3466-JUST-COMP.                                                     CL**2
00261      MOVE "800" TO CATEGORY-NUMBER.                                  CL**2
00262      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00263      GO TO 3470-CHECK-SUPER.                                         CL**2
00264  3467-SHOW-PERS.                                                     CL**2
00265      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00266      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00267      MOVE "140" TO CATEGORY-NUMBER.                                  CL**2
00268      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00269 *                                                                 DCRPT235
00270 *    CHECK TO SEE IF ANY OUTPUT FOR ENTYR                         DCRPT235
00271 *                                                                 DCRPT235
00272  3470-CHECK-SUPER.                                                DCRPT235
00273      IF CATEGORY-OUTPUT-SW EQUAL TO "Y"                           DCRPT235
00274          GO TO 1100-NEXT-OUTPUT.                                     CL**2
00275  3475-NO-CATS.                                                    DCRPT235
00276      MOVE NO-CATS-MSG TO STD-RPT-MESSAGE.                         DCRPT235
00277        IF RTBL-OPT-FORMAT EQUAL "D"                                  CL**2
00278          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00279      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00280      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00281                                                                    DCRPT23
00282 ******************************************************************DCRPT235
00283 *                                                                 DCRPT235
00284 *    DISPLAY CATEGORY                                             DCRPT235
00285 *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS       DCRPT235
00286 *        EITHER A 70, 80 OR 132 CHARACTER LINE                    DCRPT235
00287 *                                                                 DCRPT235
00288 ******************************************************************DCRPT235
00289  3500-DISPLAY-CATEGORY.                                           DCRPT235
00290      MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.                      DCRPT235
00291      MOVE 0001 TO CATLINE-COUNTER.                                DCRPT235
00292      PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.                DCRPT235
00293      IF DATA-RETURN-CODE EQUAL TO "0"                                CL**2
00294          GO TO 3510-CK-1ST-LINE.                                     CL**2
00295 *                                                                    CL**2
00296 *    CHECK FOR SUPER CAT AND BYPASS MSG                              CL**2
00297 *                                                                    CL**2
00298      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00299          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00300          GO TO 3715-NOCAT-LINE.                                      CL**2
00301 *                                                                 DCRPT235
00302 *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE             DCRPT235
00303 *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT        DCRPT235
00304 *                                                                 DCRPT235
00305  3510-CK-1ST-LINE.                                                DCRPT235
00306      IF CAT-LINE LESS THAN FRLINE-LIMIT                           DCRPT235
00307          GO TO 3515-BYPASS-LINE.                                  DCRPT235
00308 *                                                                 DCRPT235
00309 *    RETRIEVE 1ST LINE OF CATEGORY                                DCRPT235
00310 *                                                                 DCRPT235
00311      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT235
00312          GO TO 3717-CK-SUPER-CAT.                                    CL**2
00313      GO TO 3520-OUTPUT-CATHDR.                                    DCRPT235
00314  3515-BYPASS-LINE.                                                DCRPT235
00315      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT235
00316      IF DATA-RETURN-CODE EQUAL TO "0" OR "3"                      DCRPT235
00317          GO TO 3510-CK-1ST-LINE.                                  DCRPT235
00318  3717-CK-SUPER-CAT.                                                  CL**2
00319      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00320          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00321      GO TO 3715-NOCAT-LINE.                                          CL**2
00322 *                                                                 DCRPT235
00323 *    LOOKUP AND OUTPUT CATEGORY HEADER LINE                       DCRPT235
00324 *                                                                 DCRPT235
00325  3520-OUTPUT-CATHDR.                                              DCRPT235
00326      MOVE 1 TO SUB4.                                              DCRPT235
00327  3525-NEXT-CATNUM.                                                DCRPT235
00328      IF ENT35-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER                CL**2
00329          GO TO 3530-DISPLAY-HDG.                                  DCRPT235
00330      ADD 1 TO SUB4.                                               DCRPT235
00331      GO TO 3525-NEXT-CATNUM.                                      DCRPT235
00332  3530-DISPLAY-HDG.                                                DCRPT235
00333      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00334          GO TO 3532-FMT-FILE-DETAIL.                                 CL**2
00335      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00336      MOVE ENT35-CATHDRS (SUB4) TO CATEGORY-HEADER.                   CL**2
00337      MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.                     CL**2
00338      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00339          MOVE "Y" TO CATEGORY-811-SW                                 CL**2
00340          MOVE CATEGORY-HEADER TO CAT-HEADER-811                      CL**2
00341          MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.                 CL**2
00342      MOVE 2 TO PRT-CTL.                                              CL**2
00343      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00344      MOVE 1 TO PRT-CTL.                                              CL**2
00345      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00346      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00347      MOVE "Y" TO CATEGORY-OUTPUT-SW.                              DCRPT235
00348 *****************************************************************    CL**2
00349 *                                                                    CL**2
00350 *     FORMAT$FILE REQUEST DETAIL RECORDS                             CL**2
00351 *          A RECORD IS FORMATTED FOR EACH SELECTED LINE              CL**2
00352 *                                                                    CL**2
00353 ***************************************************************      CL**2
00354  3532-FMT-FILE-DETAIL.                                               CL**2
00355      IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"               CL**2
00356          GO TO 3540-FMT-CAT-DETAIL.                                  CL**2
00357 *                                                                    CL**2
00358 *     USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY     CL**2
00359 *                                                                    CL**2
00360      MOVE 1 TO HDG-SUB.                                              CL**2
00361 *     FIND THE FIRST DASH IN THE HDG                                 CL**2
00362  3534-FIND-DASH.                                                     CL**2
00363      IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"                     CL**2
00364          ADD 1 TO HDG-SUB                                            CL**2
00365          GO TO 3534-FIND-DASH.                                       CL**2
00366  3536-BYPASS-DASH.                                                   CL**2
00367      IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-"                      CL**2
00368          ADD 1 TO HDG-SUB                                            CL**2
00369          GO TO 3536-BYPASS-DASH.                                     CL**2
00370      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.           CL**2
00371      ADD 1 TO HDG-SUB.                                               CL**2
00372      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.           CL**2
00373      ADD 1 TO HDG-SUB.                                               CL**2
00374      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.           CL**2
00375 *                                                                    CL**2
00376 *     FORMAT DETAIL RECORD                                           CL**2
00377 *                                                                    CL**2
00378      MOVE SPACES TO USER-LINE200-REC.                                CL**2
00379      MOVE RTBL-HDR-REQNO TO USER-L200-REQNO.                         CL**2
00380      MOVE EXT-HOLD-CATNAME TO USER-L200-CNAME.                       CL**2
00381      MOVE EXT-HOLD-TYPE TO USER-L200-ENTTYPE.                        CL**2
00382      MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT.                      CL**2
00383      MOVE CAT-LENGTH    TO USER-L200-LENGTH.                         CL**2
00384      MOVE CAT-LINE      TO USER-L200-LINE.                           CL**2
00385      MOVE CAT-REV       TO USER-L200-REV.                            CL**2
00386      MOVE CAT-DETAIL    TO USER-L200-DATA.                           CL**2
00387      MOVE "U" TO CATTBL-FILE-TYPE.                                   CL**2
00388      IF CAT-LENGTH GREATER THAN 67                                   CL**2
00389      MOVE "5" TO USER-L200-RECTYPE                                   CL**2
00390          MOVE "5" TO CATTBL-RECORD-TYPE                              CL**2
00391      ELSE                                                            CL**2
00392      MOVE "4" TO USER-L200-RECTYPE                                   CL**2
00393          MOVE "4" TO CATTBL-RECORD-TYPE.                             CL**2
00394      PERFORM 0900-USERFILE-OUT THRU 0999-USERFILE-OUT-XIT.           CL**2
00395      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00396          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00397 *                                                                 DCRPT235
00398 *    FORMAT CATEGORY DETAIL LINES                                 DCRPT235
00399 *        IF 70 CHR FORMAT PUT OUT LINE NO ON SEP LINE             DCRPT235
00400 *                                                                 DCRPT235
00401  3540-FMT-CAT-DETAIL.                                             DCRPT235
00402      IF RTBL-OPT-FORMAT EQUAL "S"                                    CL**2
00403          GO TO 3550-FMT-LINE-PREFIX.                              DCRPT235
00404      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00405          GO TO 3550-FMT-LINE-PREFIX.                                 CL**2
00406      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00407      GO TO 3560-FORMAT-REPORT.                                       CL**2
00408  3550-FMT-LINE-PREFIX.                                            DCRPT235
00409      IF CATEGORY-NUMBER NOT EQUAL TO "800"                           CL**2
00410          GO TO 3555-MOVE-LINE.                                       CL**2
00411      IF FIRST-REC-SW EQUAL TO "Y"                                    CL**2
00412          GO TO 3560-FORMAT-REPORT.                                   CL**2
00413  3555-MOVE-LINE.                                                     CL**2
00414      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00415          MOVE 98765 TO STDRPT-REVNO                                  CL**2
00416          MOVE CAT-LINE TO STDRPT-LINE                                CL**2
00417          GO TO 3560-FORMAT-REPORT                                    CL**2
00418      ELSE                                                            CL**2
00419          MOVE CAT-REV TO STDRPT-REVNO                                CL**2
00420      MOVE CAT-LINE TO STDRPT-LINE.                                   CL**2
00421 *                                                                 DCRPT235
00422 *    CHECK FOR COMMENT LINE                                       DCRPT235
00423  3560-FORMAT-REPORT.                                                 CL**2
00424      IF CAT-COMMENT NOT EQUAL TO "*"                                 CL**2
00425          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00426      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00427          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00428      PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT.               CL**2
00429      GO TO 3700-GET-NEXT-LINE.                                       CL**2
00430 *                                                                 DCRPT235
00431 *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT           DCRPT235
00432 *                                                                 DCRPT235
00433  3565-CATEGORY-CHECK.                                                CL**2
00434      IF CATEGORY-NUMBER EQUAL TO "010"                            DCRPT235
00435          PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT         DCRPT235
00436          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00437      IF CATEGORY-NUMBER EQUAL TO "020"                            DCRPT235
00438          PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT         DCRPT235
00439          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00440      IF CATEGORY-NUMBER EQUAL TO "030"                            DCRPT235
00441          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT         DCRPT235
00442          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00443      IF CATEGORY-NUMBER EQUAL TO "140"                               CL**2
00444          PERFORM 20000-FMT-CAT140 THRU 20190-FMT-CAT140-XIT          CL**2
00445          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00446      IF CATEGORY-NUMBER EQUAL TO "200"                               CL**2
00447          PERFORM 20200-FMT-CAT-200 THRU 20230-FMT-CAT200-XIT         CL**2
00448          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00449      IF CATEGORY-NUMBER EQUAL TO "210"                               CL**2
00450          PERFORM 20400-FMT-CAT210 THRU 20430-FMT-CAT210-XIT          CL**2
00451          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00452      IF CATEGORY-NUMBER EQUAL TO "230"                               CL**2
00453          PERFORM 20500-FMT-CAT230 THRU 20685-FMT-CAT230-XIT          CL**2
00454          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00455      IF CATEGORY-NUMBER EQUAL TO "240"                               CL**2
00456          PERFORM 20700-FMT-CAT240 THRU 20770-FMT-CAT240-XIT          CL**2
00457          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00458      IF CATEGORY-NUMBER EQUAL TO "800"                               CL**2
00459          PERFORM 20800-FMT-CAT800 THRU 20870-FMT-CAT800-XIT          CL**2
00460          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00461      IF CATEGORY-NUMBER EQUAL TO "900"                            DCRPT235
00462          PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT         DCRPT235
00463          GO TO 3700-GET-NEXT-LINE.                                DCRPT235
00464      GO TO 3710-NOCAT-DATA.                                          CL**2
00465 *                                                                 DCRPT235
00466 *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END                  DCRPT235
00467 *                                                                 DCRPT235
00468  3700-GET-NEXT-LINE.                                              DCRPT235
00469      IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT                    DCRPT235
00470        GO TO 3749-DISPLAY-CAT-XIT.                                DCRPT235
00471      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT235
00472      IF DATA-RETURN-CODE EQUAL TO  1 OR 2                         DCRPT235
00473          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT235
00474      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT235
00475          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT235
00476      ADD 1 TO CATLINE-COUNTER.                                       CL**2
00477      GO TO 3532-FMT-FILE-DETAIL.                                     CL**2
00478  3749-DISPLAY-CAT-XIT.                                            DCRPT235
00479      EXIT.                                                        DCRPT235
00480                                                                    DCRPT23
00481 *                                                                 DCRPT235
00482 *   FORMAT WARNING AND INFORMATION MESSAGES                       DCRPT235
00483 *                                                                 DCRPT235
00484  3710-NOCAT-DATA.                                                 DCRPT235
00485      MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE.                 DCRPT235
00486      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00487          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00488      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00489      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00490  3715-NOCAT-LINE.                                                 DCRPT235
00491      MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE.                 DCRPT235
00492      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00493          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00494      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00495      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00496                                                                    DCRPT23
00497  3800-NOMORE-HITS.                                                DCRPT235
00498 *                                                                 DCRPT235
00499 *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE                DCRPT235
00500 *                                                                 DCRPT235
00501      GO TO 1500-REPORT-END.                                          CL**2
00502                                                                    DCRPT23
00503 ***************************************************************** DCRPT235
00504 *                                                                 DCRPT235
00505 *    FORMAT CATEGORY 010 DETAIL LINE                              DCRPT235
00506 *        CATEGORY 010 = CONTROL                                   DCRPT235
00507 *                                                                 DCRPT235
00508 ***************************************************************** DCRPT235
00509  5100-FMT-CAT010.                                                 DCRPT235
00510      MOVE SPACES TO CAT00010-LINE.                                DCRPT235
00511 *                                                                 DCRPT235
00512 *    FORMAT ALIAS VERSION FIELD                                   DCRPT235
00513 *                                                                 DCRPT235
00514  5105-FMT-FLD05.                                                  DCRPT235
00515      IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.        DCRPT235
00516      IF DATA-ENTRY-TYPE GREATER THAN 15                           DCRPT235
00517          MOVE FLD0001005-HCONV TO FLD0001005-HDG                  DCRPT235
00518       ELSE                                                        DCRPT235
00519          MOVE FLD0001005-HCONA TO FLD0001005-HDG.                 DCRPT235
00520      MOVE CTL-ALY-VER TO FLD0001005-VAL.                          DCRPT235
00521 *                                                                 DCRPT235
00522 *     FORMAT STATUS FIELD                                         DCRPT235
00523 *                                                                 DCRPT235
00524  5110-FMT-FLD010.                                                 DCRPT235
00525      IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015.         DCRPT235
00526      MOVE FLD0001010-HCON TO FLD0001010-HDG.                      DCRPT235
00527          GO TO 5112-INTERPRET-CODE.                                  CL**2
00528  5111-JUST-CODE.                                                     CL**2
00529      MOVE CTL-STATUS TO FLD0001010-POS1.                             CL**2
00530      GO TO 5115-FMT-FLD015.                                          CL**2
00531  5112-INTERPRET-CODE.                                                CL**2
00532      MOVE 01 TO SUB3.                                                CL**2
00533  5113-NEXT-CODE-CK.                                                  CL**2
00534      IF FLD0001010-CODES (SUB3) EQUAL TO "9"                         CL**2
00535          GO TO 5111-JUST-CODE.                                       CL**2
00536      IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS                  CL**2
00537          GO TO 5114-EXTRACT-MNG.                                     CL**2
00538      ADD 1 TO SUB3.                                                  CL**2
00539      GO TO 5113-NEXT-CODE-CK.                                        CL**2
00540  5114-EXTRACT-MNG.                                                   CL**2
00541      MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.                   CL**2
00542 *                                                                 DCRPT235
00543 *     FORMAT SECURITY FIELD                                       DCRPT235
00544 *                                                                 DCRPT235
00545  5115-FMT-FLD015.                                                 DCRPT235
00546      IF CTL-SECURITY EQUAL TO SPACES                              DCRPT235
00547          GO TO 5120-OUTPUT-LINE.                                     CL**2
00548      MOVE FLD0001015-HCON TO FLD0001015-HDG.                      DCRPT235
00549      MOVE CTL-SECURITY    TO FLD0001015-VAL.                      DCRPT235
00550 *                                                                 DCRPT235
00551 *     FORMATTING OF CATEGORY LINE COMPLETE                        DCRPT235
00552  5120-OUTPUT-LINE.                                                DCRPT235
00553      IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.  DCRPT235
00554      MOVE CAT00010-LINE TO STDRPT-70CHR.                          DCRPT235
00555      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00556 *                                                                 DCRPT235
00557  5199-FMT-CAT010-XIT.                                             DCRPT235
00558      EXIT.                                                        DCRPT235
00559                                                                    DCRPT23
00560 ***************************************************************** DCRPT235
00561 *                                                                 DCRPT235
00562 *    FORMAT CATEGORY 020 LINE                                     DCRPT235
00563 *        CATEGORY 020 = KEYWORD                                   DCRPT235
00564 *                                                                 DCRPT235
00565 ***************************************************************** DCRPT235
00566  5200-FMT-CAT020.                                                 DCRPT235
00567      MOVE SPACES TO CAT00020-LINE.                                DCRPT235
00568 *                                                                 DCRPT235
00569 *    FORMAT KEYWORD FIELD                                         DCRPT235
00570 *                                                                 DCRPT235
00571  5205-FMT-FLD05.                                                  DCRPT235
00572      MOVE FLD0002005-HCON TO FLD0002005-HDG.                      DCRPT235
00573      MOVE KEY-WORDS TO FLD0002005-VAL.                            DCRPT235
00574 *                                                                 DCRPT235
00575 *    FORMATTING OF CATEGORY LINE COMPLETE                         DCRPT235
00576 *                                                                 DCRPT235
00577  5210-OUTPUT-LINE.                                                DCRPT235
00578      MOVE CAT00020-LINE TO STDRPT-70CHR.                          DCRPT235
00579      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00580  5299-FMT-CAT020-XIT.                                             DCRPT235
00581      EXIT.                                                        DCRPT235
00582                                                                    DCRPT23
00583 ***************************************************************** DCRPT235
00584 *                                                                 DCRPT235
00585 *    FORMAT CATEGORY 030 LINE                                     DCRPT235
00586 *        CATEGORY 030 = DESCRIPTION                               DCRPT235
00587 *                                                                 DCRPT235
00588 ***************************************************************** DCRPT235
00589  5300-FMT-CAT030.                                                 DCRPT235
00590      MOVE SPACES TO CAT00030-LINE.                                   CL**2
00591      MOVE DESC-FLAG      TO FLD0003005-VAL.                       DCRPT235
00592      MOVE DESC-COMMENT   TO FLD0003010-VAL.                       DCRPT235
00593  5310-OUTPUT-LINE.                                                DCRPT235
00594      MOVE CAT00030-LINE  TO STDRPT-70CHR.                         DCRPT235
00595      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00596  5399-FMT-CAT030-XIT.                                             DCRPT235
00597      EXIT.                                                        DCRPT235
00598                                                                    DCRPT23
00599 ***************************************************************** DCRPT235
00600 *                                                                 DCRPT235
00601 *    FORMAT CATEGORY 900 LINE                                     DCRPT235
00602 *        CATEGORY 900 = OTHER                                     DCRPT235
00603 ***************************************************************** DCRPT235
00604  5900-FMT-CAT900.                                                 DCRPT235
00605      MOVE SPACES TO CAT00900-LINE.                                   CL**2
00606      MOVE DESC-FLAG    TO FLD0090005-VAL.                            CL**2
00607      MOVE DESC-COMMENT TO FLD0090010-VAL.                            CL**2
00608  5910-OUTPUT-LINE.                                                DCRPT235
00609      MOVE CAT00900-LINE TO STDRPT-70CHR.                             CL**2
00610      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT235
00611  5999-FMT-CAT900-XIT.                                             DCRPT235
00612      EXIT.                                                        DCRPT235
00613                                                                    DCRPT23
*CALL     RPTRT35                                                          CL**5
*CALL     DISPLAY2                                                         CL**2
*CALL     WRITELNI                                                         CL**2
00617  USER-ROUTINE.                                                       CL**2
00618      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00619          MOVE SUB-HEAD-811 TO PRINT-DATA                             CL**2
00620          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00621          MOVE SUB-HEAD2-811 TO PRINT-DATA                            CL**2
00622      ELSE                                                            CL**2
00623          MOVE SUB-HEADING-LINE TO PRINT-DATA.                        CL**2
00624      ADD 2 TO LINE-CT.                                               CL**2
00625      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00626      MOVE SPACE TO PRINT-DATA.                                       CL**2
00627      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00628      IF SEC-PAGE-SW EQUAL TO "Y"                                     CL**2
00629          MOVE LIST-LINE-MSG TO CATA-NAME-LINE                        CL**2
00630          MOVE CONTINUATION-LINE TO PRINT-DATA                        CL**2
00631          MOVE 1 TO PRT-CTL                                           CL**2
00632          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00633          MOVE 1 TO PRT-CTL                                           CL**2
00634          MOVE STATEMENT-LINE TO PRINT-DATA                           CL**2
00635          PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                     CL**2
00636      MOVE "Y" TO SEC-PAGE-SW.                                        CL**2
00637  USER-ROUTINE-XIT.                                                   CL**2
00638      EXIT.                                                           CL**2
*CALL     RPT811                                                           CL**2
00643                                                                    DCRPT23
*CALL     MAST1RFL                                                         CL**2
*CALL     MAST1RFC                                                         CL**5
*CALL     MAST1RNL                                                         CL**5
*CALL     MAST1EXT                                                         CL**5
*CALL     MAST1RDR                                                         CL**2
*CALL     MAST1ALG                                                         CL**5
