*DECK     DCRPT213
00001  IDENTIFICATION DIVISION.                                         06/19/78
       PROGRAM-ID. RPT213.
      *    THIS MODULE PRINTS A RECORD OF A $REPORT OR $FILE REQUEST. 
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR "RECORDS". THE MODULE ALSO FORMATS INDEX REPORT
      *    DETAIL RECORDS.
      *    ENTRY TYPE 13 = RECORD 
00011  ENVIRONMENT DIVISION.                                               CL**2
00012  CONFIGURATION SECTION.                                              CL**2
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
00015  INPUT-OUTPUT SECTION.                                               CL**2
00016  DATA DIVISION.                                                      CL**2
*CALL RPTCS 
*CALL     WRKSTG77                                                         CL**2
*CALL     MAST1WS                                                          CL**2
*CALL     TESTWACOM                                                        CL**2
*CALL     DCDWA13                                                          CL**2
           02  DEP-QUAL REDEFINES CAT-DETAIL. 
               03  FILLER              PICTURE X. 
               03  STC-OCC-DEP-QUAL3   PICTURE X(32). 
               03  STC-OCC-DEP-QUAL4   PICTURE X(32). 
               03  STC-OCC-DEP-QUAL5   PICTURE X(32). 
           02  R-T-QUAL REDEFINES CAT-DETAIL. 
               03  FILLER              PICTURE X. 
               03  STC-REN-THR-QUAL4   PICTURE X(32). 
               03  STC-REN-THR-QUAL5   PICTURE X(32). 
*CALL RPTDEF00
*CALL     RPTDEF13                                                         CL**2
*CALL     QTBL2                                                            CL**2
*CALL     RPTWORK                                                          CL**2
00179                                                                    DCRPT21
00180  PROCEDURE DIVISION.                                                 CL**2
*CALL     CATRTS                                                           CL**2
00188 *                                                                    CL**2
00189 *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY                      CL**2
00190 *                                                                    CL**2
00191  3400-INIT-LINELIMS.                                                 CL**2
00192      IF QTBL-OUT-FRLINE EQUAL TO SPACES                              CL**2
00193          MOVE 0001 TO FRLINE-LIMIT                                   CL**2
00194         ELSE                                                         CL**2
00195          MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.                       CL**2
00196      IF QTBL-OUT-TOLINE EQUAL TO SPACES                              CL**2
00197          MOVE 9999 TO TOLINE-LIMIT                                   CL**2
00198         ELSE                                                         CL**2
00199          MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.                       CL**2
00200      IF QTBL-OUT-FORLINES EQUAL TO SPACES                            CL**2
00201          MOVE 9999 TO FORLINE-LIMIT                                  CL**2
00202         ELSE                                                         CL**2
00203          MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT.                    CL**2
00204 *                                                                    CL**2
00205 *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY           CL**2
      *        CATEGORIES ARE AS FOLLOWS
      *            995 = PEOPLE 
      *            996 = ADMINISTRATION 
      *            997 = CHARACTERISTICS
      *            998 = COMPONENTS 
      *            999 = ALL  OR NONE GIVEN 
00206 *                                                                    CL**2
00207      MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.                           CL**2
00208      MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME.                          CL**2
00209      MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.                       CL**2
00210      MOVE "N" TO CATEGORY-OUTPUT-SW.                                 CL**2
00211      IF CATEGORY-NUMBER EQUAL TO "999"                               CL**2
00212          GO TO 3450-SHOW-ALL.                                        CL**2
00213      IF CATEGORY-NUMBER EQUAL TO "998"                               CL**2
00214          GO TO 3465-SHOW-COMP.                                       CL**2
00215      IF CATEGORY-NUMBER EQUAL TO "996"                               CL**2
00216          GO TO 3450-SHOW-ALL.                                        CL**2
00217      IF CATEGORY-NUMBER EQUAL TO "997" OR "995"                      CL**2
00218          GO TO 3460-SHOW-CHAR.                                       CL**2
00219 *                                                                    CL**2
00220 *    SHOW ONE CATEGORY HE ASKED FOR                                  CL**2
00221 *                                                                    CL**2
00222      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00223      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00224 *                                                                    CL**2
00225 *    SHOW ALL                                                        CL**2
00226 *                                                                    CL**2
00227  3450-SHOW-ALL.                                                      CL**2
00228      MOVE "010" TO CATEGORY-NUMBER.                                  CL**2
00229      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00230      MOVE "020" TO CATEGORY-NUMBER.                                  CL**2
00231      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00232 *                                                                    CL**2
00233  3460-SHOW-CHAR.                                                     CL**2
00234 *                                                                    CL**2
00235      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00236      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00237      IF QTBL-OUT-CAT EQUAL TO "996" OR "995"                         CL**2
00238          GO TO 3470-CHECK-SUPER.                                     CL**2
00239      MOVE "200" TO CATEGORY-NUMBER.                                  CL**2
00240      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00241      MOVE "210" TO CATEGORY-NUMBER.                                  CL**2
00242      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
           MOVE "400" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
00243      MOVE "900" TO CATEGORY-NUMBER.                                  CL**2
00244      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00245      IF QTBL-OUT-CAT EQUAL TO "997"                                  CL**2
00246          GO TO 3470-CHECK-SUPER.                                     CL**2
00247  3465-SHOW-COMP.                                                     CL**2
00248      IF QTBL-OUT-CAT EQUAL TO "999"                                  CL**2
00249          GO TO 3466-JUST-COMP.                                       CL**2
00250      MOVE "030" TO CATEGORY-NUMBER.                                  CL**2
00251      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00252  3466-JUST-COMP.                                                     CL**2
00253      MOVE "300" TO CATEGORY-NUMBER.                                  CL**2
00254      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00255 *                                                                    CL**2
00256 *    CHECK TO SEE IF ANY OUTPUT FOR RECORDS                          CL**2
00257 *                                                                    CL**2
00258  3470-CHECK-SUPER.                                                   CL**2
00259      IF CATEGORY-OUTPUT-SW EQUAL TO "Y"                              CL**2
00260          GO TO 1100-NEXT-OUTPUT.                                     CL**2
00261  3475-NO-CATS.                                                       CL**2
00262      MOVE NO-CATS-MSG TO STD-RPT-MESSAGE.                            CL**2
00263      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00264          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00265      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00266      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00267                                                                    DCRPT21
00268 ******************************************************************   CL**2
00269 *                                                                    CL**2
00270 *    DISPLAY CATEGORY                                                CL**2
00271 *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS          CL**2
00272 *        EITHER A 70, 80 OR 132 CHARACTER LINE                       CL**2
00273 *                                                                    CL**2
00274 ******************************************************************   CL**2
00275  3500-DISPLAY-CATEGORY.                                              CL**2
00276      MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.                         CL**2
00277      MOVE 0001 TO CATLINE-COUNTER.                                   CL**2
00278      PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.                   CL**2
00279      IF DATA-RETURN-CODE EQUAL TO "0"                                CL**2
00280          GO TO 3510-CK-1ST-LINE.                                     CL**2
00281 *                                                                    CL**2
00282 *    CHECK FOR SUPER CAT AND BYPASS MSG                              CL**2
00283 *                                                                    CL**2
00284      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00285          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00286      GO TO 3715-NOCAT-LINE.                                          CL**2
00287 *                                                                    CL**2
00288 *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE                CL**2
00289 *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT           CL**2
00290 *                                                                    CL**2
00291  3510-CK-1ST-LINE.                                                   CL**2
00292      IF CAT-LINE LESS THAN FRLINE-LIMIT                              CL**2
00293          GO TO 3515-BYPASS-LINE.                                     CL**2
00294 *                                                                    CL**2
00295 *    RETRIEVE 1ST LINE OF CATEGORY                                   CL**2
00296 *                                                                    CL**2
00297      IF CAT-LINE GREATER THAN TOLINE-LIMIT                           CL**2
00298          GO TO 3517-CK-SUPER-CAT.                                    CL**2
00299      GO TO 3520-OUTPUT-CATHDR.                                       CL**2
00300  3515-BYPASS-LINE.                                                   CL**2
00301      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.                 CL**2
00302      IF DATA-RETURN-CODE EQUAL TO "0" OR "3"                         CL**2
00303          GO TO 3510-CK-1ST-LINE.                                     CL**2
00304  3517-CK-SUPER-CAT.                                                  CL**2
00305      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00306          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00307      GO TO 3715-NOCAT-LINE.                                          CL**2
00308 *                                                                    CL**2
00309 *    LOOKUP AND OUTPUT CATEGORY HEADER LINE                          CL**2
00310 *                                                                    CL**2
00311  3520-OUTPUT-CATHDR.                                                 CL**2
00312      MOVE 1 TO SUB4.                                                 CL**2
00313  3525-NEXT-CATNUM.                                                   CL**2
00314      IF ENT13-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER                CL**2
00315          GO TO 3530-DISPLAY-HDG.                                     CL**2
00316      ADD 1 TO SUB4.                                                  CL**2
00317      GO TO 3525-NEXT-CATNUM.                                         CL**2
00318  3530-DISPLAY-HDG.                                                   CL**2
00319      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00320          GO TO 3532-FMT-FILE-DETAIL.                                 CL**2
00321      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00322      MOVE ENT13-CATHDRS (SUB4) TO CATEGORY-HEADER.                   CL**2
00323      MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.                     CL**2
00324      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00325          MOVE "Y" TO CATEGORY-811-SW                                 CL**2
00326          MOVE CATEGORY-HEADER TO CAT-HEADER-811                      CL**2
00327          MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.                 CL**2
00328      MOVE 2 TO PRT-CTL.                                              CL**2
00329      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00330      MOVE 1 TO PRT-CTL.                                              CL**2
00331      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00332      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00333      MOVE "Y" TO CATEGORY-OUTPUT-SW.                                 CL**2
00334 *****************************************************************    CL**2
00335 *                                                                    CL**2
00336 *     FORMAT$FILE REQUEST DETAIL RECORDS                             CL**2
00337 *          A RECORD IS FORMATTED FOR EACH SELECTED LINE              CL**2
00338 *                                                                    CL**2
00339 ***************************************************************      CL**2
00340  3532-FMT-FILE-DETAIL.                                               CL**2
00341      IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"               CL**2
00342          GO TO 3540-FMT-CAT-DETAIL.                                  CL**2
00343 *                                                                    CL**2
00344 *     USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY     CL**2
00345 *                                                                    CL**2
00346      MOVE 1 TO HDG-SUB.                                              CL**2
00347 *     FIND THE FIRST DASH IN THE HDG                                 CL**2
00348  3534-FIND-DASH.                                                     CL**2
00349      IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"                     CL**2
00350          ADD 1 TO HDG-SUB                                            CL**2
00351          GO TO 3534-FIND-DASH.                                       CL**2
00352  3536-BYPASS-DASH.                                                   CL**2
00353      IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-"                      CL**2
00354          ADD 1 TO HDG-SUB                                            CL**2
00355          GO TO 3536-BYPASS-DASH.                                     CL**2
00356      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.           CL**2
00357      ADD 1 TO HDG-SUB.                                               CL**2
00358      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.           CL**2
00359      ADD 1 TO HDG-SUB.                                               CL**2
00360      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.           CL**2
00361 *                                                                    CL**2
00362 *     FORMAT DETAIL RECORD                                           CL**2
00363 *                                                                    CL**2
00364      MOVE SPACES TO USER-LINE200-REC.                                CL**2
00365      MOVE RTBL-HDR-REQNO TO USER-L200-REQNO.                         CL**2
00366      MOVE EXT-HOLD-CATNAME TO USER-L200-CNAME.                       CL**2
00367      MOVE EXT-HOLD-TYPE TO USER-L200-ENTTYPE.                        CL**2
00368      MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT.                      CL**2
00369      MOVE CAT-LENGTH    TO USER-L200-LENGTH.                         CL**2
00370      MOVE CAT-LINE      TO USER-L200-LINE.                           CL**2
00371      MOVE CAT-REV       TO USER-L200-REV.                            CL**2
00372      MOVE CAT-DETAIL    TO USER-L200-DATA.                           CL**2
00373      MOVE "U" TO CATTBL-FILE-TYPE.                                   CL**2
00374      IF CAT-LENGTH GREATER THAN 67                                   CL**2
00375      MOVE "5" TO USER-L200-RECTYPE                                   CL**2
00376          MOVE "5" TO CATTBL-RECORD-TYPE                              CL**2
00377      ELSE                                                            CL**2
00378      MOVE "4" TO USER-L200-RECTYPE                                   CL**2
00379          MOVE "4" TO CATTBL-RECORD-TYPE.                             CL**2
00380      PERFORM 0900-USERFILE-OUT THRU 0999-USERFILE-OUT-XIT.           CL**2
00381      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00382          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00383 *                                                                    CL**2
00384 *    FORMAT CATEGORY DETAIL LINES                                    CL**2
00385 *        IF 70 CHR FORMAT PUT OUT LINE NO ON SEP LINE                CL**2
00386 *                                                                    CL**2
00387  3540-FMT-CAT-DETAIL.                                                CL**2
00388      IF RTBL-OPT-FORMAT EQUAL "S"                                    CL**2
00389          GO TO 3550-FMT-LINE-PREFIX.                                 CL**2
00390      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00391          GO TO 3550-FMT-LINE-PREFIX.                                 CL**2
00392      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00393      GO TO 3560-FORMAT-REPORT.                                       CL**2
00394  3550-FMT-LINE-PREFIX.                                               CL**2
00395      IF CATEGORY-NUMBER NOT EQUAL TO "300"                           CL**2
00396          GO TO 3555-MOVE-LINE.                                       CL**2
00397      IF FIRST-REC-SW EQUAL TO "Y"                                    CL**2
00398          GO TO 3560-FORMAT-REPORT.                                   CL**2
00399  3555-MOVE-LINE.                                                     CL**2
00400      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00401          MOVE 98765 TO STDRPT-REVNO                                  CL**2
00402          MOVE CAT-LINE TO STDRPT-LINE                                CL**2
00403          GO TO 3560-FORMAT-REPORT                                    CL**2
00404      ELSE                                                            CL**2
00405          MOVE CAT-REV TO STDRPT-REVNO                                CL**2
00406      MOVE CAT-LINE TO STDRPT-LINE.                                   CL**2
00407 *                                                                    CL**2
00408 *    CHECK FOR COMMENT LINE                                          CL**2
00409  3560-FORMAT-REPORT.                                                 CL**2
00410      IF CAT-COMMENT NOT EQUAL TO "*"                                 CL**2
00411          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00412      IF CATEGORY-NUMBER EQUAL TO "300"                               CL**2
00413          GO TO 3565-CATEGORY-CHECK.                                  CL**2
00414      PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT.               CL**2
00415      GO TO 3700-GET-NEXT-LINE.                                       CL**2
00416 *                                                                    CL**2
00417 *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT              CL**2
00418 *                                                                    CL**2
00419  3565-CATEGORY-CHECK.                                                CL**2
00420      IF CATEGORY-NUMBER EQUAL TO "010"                               CL**2
00421          PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT            CL**2
00422          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00423      IF CATEGORY-NUMBER EQUAL TO "020"                               CL**2
00424          PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT            CL**2
00425          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00426      IF CATEGORY-NUMBER EQUAL TO "030"                               CL**2
00427          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT            CL**2
00428          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00429      IF CATEGORY-NUMBER EQUAL TO "200"                               CL**2
00430          PERFORM 11200-FMT-CAT200 THRU 11260-FMT-CAT200-XIT          CL**2
00431          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00432      IF CATEGORY-NUMBER EQUAL TO "210"                               CL**2
00433          PERFORM 11500-FMT-CAT210 THRU 11580-FMT-CAT210-XIT          CL**2
00434          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00435      IF CATEGORY-NUMBER EQUAL TO "300"                               CL**2
               PERFORM 11800-FMT-CAT300 THRU 1299-FMT-CAT300-XIT
00437      GO TO 3700-GET-NEXT-LINE.                                       CL**2
           IF CATEGORY-NUMBER EQUAL TO "400"
               PERFORM FMT-CAT400 THRU FMT-CAT400-XIT 
               GO TO 3700-GET-NEXT-LINE 
           END-IF 
00438      IF CATEGORY-NUMBER EQUAL TO "900"                               CL**2
00439          PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT            CL**2
00440          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00441      GO TO 3710-NOCAT-DATA.                                          CL**2
00442 *                                                                    CL**2
00443 *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END                     CL**2
00444 *                                                                    CL**2
00445  3700-GET-NEXT-LINE.                                                 CL**2
00446      IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT                       CL**2
00447        GO TO 3749-DISPLAY-CAT-XIT.                                   CL**2
00448      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.                 CL**2
00449      IF DATA-RETURN-CODE EQUAL TO  1 OR 2                            CL**2
00450          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00451      IF CAT-LINE GREATER THAN TOLINE-LIMIT                           CL**2
00452          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00453      ADD 1 TO CATLINE-COUNTER.                                       CL**2
00454      GO TO 3532-FMT-FILE-DETAIL.                                     CL**2
00455  3749-DISPLAY-CAT-XIT.                                               CL**2
00456      EXIT.                                                           CL**2
00457                                                                    DCRPT21
00458 *                                                                    CL**2
00459 *   FORMAT WARNING AND INFORMATION MESSAGES                          CL**2
00460 *                                                                    CL**2
00461  3710-NOCAT-DATA.                                                    CL**2
00462      MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE.                    CL**2
00463      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00464          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00465      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00466      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00467  3715-NOCAT-LINE.                                                    CL**2
00468      MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE.                    CL**2
00469      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00470          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00471      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00472      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00473                                                                    DCRPT21
00474  3800-NOMORE-HITS.                                                   CL**2
00475 *                                                                    CL**2
00476 *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE                   CL**2
00477 *                                                                    CL**2
00478      GO TO 1500-REPORT-END.                                          CL**2
00479                                                                    DCRPT21
00480 *****************************************************************    CL**2
00481 *                                                                    CL**2
00482 *    FORMAT CATEGORY 010 DETAIL LINE                                 CL**2
00483 *        CATEGORY 010 = CONTROL                                      CL**2
00484 *                                                                    CL**2
00485 *****************************************************************    CL**2
00486  5100-FMT-CAT010.                                                    CL**2
00487      MOVE SPACES TO CAT00010-LINE.                                   CL**2
00488 *                                                                    CL**2
00489 *    FORMAT ALIAS VERSION FIELD                                      CL**2
00490 *                                                                    CL**2
00491  5105-FMT-FLD05.                                                     CL**2
00492      IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.           CL**2
00493      IF DATA-ENTRY-TYPE GREATER THAN 15                              CL**2
00494          MOVE FLD0001005-HCONV TO FLD0001005-HDG                     CL**2
00495       ELSE                                                           CL**2
00496          MOVE FLD0001005-HCONA TO FLD0001005-HDG.                    CL**2
00497      MOVE CTL-ALY-VER TO FLD0001005-VAL.                             CL**2
00498 *                                                                    CL**2
00499 *     FORMAT STATUS FIELD                                            CL**2
00500 *                                                                    CL**2
00501  5110-FMT-FLD010.                                                    CL**2
00502      IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015.            CL**2
00503      MOVE FLD0001010-HCON TO FLD0001010-HDG.                         CL**2
00504          GO TO 5112-INTERPRET-CODE.                                  CL**2
00505  5111-JUST-CODE.                                                     CL**2
00506      MOVE CTL-STATUS TO FLD0001010-POS1.                             CL**2
00507      GO TO 5115-FMT-FLD015.                                          CL**2
00508  5112-INTERPRET-CODE.                                                CL**2
00509      MOVE 01 TO SUB3.                                                CL**2
00510  5113-NEXT-CODE-CK.                                                  CL**2
00511      IF FLD0001010-CODES (SUB3) EQUAL TO "9"                         CL**2
00512          GO TO 5111-JUST-CODE.                                       CL**2
00513      IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS                  CL**2
00514          GO TO 5114-EXTRACT-MNG.                                     CL**2
00515      ADD 1 TO SUB3.                                                  CL**2
00516      GO TO 5113-NEXT-CODE-CK.                                        CL**2
00517  5114-EXTRACT-MNG.                                                   CL**2
00518      MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.                   CL**2
00519 *                                                                    CL**2
00520 *     FORMAT SECURITY FIELD                                          CL**2
00521 *                                                                    CL**2
00522  5115-FMT-FLD015.                                                    CL**2
00523      IF CTL-SECURITY EQUAL TO SPACES                                 CL**2
00524          GO TO 5120-OUTPUT-LINE.                                     CL**2
00525      MOVE FLD0001015-HCON TO FLD0001015-HDG.                         CL**2
00526      MOVE CTL-SECURITY    TO FLD0001015-VAL.                         CL**2
00527 *                                                                    CL**2
00528 *     FORMATTING OF CATEGORY LINE COMPLETE                           CL**2
00529  5120-OUTPUT-LINE.                                                   CL**2
00530      IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.     CL**2
00531      MOVE CAT00010-LINE TO STDRPT-70CHR.                             CL**2
00532      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00533 *                                                                    CL**2
00534  5199-FMT-CAT010-XIT.                                                CL**2
00535      EXIT.                                                           CL**2
00536                                                                    DCRPT21
00537 *****************************************************************    CL**2
00538 *                                                                    CL**2
00539 *    FORMAT CATEGORY 020 LINE                                        CL**2
00540 *        CATEGORY 020 = KEYWORD                                      CL**2
00541 *                                                                    CL**2
00542 *****************************************************************    CL**2
00543  5200-FMT-CAT020.                                                    CL**2
00544      MOVE SPACES TO CAT00020-LINE.                                   CL**2
00545 *                                                                    CL**2
00546 *    FORMAT KEYWORD FIELD                                            CL**2
00547 *                                                                    CL**2
00548  5205-FMT-FLD05.                                                     CL**2
00549      MOVE FLD0002005-HCON TO FLD0002005-HDG.                         CL**2
00550      MOVE KEY-WORDS TO FLD0002005-VAL.                               CL**2
00551 *                                                                    CL**2
00552 *    FORMATTING OF CATEGORY LINE COMPLETE                            CL**2
00553 *                                                                    CL**2
00554  5210-OUTPUT-LINE.                                                   CL**2
00555      MOVE CAT00020-LINE TO STDRPT-70CHR.                             CL**2
00556      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00557  5299-FMT-CAT020-XIT.                                                CL**2
00558      EXIT.                                                           CL**2
00559                                                                    DCRPT21
00560 *****************************************************************    CL**2
00561 *                                                                    CL**2
00562 *    FORMAT CATEGORY 030 LINE                                        CL**2
00563 *        CATEGORY 030 = DESCRIPTION                                  CL**2
00564 *                                                                    CL**2
00565 *****************************************************************    CL**2
00566  5300-FMT-CAT030.                                                    CL**2
00567      MOVE SPACES TO CAT00030-LINE.                                   CL**2
00568      MOVE DESC-FLAG      TO FLD0003005-VAL.                          CL**2
00569      MOVE DESC-COMMENT   TO FLD0003010-VAL.                          CL**2
00570  5310-OUTPUT-LINE.                                                   CL**2
00571      MOVE CAT00030-LINE  TO STDRPT-70CHR.                            CL**2
00572      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00573  5399-FMT-CAT030-XIT.                                                CL**2
00574      EXIT.                                                           CL**2
00575                                                                    DCRPT21
00576 *****************************************************************    CL**2
00577 *                                                                    CL**2
00578 *    FORMAT CATEGORY 900 LINE                                        CL**2
00579 *        CATEGORY 900 = OTHER                                        CL**2
00580 *****************************************************************    CL**2
00581  5900-FMT-CAT900.                                                    CL**2
00582      MOVE SPACES TO CAT00900-LINE.                                   CL**2
00583      MOVE DESC-FLAG    TO FLD0090005-VAL.                            CL**2
00584      MOVE DESC-COMMENT TO FLD0090010-VAL.                            CL**2
00585  5910-OUTPUT-LINE.                                                   CL**2
00586      MOVE CAT00900-LINE TO STDRPT-70CHR.                             CL**2
00587      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00588  5999-FMT-CAT900-XIT.                                                CL**2
00589      EXIT.                                                           CL**2
00590                                                                    DCRPT21
*CALL     RPTRT13                                                          CL**2
*CALL     DISPLAY2                                                         CL**2
*CALL     WRITELNI                                                         CL**2
00594  USER-ROUTINE.                                                       CL**2
00595      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00596          MOVE SUB-HEAD-811 TO PRINT-DATA                             CL**2
00597          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00598          MOVE SUB-HEAD2-811 TO PRINT-DATA                            CL**2
00599      ELSE                                                            CL**2
00600          MOVE SUB-HEADING-LINE TO PRINT-DATA.                        CL**2
00601      ADD 2 TO LINE-CT.                                               CL**2
00602      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00603      MOVE SPACES TO PRINT-DATA.                                      CL**2
00604      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00605      IF SEC-PAGE-SW EQUAL TO "Y"                                     CL**2
00606          MOVE LIST-LINE-MSG TO CATA-NAME-LINE                        CL**2
00607          MOVE CONTINUATION-LINE TO PRINT-DATA                        CL**2
00608          MOVE 1 TO PRT-CTL                                           CL**2
00609          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
00610          MOVE 1 TO PRT-CTL                                           CL**2
00611          MOVE STATEMENT-LINE TO PRINT-DATA                           CL**2
00612      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
00613      MOVE "Y" TO SEC-PAGE-SW.                                        CL**2
00614  USER-ROUTINE-XIT.                                                   CL**2
00615      EXIT.                                                           CL**2
*CALL     RPT811                                                           CL**2
00620                                                                    DCRPT21
*CALL     MAST1RFL                                                         CL**2
*CALL     MAST1RFC                                                         CL**2
*CALL     MAST1RNL                                                         CL**2
*CALL     MAST1EXT                                                         CL**2
*CALL     MAST1RDR                                                         CL**2
*CALL     MAST1ALG                                                         CL**2
