*COMDECK  COMCSTF            SET TERMINAL FILE.                          COMCSTF
 STF      CTEXT  COMCSTF - SET TERMINAL FILE.                            COMCSTF
 STF      SPACE  4,10                                                    COMCSTF
          IF     -DEF,QUAL$,1                                            COMCSTF
          QUAL   COMCSTF                                                 COMCSTF
          BASE   D                                                       COMCSTF
*         COMMENT COPYRIGHT CONTROL DATA CORP. 1971, 1978.               COMCSTF
 STF      SPACE  4,10                                                    COMCSTF
***       STF - SET TERMINAL FILE.                                       COMCSTF
*                                                                        COMCSTF
*         J. L. WARDELL.     71/01/29.                                   COMCSTF
*         R. E. TATE.        73/04/08.                                   COMCSTF
*         G. M. TOWNSEND.    77/05/26.                                   COMCSTF
*         C. J. CONRAD.      81/08/06.
* 
*         ******************************************************* 
*         * THIS COMMON DECK IS PART OF THE COMMON COMMON DECKS * 
*         * RESIDING ON THE COMPASS PROGRAM LIBRARY, AND BEING  * 
*         * MAINTAINED BY THE COMPASS PROJECT.  ANY CHANGES     * 
*         * REQUIRED SHOULD BE DIRECTED TO THE COMPASS PROJECT  * 
*         * THROUGH THE PROPER PROCEDURE.                       * 
*         ******************************************************* 
* 
*                                                                        COMCSTF
*         STF DETERMINES WHETHER A FILE IS ASSIGNED TO AN INTERACTIVE    COMCSTF
*         TERMINAL.                                                      COMCSTF
 STF      SPACE  4,10                                                    COMCSTF
***       STF DETECTS IF A FILE IS ASSIGNED TO A TERMINAL.               COMCSTF
*                                                                        COMCSTF
*         ENTRY  (X2) = ADDRESS OF FET.                                  COMCSTF
*                (B1) = 1.                                               COMCSTF
*                FET MUST BE GREATER THAN FIVE WORDS IN LENGTH.          COMCSTF
*                                                                        COMCSTF
*         EXIT   (X6) = 0 IF FILE IS TERMINAL FILE.                      COMCSTF
*                (X2) = ADDRESS OF FET.                                  COMCSTF
*                                                                        COMCSTF
*         USES   A - 1, 4, 6. 
*                B - NONE.                                               COMCSTF
*                X - 1, 3, 4, 6.                                         COMCSTF
*                                                                        COMCSTF
*         MACROS OPEN.
                                                                         COMCSTF
                                                                         COMCSTF
 STF      SUBR               ENTRY/EXIT                                  COMCSTF
          SA1    X2          CHECK FILE NAME AND STATUS 
          SX6    1
          BX6    X6+X1       SET PREVIOUS STATUS COMPLETE 
          ZR     X1,STFX     IF NULL FILE, RETURN 
          SA6    STFA        SAVE FET STATUS
          OPEN   X2,ALTERNR,R                                            COMCSTF
          SA1    STFA        RESTORE PREVIOUS FUNCTION CODE 
          MX3    -12
          BX6    X1 
          SA1    X2+B1
          SA6    X2 
          LX1    -48                                                     COMCSTF
          BX4    -X3*X1                                                  COMCSTF
          SX6    X4-2RTT     CHECK FOR DEVICE TYPE *TT*                  COMCSTF
          ZR     X6,STFX                                                 COMCSTF
          AX4    6                                                       COMCSTF
          SX6    X4-61B      CHECK FOR DEVICE TYPE 61B                   COMCSTF
          EQ     STFX        RETURN                                      COMCSTF
  
 STFA     CON    0           SAVE FET FUNCTION CODE 
 STF      SPACE  4,10                                                    COMCSTF
          BASE   *                                                       COMCSTF
 QUAL$    IF     -DEF,QUAL$                                              COMCSTF
          QUAL   *                                                       COMCSTF
 STF      EQU    /COMCSTF/STF                                            COMCSTF
 STF=     EQU    /COMCSTF/STF 
 QUAL$    ENDIF                                                          COMCSTF
 STF      ENDX                                                           COMCSTF
