*COMDECK  COMCCPT            COPY PREFIX TABLE.                          COMCCPT
 CPT      CTEXT  COMCCPT - COPY PREFIX TABLE.                            COMCCPT
 CPT      SPACE  4,10                                                    COMCCPT
          IF     -DEF,QUAL$,1                                            COMCCPT
          QUAL   COMCCPT                                                 COMCCPT
          BASE   D                                                       COMCCPT
          CODE   D                                                       COMCCPT
*         COMMENT COPYRIGHT CONTROL DATA CORPORATION. 1973, 1978.        COMCCPT
 CPT      SPACE  4,10                                                    COMCCPT
***       CPT - COPY PREFIX TABLE.                                       COMCCPT
*                                                                        COMCCPT
*         P. D. HAAS.        73/10/12.                                   COMCCPT
* 
*         ******************************************************* 
*         * THIS COMMON DECK IS PART OF THE COMMON COMMON DECKS * 
*         * RESIDING ON THE COMPASS PROGRAM LIBRARY, AND BEING  * 
*         * MAINTAINED BY THE COMPASS PROJECT.  ANY CHANGES     * 
*         * REQUIRED SHOULD BE DIRECTED TO THE COMPASS PROJECT  * 
*         * THROUGH THE PROPER PROCEDURE.                       * 
*         ******************************************************* 
* 
*                                                                        COMCCPT
*         CPT EXTRACTS THE COMMENTS FIELD FROM A PREFIX TABLE.           COMCCPT
 CPT      SPACE  4,10                                                    COMCCPT
***       CPT COPIES THE COMMENTS FIELD OF A PREFIX (7700) TABLE.        COMCCPT
*         BOTH OLD AND NEW FORMS OF THE PREFIX TABLE ARE HANDLED,        COMCCPT
*         AND ARE DIFFERENTIATED BY CHECKING IF WORD (FWA+3) OF THE      COMCCPT
*         PREFIX TABLE LOOKS LIKE A TIME-OF-DAY WORD.  THE COPY          COMCCPT
*         TERMINATES ON END OF TABLE, ZERO BYTE, OR *COPYRIGHT*          COMCCPT
*         AND THE WORKING STORAGE AREA IS TERMINATED BY A ZERO WORD.     COMCCPT
*                                                                        COMCCPT
*         ENTRY  (A1) = PREFIX TABLE ADDRESS.                            COMCCPT
*                (X1) = CONTROL WORD.                                    COMCCPT
*                (A6) = ADDRESS OF WORKING STORAGE - 1.                  COMCCPT
*                (B1) = 1.                                               COMCCPT
*                                                                        COMCCPT
*         EXIT   NONE.                                                   COMCCPT
*                                                                        COMCCPT
*         USES   A - 2, 3, 4, 6.                                         COMCCPT
*                B - 3, 4.                                               COMCCPT
*                X - 1, 2, 3, 4, 6.                                      COMCCPT
*                                                                        COMCCPT
*         CALLS  NONE.                                                   COMCCPT
                                                                         COMCCPT
                                                                         COMCCPT
 CPT      SUBR               ENTRY/EXIT                                  COMCCPT
          LX1    18                                                      COMCCPT
          SX3    X1-770000B  CHECK FOR PREFIX TABLE                      COMCCPT
          LX1    6                                                       COMCCPT
          NZ     X3,CPT2     IF NO PREFIX TABLE                          COMCCPT
          SB4    B1+B1                                                   COMCCPT
          SB3    X1+B1       SET LENGTH OF TABLE                         COMCCPT
          SA3    CPTA                                                    COMCCPT
          LE     B3,B4,CPT2  IF TOO SHORT TO COPY                        COMCCPT
          SA4    A1+3                                                    COMCCPT
          BX1    X3*X4                                                   COMCCPT
          SA2    A3+B1                                                   COMCCPT
          SA4    A1+B4                                                   COMCCPT
          BX6    X1-X2                                                   COMCCPT
          SA3    A2+B1                                                   COMCCPT
          MX1    -12                                                     COMCCPT
          NZ     X6,CPT1     IF OLD TABLE FORMAT                         COMCCPT
          SB4    10B         INDEX TO COMMENTS FIELD                     CPSA104
          LE     B3,B4,CPT2  IF TOO SHORT TO COPY                        CPSA104
          SA4    A1+B4                                                   CPSA104
 CPT1     BX2    X4-X3                                                   COMCCPT
          LX6    X4                                                      COMCCPT
          ZR     X2,CPT2     IF *COPYRIGHT*                              COMCCPT
          BX4    -X1*X4                                                  COMCCPT
          SA6    A6+B1                                                   COMCCPT
          ZR     X4,CPTX     IF END OF DATA                              COMCCPT
          SB4    B4+B1                                                   COMCCPT
          SA4    A1+B4       READ NEXT ENTRY                             COMCCPT
          NE     B4,B3,CPT1                                              COMCCPT
 CPT2     BX6    X6-X6       CLEAR END OF BUFFER                         COMCCPT
          SA6    A6+B1                                                   COMCCPT
          EQ     CPTX        RETURN                                      COMCCPT
                                                                         COMCCPT
 CPTA     VFD    18/77B,18/77B,24/7777B                                  COMCCPT
          VFD    12/0,6/1H.,12/0,6/1H.,12/0,12/2H.                       COMCCPT
          DATA   10HCOPYRIGHT                                            COMCCPT
 CPT      SPACE  4,10                                                    COMCCPT
          BASE   *                                                       COMCCPT
          CODE   *                                                       COMCCPT
 QUAL$    IF     -DEF,QUAL$                                              COMCCPT
          QUAL   *                                                       COMCCPT
 CPT      EQU    /COMCCPT/CPT                                            COMCCPT
 CPT=     EQU    /COMCCPT/CPT 
 QUAL$    ENDIF                                                          COMCCPT
 CPT      ENDX                                                           COMCCPT
