*DECK TOBIN                                                              TOBIN
    FUNC   TOBIN(CHARS,LENGTH)  I ;                                      TOBIN
 #                                                                       TOBIN
***** THIS IS A SUBSYSTEM ROUTINE                                        TOBIN
***** THIS ROUTINE MUST BE COMPILED                                      TOBIN
*     USE SYMPL COMPILER  WITH THE F OPTION                              TOBIN
 #                                                                       TOBIN
     # CONVERT DISPLAY CODE TO BINARY.                                   TOBIN
       CHARS IS A WORD WHICH CONTAINS 1 TO 10 CHARS, LEFT JUSTIFIED      TOBIN
      .  ALL CHARACTERS EXCEPT THE LAST                                  TOBIN
       MUST BE NUMERIC. THE LAST MAY BE NUMERIC, [O[, OR [D[.            TOBIN
       IF THE LAST IS NUMERIC OR [O[ THE NUMBER IS OCTAL, IF THE LAST    TOBIN
       IS [D[ THE NUMBER IS DECIMAL.                                     TOBIN
       LENGTH IS EITHER THE NUMBER OF CHARS(INCLUDING THE [O[ OR [D[     TOBIN
       OR IS 0 IN WHICH CASE THE WORD MUST BE BLANK FILLED ON THE        TOBIN
       RIGHT.                                                            TOBIN
       THE NUMBER IS CONVERTED TO A BINARY INTEGER AND RETURNED.         TOBIN
      #                                                                  TOBIN
    BEGIN                                                                TOBIN
           ITEM    CHARS   I;                                            TOBIN
           ITEM    LENGTH  I;                                            TOBIN
           ITEM    INDEX   I;                                            TOBIN
           ITEM    I       I;                                            TOBIN
           ITEM    POS     I;                                            TOBIN
           ITEM    RESULT  I;                                            TOBIN
           ITEM    TEMP    I;                                            TOBIN
           ITEM    BASE    I;                                            TOBIN
           BASE = 8;                                                     TOBIN
           IF LENGTH EQ 0  THEN                                          TOBIN
               BEGIN                                                     TOBIN
                   FOR INDEX = 9 STEP -1 UNTIL 0  DO                     TOBIN
                   IF  C<INDEX,1>CHARS NQ " " THEN GOTO L1;              TOBIN
               END                                                       TOBIN
               ELSE  INDEX = LENGTH - 1;                                 TOBIN
        L1:    # INDEX POINTS AT LOW ORDER DIGIT #                       TOBIN
          IF C<INDEX,1>CHARS EQ "O" THEN INDEX = INDEX - 1;              TOBIN
             ELSE IF C<INDEX,1>CHARS EQ "D" THEN BEGIN                   TOBIN
                     BASE = 10;                                          TOBIN
                     INDEX = INDEX - 1;                                  TOBIN
                     END                                                 TOBIN
           POS = 1;                                                      TOBIN
           RESULT = 0;                                                   TOBIN
           FOR I = INDEX STEP -1 UNTIL 0  DO                             TOBIN
           BEGIN                                                         TOBIN
               TEMP = C<I,1>CHARS;                                       TOBIN
               RESULT = RESULT + POS * (TEMP - 27);                      TOBIN
                                       #27 IS VALUE OF DISPLAY CODE      TOBIN
                                        FOR 0 #                          TOBIN
               POS = BASE * POS;                                         TOBIN
           END                                                           TOBIN
           TOBIN = RESULT;                                               TOBIN
           RETURN;                                                       TOBIN
    END                                                                  TOBIN
    TERM                                                                 TOBIN
