*DECK     DCRPT226
       IDENTIFICATION DIVISION. 
       PROGRAM-ID. RPT226.
*CALL COPYRIGHT 
      *    THIS MODULE PRINTS A SCHEMA FOR A $REPORT OR $FILE REQUEST.
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR ELEMENTS. THE MODULE ALSO FORMATS INDEX REPORT 
      *    DETAIL RECORDS.
      *    ENTRY TYPE 26 = SCHEMA 
       ENVIRONMENT DIVISION.
       CONFIGURATION SECTION. 
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
       INPUT-OUTPUT SECTION.
       DATA DIVISION. 
*CALL RPTCS 
*CALL     WRKSTG77
*CALL     MAST1WS 
*CALL     TESTWACOM 
*CALL     DCDWA26 
*CALL     RPTDEF00
*CALL     RPTDEF26
*CALL     QTBL2 
*CALL     RPTWORK 
  
       PROCEDURE DIVISION.
*CALL     CATRTS
      * 
      *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY 
      * 
       3400-INIT-LINELIMS.
           IF QTBL-OUT-FRLINE EQUAL TO SPACES 
               MOVE 0001 TO FRLINE-LIMIT
              ELSE
               MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.
           IF QTBL-OUT-TOLINE EQUAL TO SPACES 
               MOVE 9999 TO TOLINE-LIMIT
              ELSE
               MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.
           IF QTBL-OUT-FORLINES EQUAL TO SPACES 
               MOVE 9999 TO FORLINE-LIMIT 
              ELSE
               MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT. 
      * 
      *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY
      *        CATEGORIES ARE AS FOLLOWS: 
      *            995 = PEOPLE 
      *            996 = ADMINISTRATION 
      *            997 = CHARACTERISTICS
      *            998 = COMPONENTS 
      *            999 = ALL OR NONE GIVEN
      * 
           MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.
           MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME. 
           MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.
           MOVE "N" TO CATEGORY-OUTPUT-SW.
           IF CATEGORY-NUMBER EQUAL TO "999"
               GO TO 3450-SHOW-ALL. 
           IF CATEGORY-NUMBER EQUAL TO "996"
               GO TO 3450-SHOW-ALL. 
           IF CATEGORY-NUMBER EQUAL TO "997" OR "998" 
               GO TO 3460-SHOW-CHAR.
           IF CATEGORY-NUMBER EQUAL TO "995"
               GO TO 3467-SHOW-PERS.
      * 
      *    SHOW ONE CATEGORY HE ASKED FOR 
      * 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           GO TO 1100-NEXT-OUTPUT.
      * 
      *    SHOW ALL 
      * 
       3450-SHOW-ALL. 
           MOVE "010" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "020" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
      * 
       3460-SHOW-CHAR.
      * 
           MOVE "030" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           IF QTBL-OUT-CAT EQUAL "996"
               GO TO 3470-CHECK-SUPER.
           IF QTBL-OUT-CAT EQUAL "998"
               GO TO 3466-JUST-COMP.
           MOVE "140" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           IF QTBL-OUT-CAT EQUAL "995"
               GO TO 3470-CHECK-SUPER.
           MOVE "200" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "450" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "475" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "550" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "575" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           IF QTBL-OUT-CAT EQUAL TO "997" 
               GO TO 3470-CHECK-SUPER.
      * 
       3465-SHOW-COMP.
           IF QTBL-OUT-CAT EQUAL "999"
               GO TO 3466-JUST-COMP.
           MOVE "030" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
      * 
       3466-JUST-COMP.
           MOVE "300" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           IF QTBL-OUT-CAT NOT EQUAL "999"
               GO TO 3470-CHECK-SUPER.
           MOVE "900" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           GO TO 3470-CHECK-SUPER.
      * 
       3467-SHOW-PERS.
           MOVE "30" TO CATEGORY-NUMBER 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
           MOVE "140" TO CATEGORY-NUMBER
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
      * 
      *    CHECK TO SEE IF ANY OUTPUT FOR ENTRY 
      * 
       3470-CHECK-SUPER.
           IF CATEGORY-OUTPUT-SW EQUAL TO "Y" 
               GO TO 1100-NEXT-OUTPUT.
       3475-NO-CATS.
           MOVE NO-CATS-MSG TO STD-RPT-MESSAGE. 
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE "Y" TO CATEGORY-811-SW. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           GO TO 1100-NEXT-OUTPUT.
  
      ******************************************************************
      * 
      *    DISPLAY CATEGORY 
      *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS 
      *        EITHER A 70, 80 OR 132 CHARACTER LINE
      * 
      ******************************************************************
       3500-DISPLAY-CATEGORY. 
           MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.
           MOVE 0001 TO CATLINE-COUNTER.
           PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.
           IF DATA-RETURN-CODE EQUAL TO "0" 
               GO TO 3510-CK-1ST-LINE.
      * 
      *    CHECK FOR SUPER CAT AND BYPASS MSG 
      * 
           IF QTBL-OUT-CAT GREATER THAN 950 
           GO TO 3749-DISPLAY-CAT-XIT.
           GO TO 3715-NOCAT-LINE. 
      * 
      *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE 
      *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT
      * 
       3510-CK-1ST-LINE.
           IF CAT-LINE LESS THAN FRLINE-LIMIT 
               GO TO 3515-BYPASS-LINE.
      * 
      *    RETRIEVE 1ST LINE OF CATEGORY
      * 
           IF CAT-LINE GREATER THAN TOLINE-LIMIT
               GO TO 3717-CK-SUPER-CAT. 
           GO TO 3520-OUTPUT-CATHDR.
       3515-BYPASS-LINE.
           PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.
           IF DATA-RETURN-CODE EQUAL TO "0" OR "3"
               GO TO 3510-CK-1ST-LINE.
       3717-CK-SUPER-CAT. 
           IF QTBL-OUT-CAT GREATER THAN 950 
               GO TO 3749-DISPLAY-CAT-XIT.
           GO TO 3715-NOCAT-LINE. 
      * 
      *    LOOKUP AND OUTPUT CATEGORY HEADER LINE 
      * 
       3520-OUTPUT-CATHDR.
           MOVE 1 TO SUB4.
       3525-NEXT-CATNUM.
           IF ENT26-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER 
               GO TO 3530-DISPLAY-HDG.
           ADD 1 TO SUB4. 
           GO TO 3525-NEXT-CATNUM.
       3530-DISPLAY-HDG.
           IF RTBL-OPT-REPORT EQUAL "N" 
               GO TO 3550-FMT-FILE-DETAIL.
           MOVE SPACES TO STD-RPT-CATHDG. 
           MOVE ENT26-CATHDRS (SUB4) TO CATEGORY-HEADER.
           MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE "Y" TO CATEGORY-811-SW
               MOVE CATEGORY-HEADER TO CAT-HEADER-811 
               MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.
           MOVE 2 TO PRT-CTL. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           MOVE 1 TO PRT-CTL. 
           MOVE SPACES TO STD-RPT-CATHDG. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           MOVE "Y" TO CATEGORY-OUTPUT-SW.
      ******************************************************* 
      * 
      *    FORMAT $FILE REQUEST DETAIL RECORDS
      *        A RECORD IS FORMATTED FOR EACH SELECTED LINE 
      * 
      ******************************************************* 
       3550-FMT-FILE-DETAIL.
           IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"
               GO TO 3590-FMT-CAT-DETAIL. 
      * 
      *    USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY 
      * 
           MOVE 1 TO HDG-SUB. 
      *    FIND THE FIRST DASH IN THE HDG 
       3570-FIND-DASH.
           IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"
               ADD 1 TO HDG-SUB 
               GO TO 3570-FIND-DASH.
       3580-BYPASS-DASH.
           IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-" 
               ADD 1 TO HDG-SUB 
               GO TO 3580-BYPASS-DASH.
           MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.
           ADD 1 TO HDG-SUB.
           MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.
           ADD 1 TO HDG-SUB.
           MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.
      * 
      *    FORMAT DETAIL RECORD 
      * 
           MOVE SPACES TO USER-LINE200-REC. 
           MOVE RTBL-HDR-REQNO     TO  USER-L200-REQNO. 
           MOVE EXT-HOLD-CATNAME   TO  USER-L200-CNAME. 
           MOVE EXT-HOLD-TYPE      TO  USER-L200-ENTTYPE. 
           MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT. 
           MOVE CAT-LENGTH         TO  USER-L200-LENGTH.
           MOVE CAT-LINE           TO  USER-L200-LINE.
           MOVE CAT-REV            TO  USER-L200-REV. 
           MOVE CAT-DETAIL         TO  USER-L200-DATA.
           MOVE "U" TO CATTBL-FILE-TYPE.
           IF CAT-LENGTH   GREATER THAN 67
               MOVE "5" TO USER-L200-RECTYPE
               MOVE "5" TO CATTBL-RECORD-TYPE 
           ELSE 
               MOVE "4" TO USER-L200-RECTYPE
               MOVE "4" TO CATTBL-RECORD-TYPE.
           PERFORM 0900-USERFILE-OUT  THRU 0999-USERFILE-OUT-XIT. 
           IF RTBL-OPT-REPORT EQUAL "N" 
               GO TO 3700-GET-NEXT-LINE.
      *************************************************** 
      * 
      *    FORMAT $REPORT DETAIL LINES
      * 
      **********************************************************
      * 
      *     FORMAT CATEGORY DETAIL LINES
      *        IF 70CHAR FORMAT PUT OUT LINE NO ON SEP LINE 
      * 
       3590-FMT-CAT-DETAIL. 
           IF RTBL-OPT-FORMAT EQUAL TO "S"
               GO TO 3595-FMT-LINE-PREFIX.
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE 98765 TO STDRPT-REVNO 
               MOVE CAT-LINE TO STDRPT-LINE 
               GO TO 3600-FORMAT-REPORT.
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           GO TO 3600-FORMAT-REPORT.
       3595-FMT-LINE-PREFIX.
           MOVE CAT-REV TO STDRPT-REVNO.
           MOVE CAT-LINE TO STDRPT-LINE.
       3600-FORMAT-REPORT.
           IF CAT-COMMENT EQUAL "*" 
               PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT 
               GO TO 3700-GET-NEXT-LINE.
      * 
      *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT 
      * 
           IF CATEGORY-NUMBER EQUAL TO "010"
               PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "020"
               PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "030"
               PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "140"
               PERFORM 5500-FMT-CAT140 THRU 5690-FMT-CAT140-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "200"
               PERFORM 12200-FMT-CAT200 THRU 12270-FMT-CAT200-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "300"
               PERFORM FMT-CAT300 THRU FMT-CAT300-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "450"
               PERFORM FMT-CAT450 THRU FMT-CAT450-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "475"
               PERFORM FMT-CAT475 THRU FMT-CAT475-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "550"
               PERFORM FMT-CAT550 THRU FMT-CAT550-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "575"
               PERFORM FMT-CAT575 THRU FMT-CAT575-XIT 
               GO TO 3700-GET-NEXT-LINE.
           IF CATEGORY-NUMBER EQUAL TO "900"
               PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT 
               GO TO 3700-GET-NEXT-LINE.
           GO TO 3710-NOCAT-DATA. 
      * 
      *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END
      * 
       3700-GET-NEXT-LINE.
           IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT
             GO TO 3749-DISPLAY-CAT-XIT.
           PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.
           IF DATA-RETURN-CODE EQUAL TO  1 OR 2 
               GO TO 3749-DISPLAY-CAT-XIT.
           IF CAT-LINE GREATER THAN TOLINE-LIMIT
               GO TO 3749-DISPLAY-CAT-XIT.
           ADD 1 TO CATLINE-COUNTER.
           GO TO 3550-FMT-FILE-DETAIL.
       3749-DISPLAY-CAT-XIT.
           EXIT.
  
      * 
      *   FORMAT WARNING AND INFORMATION MESSAGES 
      * 
       3710-NOCAT-DATA. 
           MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE. 
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE "Y" TO CATEGORY-811-SW. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           GO TO 1100-NEXT-OUTPUT.
       3715-NOCAT-LINE. 
           MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE. 
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE "Y" TO CATEGORY-811-SW. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
           GO TO 1100-NEXT-OUTPUT.
  
       3800-NOMORE-HITS.
      * 
      *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE
      * 
           GO TO 1500-REPORT-END. 
  
      ***************************************************************** 
      * 
      *    FORMAT CATEGORY 010 DETAIL LINE
      *        CATEGORY 010 = CONTROL 
      * 
      ***************************************************************** 
       5100-FMT-CAT010. 
           MOVE SPACES TO CAT00010-LINE.
      * 
      *    FORMAT ALIAS VERSION FIELD 
      * 
       5105-FMT-FLD05.
           IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.
           IF DATA-ENTRY-TYPE GREATER THAN 15 
               MOVE FLD0001005-HCONV TO FLD0001005-HDG
            ELSE
               MOVE FLD0001005-HCONA TO FLD0001005-HDG. 
           MOVE CTL-ALY-VER TO FLD0001005-VAL.
      * 
      *     FORMAT STATUS FIELD 
      * 
       5110-FMT-FLD010. 
           IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015. 
           MOVE FLD0001010-HCON TO FLD0001010-HDG.
               GO TO 5112-INTERPRET-CODE. 
       5111-JUST-CODE.
           MOVE CTL-STATUS TO FLD0001010-POS1.
           GO TO 5115-FMT-FLD015. 
       5112-INTERPRET-CODE. 
           MOVE 01 TO SUB3. 
       5113-NEXT-CODE-CK. 
           IF FLD0001010-CODES (SUB3) EQUAL TO "9"
               GO TO 5111-JUST-CODE.
           IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS 
               GO TO 5114-EXTRACT-MNG.
           ADD 1 TO SUB3. 
           GO TO 5113-NEXT-CODE-CK. 
       5114-EXTRACT-MNG.
           MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.
      * 
      *     FORMAT SECURITY FIELD 
      * 
       5115-FMT-FLD015. 
           IF CTL-SECURITY EQUAL TO SPACES
               GO TO 5120-OUTPUT-LINE.
           MOVE FLD0001015-HCON TO FLD0001015-HDG.
           MOVE CTL-SECURITY    TO FLD0001015-VAL.
      * 
      *     FORMATTING OF CATEGORY LINE COMPLETE
       5120-OUTPUT-LINE.
           IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.
           MOVE CAT00010-LINE TO STDRPT-70CHR.
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
      * 
       5199-FMT-CAT010-XIT. 
           EXIT.
  
      ***************************************************************** 
      * 
      *    FORMAT CATEGORY 020 LINE 
      *        CATEGORY 020 = KEYWORD 
      * 
      ***************************************************************** 
       5200-FMT-CAT020. 
           MOVE SPACES TO CAT00020-LINE.
      * 
      *    FORMAT KEYWORD FIELD 
      * 
       5205-FMT-FLD05.
           MOVE FLD0002005-HCON TO FLD0002005-HDG.
           MOVE KEY-WORDS TO FLD0002005-VAL.
      * 
      *    FORMATTING OF CATEGORY LINE COMPLETE 
      * 
       5210-OUTPUT-LINE.
           MOVE CAT00020-LINE TO STDRPT-70CHR.
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
       5299-FMT-CAT020-XIT. 
           EXIT.
  
      ***************************************************************** 
      * 
      *    FORMAT CATEGORY 030 LINE 
      *        CATEGORY 030 = DESCRIPTION 
      * 
      ***************************************************************** 
       5300-FMT-CAT030. 
           MOVE SPACES TO CAT00030-LINE.
           MOVE DESC-FLAG      TO FLD0003005-VAL. 
           MOVE DESC-COMMENT   TO FLD0003010-VAL. 
       5310-OUTPUT-LINE.
           MOVE CAT00030-LINE  TO STDRPT-70CHR. 
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
       5399-FMT-CAT030-XIT. 
           EXIT.
  
      ***************************************************************** 
      * 
      *    FORMAT CATEGORY 900 LINE 
      *        CATEGORY 900 = OTHER 
      ***************************************************************** 
       5900-FMT-CAT900. 
           MOVE SPACES TO CAT00900-LINE.
           MOVE DESC-FLAG      TO FLD0090005-VAL. 
           MOVE DESC-COMMENT   TO FLD0090010-VAL. 
       5910-OUTPUT-LINE.
           MOVE CAT00900-LINE TO STDRPT-70CHR.
           PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.
       5999-FMT-CAT900-XIT. 
           EXIT.
*CALL     RPTRT26 
*CALL     DISPLAY2
*CALL     WRITELNI
       USER-ROUTINE.
           IF RTBL-OPT-FORMAT EQUAL "D" 
               MOVE SUB-HEAD-811 TO PRINT-DATA
               PERFORM WRITE-LINE THRU WRITE-LINE-XIT 
               ADD 1 TO LINE-CT 
               MOVE SUB-HEAD2-811 TO PRINT-DATA 
           ELSE 
               MOVE SUB-HEADING-LINE TO PRINT-DATA. 
           ADD 2 TO LINE-CT.
           PERFORM WRITE-LINE THRU WRITE-LINE-XIT.
           MOVE SPACES TO PRINT-DATA. 
           PERFORM WRITE-LINE THRU WRITE-LINE-XIT.
           IF SEC-PAGE-SW EQUAL TO "Y"
               MOVE LIST-LINE-MSG TO CATA-NAME-LINE 
               MOVE CONTINUATION-LINE TO PRINT-DATA 
               MOVE 1 TO PRT-CTL
               PERFORM WRITE-LINE THRU WRITE-LINE-XIT 
               MOVE 1 TO PRT-CTL
               MOVE STATEMENT-LINE TO PRINT-DATA
               PERFORM WRITE-LINE THRU WRITE-LINE-XIT.
           MOVE "Y" TO SEC-PAGE-SW. 
       USER-ROUTINE-XIT.
           EXIT.
*CALL     RPT811
*CALL     MAST1RFL
*CALL     MAST1RFC
*CALL     MAST1RNL
*CALL     MAST1EXT
*CALL     MAST1RDR
*CALL     MAST1ALG
