*DECK INSTIO
*IF DEF,PROFILE$
          IDENT  INSTIO 
          COMMENT  INSTRUMENTATION I-O
          TITLE  INSTIO - INSTRUMENTATION I-O 
          SST 
**        INSTIO - INSTRUMENTATION I-O
* 
*         CALLING SEQUENCE
*                GETWAX(WSA, LENGTH, WA); 
*                PUTWAX(WSA, LENGTH, WA); 
*                CLOSEX 
* 
*         DOES - PERFORMS I-O ON THE SCRATCH FILE MODULE
*                USED ONLY BY THE INSTRUMENTATION PACKAGE 
* 
 DBUG1    IFEQ   DEBUGC,1 
          ENTRY  GETWAX 
 GETWAX   DATA   0           READ A RECORD
          RJ     INIT 
          GET    FIT,X1,X2,,X4     DO THE READ
          EQ     GETWAX      RETURN 
  
  
          ENTRY  PUTWAX 
 PUTWAX   DATA   0           WRITE A RECORD 
          RJ     INIT 
          PUT    FIT,X1,X2,,X4     DO THE WRITE 
          EQ     PUTWAX      RETURN 
  
  
          ENTRY  CLOSEX 
 CLOSEX   DATA   0
          CLOSEM FIT,R
          MX6    0
          SA6    FTSW        CLEAR FIRST TIME 
          EQ     CLOSEX 
  
  
          ENTRY  LFNINST
 INIT     DATA   0           INITIALIZE 
          SA2    FTSW        GET FIRST TIME SWITCH
          NZ     X2,INITNFT  JP IF NOT FIRST TIME 
          MX6    1
          SA6    A2          SET AS OPEN
          SA2    LFNINST     GET THE LFN
          BX6    X2 
          SA6    FIT         PLACE LFN IN THE FIT 
          SX6    A1 
          SA6    =SSAVEA1    SAVE A1
          OPENM  FIT,I-O,R   OPEN THE FILE
          SA2    SAVEA1 
          SA1    X2          RESTORE A1 AND X1
 INITNFT  BSS    0
          SB1    1
          SA2    A1+B1
          SX1    X1          WSA
          SA3    A2+B1
          SA2    X2          REC LENGTH 
          SA4    X3          WA 
          EQ     INIT 
 FIT      FILE   LFN=MODULE,FET=FET,LT=UL,RT=U,FO=WA,MRL=32000,EX=ERREX 
,,BFS=129 
 FET      BSSZ   10 
 ERREX    DATA   0
          JP     *+400000B   ERROR - ABORT
 FTSW     DATA   0
 LFNINST  DATA   0LMODULE 
 DBUG1    ENDIF 
          END 
*ENDIF
