*COMDECK CBGET10C 
 GET10CH  EJECT 
**        GET10CH - GET NEXT 10 CHARACTERS OF BOOLEAN DISPLAY ITEM
* 
*         INPUT 
*                X1 - BYTE OFFSET (UNCHANGED ON OUTPUT) 
*                B3 - WORD ADDRESS
*                B4 - BYTE LENGTH 
*         OUTPUT
*                B3 - NEW WORD ADDRESS
*                B4 - NEW BYTE LENGTH 
*                X6 - NEXT 10 CHARACTERS (DISPLAY ZERO FILL)
 GET10CH  DATA   0
          SA2    B3 
          SB3    B3+B1
          SX6    6
          IX6    X6*X1
          SB2    X6 
          LX2    B2,X2
          SX3    X1+B4
          SX6    10 
          IX7    X6-X3
          NG     X7,GETCH1   CROSSES WORD BOUNDARY
          SA3    C.MASK+B4
          SB4    B0 
          BX6    X3*X2
          SA4    C.ZEROS     ZERO FILL
          BX7    -X3*X4 
          BX6    X6+X7
          EQ     GET10CH
          SPACE  3
 GETCH1   IX7    X6-X1
          SA3    C.MASK+X7
          BX2    X3*X2
          SA4    B3 
          SB5    10 
          GE     B4,B5,GETCH2      10 OR MORE CHARACTERS
          SB6    X7 
          SB5    B4-B6
          SA3    C.MASK+B5
          BX6    X3*X4
          LX6    B2,X6
          BX6    X6+X2
          SA3    =XC.MASK+B4 ZERO FILL
          SA4    =XC.ZEROS
          BX3    -X3*X4 
          BX6    X6+X3
          SB4    B0 
          EQ     GET10CH
          SPACE  3
 GETCH2   SA3    =XC.MASK+X1
          BX6    X3*X4
          LX6    B2,X6
          BX6    X6+X2
          SB4    B4-10
          EQ     GET10CH
