*DECK READINS                                                            READINS
          IDENT  READINS                                                 READINS
          TITLE  READINS -  READ PSEUDO-INSTRUCTION FROM ZZZZZ49
  
          MACHINE  ANY,I
          COMMENT  READ PSEUCO-INSTRUCTION FROM ZZZZZ49 
          SYSCOM B1 
*CALL     COBIOM
          SPACE  4
**        INSOPEN -  OPEN PSEUDO-INSTRUCTION FILE  (ZZZZZ49)
* 
*         INSOPEN;                     (FROM SYMPL) 
  
  
          ENTRY  INSOPEN
 INSOPEN  CON    *           ENTRY/EXIT WORD
          SB1    1
          READ   ZZZZZ49     START READ 
          SX6    377777B
          SA6    INDEX
          SX6    377776B
          SA6    RLWORDS
          SX6    0
          SA6    EOF         NOT YET END OF FILE
          EQ     INSOPEN
          SPACE  4
**        READINS -  READ PSEUCO-INSTRUCTION FROM ZZZZZ49 
* 
*         READINS(INSTR,EOF)                     (FROM SYMPL) 
* 
*         SETS INSTR = NEXT PSEUDO-INSTRUCTION. 
*         SETS EOF = TRUE IFF END-OF-FILE WAS ENCOUNTERED.
  
  
                                                                         READINS
          EXT    ZZZZZ49
          ENTRY  READINS                                                 READINS
 READINS  CON    *           ENTRY/EXIT WORD                             READINS
          SB1    1
          SA5    INDEX       IF NO MORE WORDS IN WSA,  GO FILL
          SA4    RLWORDS
          IX4    X5-X4
          SX6    X5+B1       (INCREMENT INDEX TO WSA) 
          PL     X4,READINS1
          SA6    A5          STORE INCREMENTED INDEX TO WSA 
          SA2    A1+B1       ADDRESS OF *EOF* 
          SA4    =XOUTWS
          SB2    X4 
          SA4    B2+X5       SET *INSTR* = PSEUDO INSTRUCTION FORM WSA
          BX6    X6-X6
          LX7    X4 
          SA6    X2          SET *EOF* = FALSE
          SA7    X1 
          SA5    3           RA+3 
          MX0    42 
          BX5    X0*X5
          SA4    =0LREADINS 
          IX5    X4-X5
          NZ     X5,NEXT
          MX0    -3 
          SA4    =10H0000000000 
1         DUP    10 
          LX7    3
          BX5    -X0*X7 
          LX4    6
          IX4    X4+X5
1         ENDD
          BX6    X4 
          SA6    MSG+1
          SA4    A4 
1         DUP    10 
          LX7    3
          BX5    -X0*X7 
          LX4    6
          IX4    X4+X5
1         ENDD
          BX6    X4 
          SA6    MSG+2
          MESSAGE  MSG,,RECALL
          EQ     NEXT 
 MSG      DATA   10H    INSTR=
          BSSZ   3
 NEXT     BSS    0
          EQ     READINS     EXIT 
  
  
 READINS1 SA5    EOF         IF NOT YET EOF,  GO READ INTO WSA
          ZR     X5,READINS2
          SA2    A1+B1       ADDRESS OF *EOF* 
          SX6    1
          SA6    X2          SET *EOF* = TRUE 
          EQ     READINS     EXIT 
  
  
 READINS2 SX6    A1          PRESERVE PARAMETER LIST
          SA6    SAVEA1 
          SA1    OUTWS
          GETSQ  ZZZZZ49,X1,B7,READINS4,RLWORDS         (B7 IS DUMMY) 
          SA4    RLWORDS     RECORD LENGTH IN CHARACTERS
          SX5    1S20/10+1   CONVERT TO WORDS 
          IX6    X4*X5
          AX6    20 
          SA6    RLWORDS
          BX7    X7-X7       RESET INDEX = 0
          SA7    INDEX
          SA1    SAVEA1      RESET PARAMETER LIST 
          SA1    X1 
          EQ     READINS+1   TRY AGAIN
          SPACE  4
*    DATA EXIT FOR ZZZZZ49
  
 READINS4 BSS    0
          RETRN  ZZZZZ49
          SA1    =XWSLIM
          BX7    X1 
          SA7    INDEX
          SA1    SAVEA1      RESET PARAMETER LIST 
          SX6    B1          SET *EOF* = TRUE 
          SA2    X1+B1
          SA6    X2+0 
          SA6    EOF         SET LOCAL EOF FLAG 
          EQ     READINS     EXIT 
          SPACE  4
 INDEX    BSS    1           INDEX TO WSA 
 RLWORDS  BSS    1           NUMBER OF WORDS IN WSA 
 EOF      BSS    1           LOCAL FLAG FOR END OF FILE  (0 = NOT YET)
 SAVEA1   BSS    1           VALUE OF ORIGINAL A1 
  
          END                                                            READINS
