*DECK     DCRPT205
00001  IDENTIFICATION DIVISION.                                         06/27/78
       PROGRAM-ID. RPT205.
*CALL COPYRIGHT 
      *    THIS MODULE PRINTS AN ELEMENT FOR A $REPORT OR $FILE REQUEST.
      *    IN ADDITION IF A FILE HAS BEEN REQUESTED THIS MODULE FORMATS 
      *    RECORDS FOR ELEMENTS. THE MODULE ALSO FORMATS INDEX REPORT 
      *    DETAIL RECORDS.
      *    ENTRY TYPE 05 = ELEMENT
00011  ENVIRONMENT DIVISION.                                            DCRPT205
00012  CONFIGURATION SECTION.                                           DCRPT205
       SOURCE-COMPUTER. CYBER.
       OBJECT-COMPUTER. CYBER.
00015  INPUT-OUTPUT SECTION.                                            DCRPT205
00016  DATA DIVISION.                                                   DCRPT205
*CALL RPTCS 
*CALL     WRKSTG77                                                         CL**5
*CALL     MAST1WS                                                          CL**5
*CALL     TESTWACOM                                                        CL**5
*CALL     DCDWA05                                                          CL**5
*CALL RPTDEF05
*CALL     QTBL2                                                            CL**2
*CALL     RPTWORK                                                          CL**2
00487                                                                    DCRPT20
00488  PROCEDURE DIVISION.                                                 CL**2
*CALL     CATRTS                                                           CL**2
00496 *                                                                 DCRPT205
00497 *    INITIALIZE LINE RETRIEVAL LIMITS FOR QUERY                   DCRPT205
00498 *                                                                 DCRPT205
00499  3400-INIT-LINELIMS.                                              DCRPT205
00500      IF QTBL-OUT-FRLINE EQUAL TO SPACES                           DCRPT205
00501          MOVE 0001 TO FRLINE-LIMIT                                DCRPT205
00502         ELSE                                                      DCRPT205
00503          MOVE QTBL-OUT-FRLINE TO FRLINE-LIMIT.                    DCRPT205
00504      IF QTBL-OUT-TOLINE EQUAL TO SPACES                           DCRPT205
00505          MOVE 9999 TO TOLINE-LIMIT                                DCRPT205
00506         ELSE                                                      DCRPT205
00507          MOVE QTBL-OUT-TOLINE TO TOLINE-LIMIT.                    DCRPT205
00508      IF QTBL-OUT-FORLINES EQUAL TO SPACES                         DCRPT205
00509          MOVE 9999 TO FORLINE-LIMIT                               DCRPT205
00510         ELSE                                                      DCRPT205
00511          MOVE QTBL-OUT-FORLINES TO FORLINE-LIMIT.                 DCRPT205
00512 *                                                                 DCRPT205
00513 *    DETERMINE IF SHOW IF FOR A CATEGORY OR SUPER CATEGORY        DCRPT205
      *        CATEGORIES ARE AS FOLLOWS
      *            995 = PEOPLE 
      *            996 = ADMINISTRATION 
      *            997 = CHARACTERISTICS
      *            998 = COMPONENTS 
      *            999 = ALL  OR NONE GIVEN 
00514 *                                                                 DCRPT205
00515      MOVE QTBL-OUT-CAT TO CATEGORY-NUMBER.                           CL**2
00516      MOVE HIT-WORK-NAME TO DATA-ENTRY-NAME.                       DCRPT205
00517      MOVE HIT-WORK-ENTTYPE TO DATA-ENTRY-TYPE.                    DCRPT205
00518      MOVE "N" TO CATEGORY-OUTPUT-SW.                              DCRPT205
00519      IF CATEGORY-NUMBER EQUAL TO "999"                            DCRPT205
00520          GO TO 3450-SHOW-ALL.                                     DCRPT205
00521      IF CATEGORY-NUMBER EQUAL TO "996"                            DCRPT205
00522          GO TO 3450-SHOW-ALL.                                     DCRPT205
00523      IF CATEGORY-NUMBER EQUAL TO "997" OR "998" OR "995"             CL**2
00524          GO TO 3460-SHOW-CHAR.                                    DCRPT205
00525 *                                                                 DCRPT205
00526 *    SHOW ONE CATEGORY HE ASKED FOR                               DCRPT205
00527 *                                                                    CL**2
00528      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00529      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00530 *                                                                 DCRPT205
00531 *    SHOW ALL                                                     DCRPT205
00532 *                                                                 DCRPT205
00533  3450-SHOW-ALL.                                                   DCRPT205
00534      MOVE "010" TO CATEGORY-NUMBER.                               DCRPT205
00535      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00536      MOVE "020" TO CATEGORY-NUMBER.                               DCRPT205
00537      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00538 *                                                                    CL**2
00539  3460-SHOW-CHAR.                                                  DCRPT205
00540 *                                                                    CL**2
00541      MOVE "030" TO CATEGORY-NUMBER.                               DCRPT205
00542      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00543      IF QTBL-OUT-CAT EQUAL TO "996" OR "998" OR "995"                CL**2
00544          GO TO 3470-CHECK-SUPER.                                  DCRPT205
00545      MOVE "100" TO CATEGORY-NUMBER.                               DCRPT205
00546      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00547      MOVE "110" TO CATEGORY-NUMBER.                               DCRPT205
00548      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00553      MOVE "200" TO CATEGORY-NUMBER.                               DCRPT205
00554      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00555      MOVE "210" TO CATEGORY-NUMBER.                                  CL**2
00556      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
00557      MOVE "211" TO CATEGORY-NUMBER.                               DCRPT205
00558      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.     DCRPT205
00559      MOVE "900" TO CATEGORY-NUMBER.                                  CL**2
00560      PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT.        CL**2
           MOVE "400" TO CATEGORY-NUMBER. 
           PERFORM 3500-DISPLAY-CATEGORY THRU 3749-DISPLAY-CAT-XIT. 
00561 *                                                                 DCRPT205
00562 *    CHECK TO SEE IF ANY OUTPUT FOR ENTYR                         DCRPT205
00563 *                                                                 DCRPT205
00564  3470-CHECK-SUPER.                                                DCRPT205
00565      IF CATEGORY-OUTPUT-SW EQUAL TO "Y"                           DCRPT205
00566          GO TO 1100-NEXT-OUTPUT.                                     CL**2
00567  3475-NO-CATS.                                                       CL**2
00568      MOVE NO-CATS-MSG TO STD-RPT-MESSAGE.                         DCRPT205
00569      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00570          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00571      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00572      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00573                                                                    DCRPT20
00574 ******************************************************************DCRPT205
00575 *                                                                 DCRPT205
00576 *    DISPLAY CATEGORY                                             DCRPT205
00577 *        RETRIEVES LINES FOR SPECIFIED CATEGORY AND FORMATS       DCRPT205
00578 *        EITHER A 70, 80 OR 132 CHARACTER LINE                    DCRPT205
00579 *                                                                 DCRPT205
00580 ******************************************************************DCRPT205
00581  3500-DISPLAY-CATEGORY.                                           DCRPT205
00582      MOVE CATEGORY-NUMBER TO DATA-ENTRY-CAT.                      DCRPT205
00583      MOVE 0001 TO CATLINE-COUNTER.                                DCRPT205
00584      PERFORM READ-CATEGORY THRU READ-CATEGORY-XIT.                DCRPT205
00585      IF DATA-RETURN-CODE EQUAL TO "0"                                CL**2
00586          GO TO 3510-CK-1ST-LINE.                                     CL**2
00587 *                                                                    CL**2
00588 *    CHECK FOR SUPER CAT AND BYPASS MSG                              CL**2
00589 *                                                                    CL**2
00590      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00591      GO TO 3749-DISPLAY-CAT-XIT.                                     CL**2
00592      GO TO 3715-NOCAT-LINE.                                          CL**2
00593 *                                                                 DCRPT205
00594 *    CHECK IF FIRST CATEGORY LINE IS IN DESIRED RANGE             DCRPT205
00595 *        READ PAST LINES WITH NUMBERS LOWER THAN LOW LIMIT        DCRPT205
00596 *                                                                 DCRPT205
00597  3510-CK-1ST-LINE.                                                DCRPT205
00598      IF CAT-LINE LESS THAN FRLINE-LIMIT                           DCRPT205
00599          GO TO 3515-BYPASS-LINE.                                  DCRPT205
00600 *                                                                 DCRPT205
00601 *    RETRIEVE 1ST LINE OF CATEGORY                                DCRPT205
00602 *                                                                 DCRPT205
00603      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT205
00604          GO TO 3717-CK-SUPER-CAT.                                    CL**2
00605      GO TO 3520-OUTPUT-CATHDR.                                    DCRPT205
00606  3515-BYPASS-LINE.                                                DCRPT205
00607      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT205
00608      IF DATA-RETURN-CODE EQUAL TO "0" OR "3"                      DCRPT205
00609          GO TO 3510-CK-1ST-LINE.                                  DCRPT205
00610  3717-CK-SUPER-CAT.                                                  CL**2
00611      IF QTBL-OUT-CAT GREATER THAN 950                                CL**2
00612          GO TO 3749-DISPLAY-CAT-XIT.                                 CL**2
00613      GO TO 3715-NOCAT-LINE.                                          CL**2
00614 *                                                                 DCRPT205
00615 *    LOOKUP AND OUTPUT CATEGORY HEADER LINE                       DCRPT205
00616 *                                                                 DCRPT205
00617  3520-OUTPUT-CATHDR.                                              DCRPT205
00618      MOVE 1 TO SUB4.                                                 CL**2
00619  3525-NEXT-CATNUM.                                                DCRPT205
00620      IF ENT05-CATNUMS (SUB4) EQUAL TO CATEGORY-NUMBER                CL**2
00621          GO TO 3530-DISPLAY-HDG.                                  DCRPT205
00622      ADD 1 TO SUB4.                                               DCRPT205
00623      GO TO 3525-NEXT-CATNUM.                                      DCRPT205
00624  3530-DISPLAY-HDG.                                                DCRPT205
00625      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00626          GO TO 3550-FMT-FILE-DETAIL.                                 CL**2
00627      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00628      MOVE ENT05-CATHDRS (SUB4) TO CATEGORY-HEADER.                   CL**2
00629      MOVE CATEGORY-HEADER TO CATEGORY-NAME-WORK.                     CL**2
00630      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00631          MOVE "Y" TO CATEGORY-811-SW                                 CL**2
00632          MOVE CATEGORY-HEADER TO CAT-HEADER-811                      CL**2
00633          MOVE CATEGORY-HEADER-811 TO STD-REPORT-REC.                 CL**2
00634      MOVE 2 TO PRT-CTL.                                              CL**2
00635      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00636      MOVE 1 TO PRT-CTL.                                              CL**2
00637      MOVE SPACES TO STD-RPT-CATHDG.                                  CL**2
00638      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00639      MOVE "Y" TO CATEGORY-OUTPUT-SW.                              DCRPT205
00640 *******************************************************              CL**2
00641 *                                                                    CL**2
00642 *    FORMAT $FILE REQUEST DETAIL RECORDS                             CL**2
00643 *        A RECORD IS FORMATTED FOR EACH SELECTED LINE                CL**2
00644 *                                                                    CL**2
00645 *******************************************************              CL**2
00646  3550-FMT-FILE-DETAIL.                                               CL**2
00647      IF RTBL-HDR-REQTYPE EQUAL TO "RR" OR "RS" OR "RT"               CL**2
00648          GO TO 3590-FMT-CAT-DETAIL.                                  CL**2
00649 *                                                                    CL**2
00650 *    USE 1ST 3 CHRS OF CATEGORY HDG TO IDENTIFY OUTPUT CATEGORY      CL**2
00651 *                                                                    CL**2
00652      MOVE 1 TO HDG-SUB.                                              CL**2
00653 *    FIND THE FIRST DASH IN THE HDG                                  CL**2
00654  3570-FIND-DASH.                                                     CL**2
00655      IF CATEGORY-HDG-CHR (HDG-SUB) NOT EQUAL "-"                     CL**2
00656          ADD 1 TO HDG-SUB                                            CL**2
00657          GO TO 3570-FIND-DASH.                                       CL**2
00658  3580-BYPASS-DASH.                                                   CL**2
00659      IF CATEGORY-HDG-CHR (HDG-SUB) EQUAL TO "-"                      CL**2
00660          ADD 1 TO HDG-SUB                                            CL**2
00661          GO TO 3580-BYPASS-DASH.                                     CL**2
00662      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR1.           CL**2
00663      ADD 1 TO HDG-SUB.                                               CL**2
00664      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR2.           CL**2
00665      ADD 1 TO HDG-SUB.                                               CL**2
00666      MOVE CATEGORY-HDG-CHR (HDG-SUB) TO CATEGORY-ABB-CHR3.           CL**2
00667 *                                                                    CL**2
00668 *    FORMAT DETAIL RECORD                                            CL**2
00669 *                                                                    CL**2
00670      MOVE SPACES TO USER-LINE200-REC.                                CL**2
00671      MOVE RTBL-HDR-REQNO     TO  USER-L200-REQNO.                    CL**2
00672      MOVE EXT-HOLD-CATNAME   TO  USER-L200-CNAME.                    CL**2
00673      MOVE EXT-HOLD-TYPE      TO  USER-L200-ENTTYPE.                  CL**2
00674      MOVE CATEGORY-NAME-ABBRV TO USER-L200-CAT.                      CL**2
00675      MOVE CAT-LENGTH         TO  USER-L200-LENGTH.                   CL**2
00676      MOVE CAT-LINE           TO  USER-L200-LINE.                     CL**2
00677      MOVE CAT-REV            TO  USER-L200-REV.                      CL**2
00678      MOVE CAT-DETAIL         TO  USER-L200-DATA.                     CL**2
00679      MOVE "U" TO CATTBL-FILE-TYPE.                                   CL**2
00680      IF CAT-LENGTH   GREATER THAN 67                                 CL**2
00681          MOVE "5" TO USER-L200-RECTYPE                               CL**2
00682          MOVE "5" TO CATTBL-RECORD-TYPE                              CL**2
00683      ELSE                                                            CL**2
00684          MOVE "4" TO USER-L200-RECTYPE                               CL**2
00685          MOVE "4" TO CATTBL-RECORD-TYPE.                             CL**2
00686      PERFORM 0900-USERFILE-OUT  THRU 0999-USERFILE-OUT-XIT.          CL**2
00687      IF RTBL-OPT-REPORT EQUAL "N"                                    CL**2
00688          GO TO 3700-GET-NEXT-LINE.                                   CL**2
00689 ***************************************************                  CL**2
00690 *                                                                    CL**2
00691 *    FORMAT $REPORT DETAIL LINES                                     CL**2
00692 *                                                                    CL**2
00693 **********************************************************           CL**2
00694 *                                                                    CL**2
00695 *     FORMAT CATEGORY DETAIL LINES                                   CL**2
00696 *        IF 70CHAR FORMAT PUT OUT LINE NO ON SEP LINE                CL**2
00697 *                                                                    CL**2
00698  3590-FMT-CAT-DETAIL.                                                CL**2
00699      IF RTBL-OPT-FORMAT EQUAL TO "S"                                 CL**2
00700          GO TO 3595-FMT-LINE-PREFIX.                                 CL**2
00701      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00702          MOVE 98765 TO STDRPT-REVNO                                  CL**2
00703          MOVE CAT-LINE TO STDRPT-LINE                                CL**2
00704          GO TO 3600-FORMAT-REPORT.                                   CL**2
00705      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                     CL**2
00706      GO TO 3600-FORMAT-REPORT.                                       CL**2
00707  3595-FMT-LINE-PREFIX.                                               CL**2
00708      MOVE CAT-REV TO STDRPT-REVNO.                                   CL**2
00709      MOVE CAT-LINE TO STDRPT-LINE.                                   CL**2
00710  3600-FORMAT-REPORT.                                                 CL**2
00711      IF CAT-COMMENT EQUAL "*"                                        CL**2
00712          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT         DCRPT205
00713          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00714 *                                                                 DCRPT205
00715 *    CHECK FOR CATEGORY NUMBERS AND ENTER FORMATTING RT           DCRPT205
00716 *                                                                 DCRPT205
00717      IF CATEGORY-NUMBER EQUAL TO "010"                            DCRPT205
00718          PERFORM 5100-FMT-CAT010 THRU 5199-FMT-CAT010-XIT         DCRPT205
00719          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00720      IF CATEGORY-NUMBER EQUAL TO "020"                            DCRPT205
00721          PERFORM 5200-FMT-CAT020 THRU 5299-FMT-CAT020-XIT         DCRPT205
00722          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00723      IF CATEGORY-NUMBER EQUAL TO "030"                            DCRPT205
00724          PERFORM 5300-FMT-CAT030 THRU 5399-FMT-CAT030-XIT         DCRPT205
00725          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00726      IF CATEGORY-NUMBER EQUAL TO "100"                            DCRPT205
00727          PERFORM 6000-FMT-CAT100 THRU 6299-FMT-CAT100-XIT         DCRPT205
00728          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00729      IF CATEGORY-NUMBER EQUAL TO "110"                            DCRPT205
00730          PERFORM 6500-FMT-CAT110 THRU 6599-FMT-CAT110-XIT         DCRPT205
00731          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00738      IF CATEGORY-NUMBER EQUAL TO "200"                            DCRPT205
00739          PERFORM 7700-FMT-CAT200 THRU 7799-FMT-CAT200-XIT         DCRPT205
00740          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00741      IF CATEGORY-NUMBER EQUAL TO "210"                            DCRPT205
00742          PERFORM 7800-FMT-CAT05210 THRU 7999-FMT-CAT05210-XIT     DCRPT205
00743          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00744      IF CATEGORY-NUMBER EQUAL TO "211"                            DCRPT205
00745          PERFORM 8000-FMT-CAT211 THRU 8199-FMT-CAT211-XIT         DCRPT205
00746          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
           IF CATEGORY-NUMBER EQUAL TO "400"
               PERFORM FMT-CAT400 THRU FMT-CAT400-XIT 
               GO TO 3700-GET-NEXT-LINE.
00747      IF CATEGORY-NUMBER EQUAL TO "900"                            DCRPT205
00748          PERFORM 5900-FMT-CAT900 THRU 5999-FMT-CAT900-XIT         DCRPT205
00749          GO TO 3700-GET-NEXT-LINE.                                DCRPT205
00750      GO TO 3710-NOCAT-DATA.                                          CL**2
00751 *                                                                 DCRPT205
00752 *    RETRIEVE NEXT LINE OF CATEGORY - CK FOR END                  DCRPT205
00753 *                                                                 DCRPT205
00754  3700-GET-NEXT-LINE.                                              DCRPT205
00755      IF CATLINE-COUNTER EQUAL TO FORLINE-LIMIT                    DCRPT205
00756        GO TO 3749-DISPLAY-CAT-XIT.                                DCRPT205
00757      PERFORM READ-NEXT-DATA THRU READ-NEXT-DATA-XIT.              DCRPT205
00758      IF DATA-RETURN-CODE EQUAL TO  1 OR 2                         DCRPT205
00759          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT205
00760      IF CAT-LINE GREATER THAN TOLINE-LIMIT                        DCRPT205
00761          GO TO 3749-DISPLAY-CAT-XIT.                              DCRPT205
00762      ADD 1 TO CATLINE-COUNTER.                                       CL**2
00763      GO TO 3550-FMT-FILE-DETAIL.                                     CL**2
00764  3749-DISPLAY-CAT-XIT.                                            DCRPT205
00765      EXIT.                                                        DCRPT205
00766                                                                    DCRPT20
00767 *                                                                 DCRPT205
00768 *   FORMAT WARNING AND INFORMATION MESSAGES                       DCRPT205
00769 *                                                                 DCRPT205
00770  3710-NOCAT-DATA.                                                 DCRPT205
00771      MOVE NO-CAT-MSG   TO        STD-RPT-MESSAGE.                 DCRPT205
00772      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00773          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00774      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00775      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00776  3715-NOCAT-LINE.                                                 DCRPT205
00777      MOVE NO-LINES-MSG  TO       STD-RPT-MESSAGE.                 DCRPT205
00778      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
00779          MOVE "Y" TO CATEGORY-811-SW.                                CL**2
00780      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00781      GO TO 1100-NEXT-OUTPUT.                                         CL**2
00782                                                                    DCRPT20
00783  3800-NOMORE-HITS.                                                DCRPT205
00784 *                                                                 DCRPT205
00785 *    ON-LINE VERSION WILL DETERMINE NEXT STEP HERE                DCRPT205
00786 *                                                                 DCRPT205
00787      GO TO 1500-REPORT-END.                                          CL**2
00788                                                                    DCRPT20
00789 ***************************************************************** DCRPT205
00790 *                                                                 DCRPT205
00791 *    FORMAT CATEGORY 010 DETAIL LINE                              DCRPT205
00792 *        CATEGORY 010 = CONTROL                                   DCRPT205
00793 *                                                                 DCRPT205
00794 ***************************************************************** DCRPT205
00795  5100-FMT-CAT010.                                                 DCRPT205
00796      MOVE SPACES TO CAT00010-LINE.                                DCRPT205
00797 *                                                                 DCRPT205
00798 *    FORMAT ALIAS VERSION FIELD                                   DCRPT205
00799 *                                                                 DCRPT205
00800  5105-FMT-FLD05.                                                  DCRPT205
00801      IF CTL-ALY-VER EQUAL TO SPACES GO TO 5110-FMT-FLD010.        DCRPT205
00802      IF DATA-ENTRY-TYPE GREATER THAN 15                           DCRPT205
00803          MOVE FLD0001005-HCONV TO FLD0001005-HDG                  DCRPT205
00804       ELSE                                                        DCRPT205
00805          MOVE FLD0001005-HCONA TO FLD0001005-HDG.                 DCRPT205
00806      MOVE CTL-ALY-VER TO FLD0001005-VAL.                          DCRPT205
00807 *                                                                 DCRPT205
00808 *     FORMAT STATUS FIELD                                         DCRPT205
00809 *                                                                 DCRPT205
00810  5110-FMT-FLD010.                                                 DCRPT205
00811      IF CTL-STATUS EQUAL TO SPACES GO TO 5115-FMT-FLD015.         DCRPT205
00812      MOVE FLD0001010-HCON TO FLD0001010-HDG.                      DCRPT205
00813          GO TO 5112-INTERPRET-CODE.                                  CL**2
00814  5111-JUST-CODE.                                                     CL**2
00815      MOVE CTL-STATUS TO FLD0001010-POS1.                             CL**2
00816      GO TO 5115-FMT-FLD015.                                          CL**2
00817  5112-INTERPRET-CODE.                                                CL**2
00818      MOVE 01 TO SUB3.                                                CL**2
00819  5113-NEXT-CODE-CK.                                                  CL**2
00820      IF FLD0001010-CODES (SUB3) EQUAL TO "9"                         CL**2
00821          GO TO 5111-JUST-CODE.                                       CL**2
00822      IF FLD0001010-CODES (SUB3) EQUAL TO CTL-STATUS                  CL**2
00823          GO TO 5114-EXTRACT-MNG.                                     CL**2
00824      ADD 1 TO SUB3.                                                  CL**2
00825      GO TO 5113-NEXT-CODE-CK.                                        CL**2
00826  5114-EXTRACT-MNG.                                                   CL**2
00827      MOVE FLD0001010-MNG (SUB3) TO FLD0001010-VAL.                   CL**2
00828 *                                                                 DCRPT205
00829 *     FORMAT SECURITY FIELD                                       DCRPT205
00830 *                                                                 DCRPT205
00831  5115-FMT-FLD015.                                                 DCRPT205
00832      IF CTL-SECURITY EQUAL TO SPACES                              DCRPT205
00833          GO TO 5120-OUTPUT-LINE.                                     CL**2
00834      MOVE FLD0001015-HCON TO FLD0001015-HDG.                      DCRPT205
00835      MOVE CTL-SECURITY    TO FLD0001015-VAL.                      DCRPT205
00836 *                                                                 DCRPT205
00837 *     FORMATTING OF CATEGORY LINE COMPLETE                        DCRPT205
00838  5120-OUTPUT-LINE.                                                DCRPT205
00839      IF CAT00010-LINE EQUAL TO SPACES GO TO 5199-FMT-CAT010-XIT.  DCRPT205
00840      MOVE CAT00010-LINE TO STDRPT-70CHR.                          DCRPT205
00841      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00842 *                                                                 DCRPT205
00843  5199-FMT-CAT010-XIT.                                             DCRPT205
00844      EXIT.                                                        DCRPT205
00845                                                                    DCRPT20
00846 ***************************************************************** DCRPT205
00847 *                                                                 DCRPT205
00848 *    FORMAT CATEGORY 020 LINE                                     DCRPT205
00849 *        CATEGORY 020 = KEYWORD                                   DCRPT205
00850 *                                                                 DCRPT205
00851 ***************************************************************** DCRPT205
00852  5200-FMT-CAT020.                                                 DCRPT205
00853      MOVE SPACES TO CAT00020-LINE.                                DCRPT205
00854 *                                                                 DCRPT205
00855 *    FORMAT KEYWORD FIELD                                         DCRPT205
00856 *                                                                 DCRPT205
00857  5205-FMT-FLD05.                                                  DCRPT205
00858      MOVE FLD0002005-HCON TO FLD0002005-HDG.                      DCRPT205
00859      MOVE KEY-WORDS TO FLD0002005-VAL.                            DCRPT205
00860 *                                                                 DCRPT205
00861 *    FORMATTING OF CATEGORY LINE COMPLETE                         DCRPT205
00862 *                                                                 DCRPT205
00863  5210-OUTPUT-LINE.                                                DCRPT205
00864      MOVE CAT00020-LINE TO STDRPT-70CHR.                          DCRPT205
00865      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00866  5299-FMT-CAT020-XIT.                                             DCRPT205
00867      EXIT.                                                        DCRPT205
00868                                                                    DCRPT20
00869 ***************************************************************** DCRPT205
00870 *                                                                 DCRPT205
00871 *    FORMAT CATEGORY 030 LINE                                     DCRPT205
00872 *        CATEGORY 030 = DESCRIPTION                               DCRPT205
00873 *                                                                 DCRPT205
00874 ***************************************************************** DCRPT205
00875  5300-FMT-CAT030.                                                 DCRPT205
00876      MOVE SPACES TO CAT00030-LINE.                                   CL**2
00877      MOVE DESC-FLAG      TO FLD0003005-VAL.                       DCRPT205
00878      MOVE DESC-COMMENT   TO FLD0003010-VAL.                       DCRPT205
00879  5310-OUTPUT-LINE.                                                DCRPT205
00880      MOVE CAT00030-LINE  TO STDRPT-70CHR.                         DCRPT205
00881      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00882  5399-FMT-CAT030-XIT.                                             DCRPT205
00883      EXIT.                                                        DCRPT205
00884                                                                    DCRPT20
00885 ***************************************************************** DCRPT205
00886 *                                                                 DCRPT205
00887 *    FORMAT CATEGORY 900 LINE                                     DCRPT205
00888 *        CATEGORY 900 = OTHER                                     DCRPT205
00889 ***************************************************************** DCRPT205
00890  5900-FMT-CAT900.                                                 DCRPT205
00891      MOVE SPACES TO CAT00900-LINE.                                   CL**2
00892      MOVE DESC-FLAG      TO FLD0090005-VAL.                          CL**2
00893      MOVE DESC-COMMENT   TO FLD0090010-VAL.                          CL**2
00894  5910-OUTPUT-LINE.                                                DCRPT205
00895      MOVE CAT00900-LINE TO STDRPT-70CHR.                             CL**2
00896      PERFORM DISPLAY-LINE THRU DISPLAY-LINE-XIT.                  DCRPT205
00897  5999-FMT-CAT900-XIT.                                             DCRPT205
00898      EXIT.                                                        DCRPT205
00899                                                                    DCRPT20
*CALL RPTRT05 
*CALL     DISPLAY2                                                         CL**2
*CALL     WRITELNI                                                         CL**2
01500  USER-ROUTINE.                                                       CL**2
01501      IF RTBL-OPT-FORMAT EQUAL "D"                                    CL**2
01502          MOVE SUB-HEAD-811 TO PRINT-DATA                             CL**2
01503          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
01504          ADD 1 TO LINE-CT                                            CL**2
01505          MOVE SUB-HEAD2-811 TO PRINT-DATA                            CL**2
01506      ELSE                                                            CL**2
01507          MOVE SUB-HEADING-LINE TO PRINT-DATA.                        CL**2
01508      ADD 2 TO LINE-CT.                                               CL**2
01509      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
01510      MOVE SPACES TO PRINT-DATA.                                      CL**2
01511      PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                         CL**2
01512      IF SEC-PAGE-SW EQUAL TO "Y"                                     CL**2
01513          MOVE LIST-LINE-MSG TO CATA-NAME-LINE                        CL**2
01514          MOVE CONTINUATION-LINE TO PRINT-DATA                        CL**2
01515          MOVE 1 TO PRT-CTL                                           CL**2
01516          PERFORM WRITE-LINE THRU WRITE-LINE-XIT                      CL**2
01517          MOVE 1 TO PRT-CTL                                           CL**2
01518          MOVE STATEMENT-LINE TO PRINT-DATA                           CL**2
01519          PERFORM WRITE-LINE THRU WRITE-LINE-XIT.                     CL**2
01520      MOVE "Y" TO SEC-PAGE-SW.                                        CL**2
01521  USER-ROUTINE-XIT.                                                   CL**2
01522      EXIT.                                                           CL**2
*CALL     RPT811                                                           CL**2
*CALL     MAST1RFL                                                         CL**2
01528                                                                    DCRPT20
*CALL     MAST1RFC                                                         CL**5
*CALL     MAST1RNL                                                         CL**5
*CALL     MAST1EXT                                                         CL**5
*CALL     MAST1RDR                                                         CL**2
*CALL     MAST1ALG                                                         CL**5
